WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

JacobiCN[u,m]

ヤコビ(Jacobi)の楕円関数 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

JacobiCN

JacobiCN[u,m]

ヤコビ(Jacobi)の楕円関数 を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • ，ただし である．
  • は，周期がとの，u の二重周期関数である． は楕円積分EllipticKある．
  • JacobiCNは，両方の引数において有理型関数である．
  • 特別な引数の場合，JacobiCNは，自動的に厳密値を計算する．
  • JacobiCNは任意の数値精度で評価できる．
  • JacobiCNは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: JacobiCN[2.5, 0.3]

実数の部分集合上で関数をプロットする：

Wolfram Language code: Plot[JacobiCN[x, 1 / 3], {x, -10, 10}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[JacobiCN[z, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点付近の級数展開：

Wolfram Language code: Series[JacobiCN[z, m], {z, 0, 7}]
Wolfram Language code: Series[JacobiCN[z, m], {m, 0, 1}]

特異点における級数展開：

Wolfram Language code: Series[JacobiCN[x, 1], {x, (I π/2), 3}]

スコープ  (33)

数値評価  (5)

高精度で評価する：

Wolfram Language code: N[JacobiCN[2, 1 / 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: JacobiCN[2, 0.333333333333333333333333333333333333333333]

複素引数について評価する：

Wolfram Language code: JacobiCN[2.5 + I, 1 - I]

JacobiCNを高精度で効率よく評価する：

Wolfram Language code: JacobiCN[2, 0.3`500]//Timing
Wolfram Language code: JacobiCN[2, 0.3`10000];//Timing

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: JacobiCN[2, Around[1 / 2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: JacobiCN[-(I π/3), {{1, 0}, {0, 1}}]

MatrixFunctionを使って行列のJacobiCN関数を計算することもできる：

Wolfram Language code: MatrixFunction[JacobiCN[-(I π/3), #]&, {{1, 0}, {0, 1}}]

特定の値  (3)

簡単な厳密値は自動的に生成される：

Wolfram Language code: {JacobiCN[z, 0], JacobiCN[z, 1]}
Wolfram Language code: {JacobiCN[0, m], JacobiCN[EllipticK[m] / 2, m], JacobiCN[EllipticK[m], m]}

JacobiCNのいくつかの極：

Wolfram Language code: {JacobiCN[-3 I EllipticK[1 - m], m], JacobiCN[-I EllipticK[1 - m], m], JacobiCN[I EllipticK[1 - m], m], JacobiCN[3I EllipticK[1 - m], m]}

TemplateBox[{x, {1, /, 3}}, JacobiCN]の零点を求める：

Wolfram Language code: xzero = N@Solve[JacobiCN[x, 1 / 3] == 0 && 0 < x < π, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[JacobiCN[x, 1 / 3], {x, -π, 2π}, Epilog -> Style[Point[{xzero, JacobiCN[xzero, 1 / 3]}], PointSize[Large], Red]]

可視化  (3)

JacobiCN関数をパラメータのさまざまな値についてプロットする：

Wolfram Language code: Plot[{JacobiCN[x, 0], JacobiCN[x, 0.5], JacobiCN[x, 1], JacobiCN[x, 1.5], JacobiCN[x, 2]}, {x, -2π, 2π}]

JacobiCNをパラメータ の関数としてプロットする：

Wolfram Language code: Plot[{JacobiCN[1, m], JacobiCN[2, m], JacobiCN[3, m]}, {m, -7, 7}]

TemplateBox[{z, {1, /, 2}}, JacobiCN]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[JacobiCN[z, 1 / 2]], {z, -4 - 4 I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

TemplateBox[{z, {1, /, 2}}, JacobiCN]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[JacobiCN[z, 1 / 2]], {z, -4 - 4 I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

関数の特性  (8)

JacobiCNは実軸に沿って 4 TemplateBox[{m}, EllipticK]の周期を持つ：

Wolfram Language code: JacobiCN[x, m] == JacobiCN[x + 4EllipticK[m], m]

JacobiCNは虚軸に沿って 4ⅈTemplateBox[{{1, -, m}}, EllipticK]の周期を持つ：

Wolfram Language code: JacobiCN[x, m] == JacobiCN[x + 4I EllipticK[1 - m], m]

JacobiCNはその第1引数において偶関数である：

Wolfram Language code: JacobiCN[-x, m] == JacobiCN[x, m]

JacobiCNは x の解析関数である：

Wolfram Language code: FunctionAnalytic[JacobiCN[x, m], {x, m}]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[JacobiCN[x, m], {x, m}]
Wolfram Language code: FunctionDiscontinuities[JacobiCN[x, m], {x, m}]

TemplateBox[{x, {1, /, 3}}, JacobiCN]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[JacobiCN[x, 1 / 3], x]

TemplateBox[{x, m}, JacobiCN]は任意の固定された については単射ではない：

Wolfram Language code: FunctionInjective[JacobiCN[x, m], x, Assumptions -> m > 1]
Wolfram Language code: FunctionInjective[JacobiCN[x, m], x, Assumptions -> m < 1]
Wolfram Language code: FunctionInjective[JacobiCN[x, 1], x]
Wolfram Language code: Plot[{JacobiCN[x, 1 / 3], .5}, {x, -10, 10}]

TemplateBox[{x, m}, JacobiCN]は任意の固定された については全射ではない：

Wolfram Language code: FunctionSurjective[JacobiCN[x, m], x, Assumptions -> m∈Reals]
Wolfram Language code: Plot[{JacobiCN[x, 3], .5}, {x, -10, 10}, PlotRange -> {0, 1.5}]

TemplateBox[{x, m}, JacobiCN]は の正の整数値について非負である：

Wolfram Language code: FunctionSign[JacobiCN[x, m], x, Assumptions -> m∈PositiveIntegers]

一般的には非負でも非正でもない：

Wolfram Language code: FunctionSign[JacobiCN[x, m], {x, m}]

JacobiCNは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[JacobiCN[x, m], {x, m}]

微分  (3)

一次導関数：

Wolfram Language code: D[JacobiCN[x, m], x]

高次導関数：

Wolfram Language code: derivs = Table[D[JacobiCN[x, m], {x, n}], {n, 1, 4}]//FullSimplify

についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[derivs /. m -> 1 / 3], {x, -6, 6}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

についての導関数：

Wolfram Language code: D[JacobiCN[x, m], m]

積分  (3)

JacobiCNの不定積分：

Wolfram Language code: Integrate[JacobiCN[z, m], z]

原点を中心とした区間上での偶関数の定積分：

Wolfram Language code: Integrate[JacobiCN[z, 1 / 3], {z, -1, 1}]

これは，半分の区間では2倍の積分になる：

Wolfram Language code: Integrate[JacobiCN[z, 1 / 3], {z, 0, 1}]

その他の積分例：

Wolfram Language code: Integrate[JacobiCN[z, m]JacobiDN[z, m], z]
Wolfram Language code: Integrate[(JacobiDN[t, m]/1 + JacobiCN[t, m]), t]

級数展開  (3)

TemplateBox[{x, {1, /, 3}}, JacobiCN]についてのテイラー(Taylor)展開：

Wolfram Language code: Series[JacobiCN[x, 1 / 3], {x, 0, 7}]

の周りのTemplateBox[{x, {1, /, 3}}, JacobiCN]の最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[JacobiCN[x, 1 / 3], {x, 0, n}], {n, 2, 7, 2}]; Plot[{JacobiCN[x, 1 / 3], terms}, {x, -2, 2}]

TemplateBox[{1, m}, JacobiCN]についてのテイラー展開：

Wolfram Language code: Series[JacobiCN[1, m], {m, 0, 3}]

の周りのTemplateBox[{1, m}, JacobiCN]の最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[JacobiCN[1, m], {m, 0, n}], {n, 1, 3}]; Plot[{JacobiCN[1, m], terms}, {m, -5, 5}]

JacobiCNはベキ級数に適用できる：

Wolfram Language code: JacobiCN[ArcTanh[x] + O[x] ^ 8, m]

関数の恒等式と簡約  (2)

パリティ変換と周期性の関係は自動的に適用される：

Wolfram Language code: JacobiCN[-u, m]
Wolfram Language code: JacobiCN[u + 4 EllipticK[m] + 4I EllipticK[1 - m], m]

JacobiSNを含む恒等式：

Wolfram Language code: JacobiCN[z, m] ^ 2 + JacobiSN[z, m] ^ 2//FullSimplify

関数表現  (3)

JacobiAmplitudeのCosによる表現：

Wolfram Language code: Cos[JacobiAmplitude[z, m]]

他のヤコビ楕円関数との関係：

Wolfram Language code: ((m - 1) JacobiCD[z, m]^2/m JacobiCD[z, m]^2 - 1)//FullSimplify
Wolfram Language code: JacobiCN[z, m]^2 == (JacobiCS[z, m]^2/1 + JacobiCS[z, m]^2)//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: JacobiCN[z, m]//TraditionalForm

アプリケーション  (9)

KdV方程式のクノイダル解：

Wolfram Language code: f[x_, t_] := Sqrt[(a/m)](1/m EllipticK[m]) (12 a t EllipticE[m] + (4 a (-2 + m) t + m (x - 6 t β)) EllipticK[m]);
Wolfram Language code: u[x_, t_] = 2(a/m)(1 - m + (m β/2a) - ( EllipticE[m]/EllipticK[m]) + m JacobiCN[f[x, t], m] ^ 2);

解を検証する：

Wolfram Language code: D[u[x, t], t] + 6 u[x, t] D[u[x, t], x] + D[u[x, t], {x, 3}]//FullSimplify

解をプロットする：

Wolfram Language code: Plot3D[Evaluate[u[x, t] /. {β -> 1, a -> 3, m -> 3 / 4}], {x, -2, 2}, {t, 0, 3}]

単位三角形から単位円板への等角写像：

Wolfram Language code: w[z_] := With[{ζ = (z Gamma[1 / 3] ^ 3/2^1 / 33^1 / 4π), m = Sin[π / 12] ^ 2}, 2^11 / 6Cos[π / 12](1 - JacobiCN[ζ, m])(1 + Tan[π / 12]JacobiCN[ζ, m]) / (2 3^1 / 4JacobiSN[ζ, m]JacobiDN[ζ, m] + (1 - JacobiCN[ζ, m]) ^ 2)]

写像前後の点を示す：

Wolfram Language code: trianglePoints = With[{t = E ^ (2Pi I / 3)}, Flatten[Table[s / 8. Table[#1 + j / 16(#2 - #1), {j, 0, 16}]&@@@({{1, t}, {t, 1 / t}, {1 / t, 1}} / Sqrt[3]), {s, 8}]]];
Wolfram Language code: Row[{Graphics[Point[{Re[#], Im[#]}]& /@ trianglePoints, Frame -> True, ImageSize -> Small], Graphics[Point[{Re[#], Im[#]}]& /@ w[trianglePoints], Frame -> True, ImageSize -> Small]}, Spacer[20]]

非調和振動子の解：

Wolfram Language code: ϕ[k_, φ_] = Sqrt[(2k/1 - 2k)]JacobiCN[φ / Sqrt[1 - 2k], k];
Wolfram Language code: D[ϕ[k, φ], {φ, 2}] == -ϕ[k, φ] ^ 3 - ϕ[k, φ]//FullSimplify

さまざまな解をプロットする：

Wolfram Language code: Plot[Evaluate[Table[ϕ[k, ϕ], {k, 0.1, 0.4, 0.1}]], {ϕ, 0, 6Pi}]

楕円の楕円的なパラメータ化：

Wolfram Language code: ellipse[ϕ_, {a_, b_}] := With[{u = a EllipticE[ϕ, 1 - (b^2/a^2)]}, {a JacobiCN[u, Sqrt[1 - (b^2/a^2)]], b JacobiSN[u, Sqrt[1 - (b^2/a^2)]]}]

楕円形のパラメータ化と円形のパラメータ化を使ってプロットする：

Wolfram Language code: With[{b = 1, a = 2}, ParametricPlot[Evaluate[{{a Cos[ϕ], b Sin[ϕ]}, ellipse[ϕ, {a, b}]}], {ϕ, -Pi, Pi}, PlotStyle -> {{StandardGray, Thick}, {White, Dashing[0.1]}}]]

ナム(Nahm)方程式の解：

Wolfram Language code: Subscript[T, 1][z_] = -Sqrt[m ]JacobiSN[z, m] {{0, 1, 0}, {1, 0, 1}, {0, 1, 0}} / Sqrt[2]; Subscript[T, 2] [z_] = I Sqrt[m] JacobiCN[z, m] {{0, I, 0}, {-I, 0, I}, {0, -I, 0}} / Sqrt[2]; Subscript[T, 3][z_] = I JacobiDN[z, m] {{1, 0, 0}, {0, 0, 0}, {0, 0, -1}};

解がナム方程式を満足するかどうか検証する：

Wolfram Language code: Subsuperscript[T, 1, ′][z] - I (Subscript[T, 2][z]. Subscript[T, 3][z] - Subscript[T, 3][z].Subscript[T, 2][z])
Wolfram Language code: Subsuperscript[T, 2, ′][z] - I (Subscript[T, 3][z].Subscript[T, 1][z] - Subscript[T, 1][z]. Subscript[T, 3][z])
Wolfram Language code: Subsuperscript[T, 3, ′][z] - I (Subscript[T, 1][z]. Subscript[T, 2][z] - Subscript[T, 2][z].Subscript[T, 1][z])

マイラー樹脂製風船（2つの平らなプラスチックシートを外周に沿って縫い合わせ，膨らませたもの）のパラメータ化：

Wolfram Language code: x[u_] := JacobiCN[u, 1 / Sqrt[2]]; y[u_] := Sqrt[2](EllipticE[JacobiSN[u, 1 / Sqrt[2]], 1 / Sqrt[2]] - EllipticF[JacobiSN[u, 1 / Sqrt[2]], 1 / Sqrt[2]] / 2)

膨らませた風船をプロットする：

Wolfram Language code: ParametricPlot3D[{x[u]Cos[v], x[u]Sin[v], y[u]}, {v, 0, 2Pi}, {u, -EllipticK[1 / Sqrt[2]], EllipticK[1 / Sqrt[2]]}, MaxRecursion -> 1]

JacobiCNを使って2D単体から3X3の相関行列に点をマッピングする：

Wolfram Language code: Clear[corMat];corMat[{p1_, p2_}, m_] := With[{T = 2EllipticK[m]}, With[{u1 = T p1, u2 = T p2, u3 = T(1 - p1 - p2)}, (⁠| | | | | --------------- | --------------- | --------------- | | 1 | JacobiCN[u1, m] | JacobiCN[u2, m] | | JacobiCN[u1, m] | 1 | JacobiCN[u3, m] | | JacobiCN[u2, m] | JacobiCN[u3, m] | 1 |⁠)]]

単体上に行列式を可視化する：

Wolfram Language code: Plot3D[Det[corMat[{p1, p2}, 3 / 4]]//Evaluate, {p1, p2}∈Simplex[2], MaxRecursion -> 5]

行列式が単体の重心で最大になることを確かめる：

Wolfram Language code: FullSimplify[D[Det[corMat[{Indexed[p, {1}], Indexed[p, {2}]}, m]], {{Indexed[p, {1}], Indexed[p, {2}]}}] /. p -> RegionCentroid[Simplex[2]]]

行列式の最大値を楕円パラメータ の関数としてプロットする：

Wolfram Language code: Plot[Det[corMat[{1 / 3, 1 / 3}, m]], {m, 0, 1}]

相関行列を使って3DのTコピュラ分布を定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", corMat[{0.2, 0.4}, 0.1], 7}, {UniformDistribution[], UniformDistribution[], UniformDistribution[]}]

サンプルを描画する：

Wolfram Language code: {PointSize[Tiny], Point[RandomVariate[𝒟, 10 ^ 4]]}//Graphics3D

代数的レムニスケートのパラメータ化：

Wolfram Language code: p[t_, m_] := {(JacobiSN[t, m]/1 + JacobiCN[t, m] ^ 2), (JacobiSN[t, m]JacobiCN[t, m]/1 + JacobiCN[t, m] ^ 2)};

パラメトリック関数がレムニスケートについて代数方程式を解くことを確認する：

Wolfram Language code: Entity["PlaneCurve", "Lemniscate"][EntityProperty["PlaneCurve", "AlgebraicEquation"]][a][, ]
Wolfram Language code: % /. Thread[{, } -> a p[t, m]]//FullSimplify

3つの物体の周期的な動き．物体は共通軌道上のレムニスケートで等しい時間間隔で互いを追いかける：

Wolfram Language code: p3[t_, m_] := With[{τ = 4 EllipticK[m]}, {p[t, m], p[t + τ / 3, m], p[t - τ / 3, m]}]

楕円パラメータは，3体系の重心が原点に固定されたままであることを要求することで固定される：

Wolfram Language code: m3 = m /. FindRoot[With[{t = 3 / 5EllipticK[m]}, First[Mean[p3[t, m]]]] == 0, {m, 1 / 2}, WorkingPrecision -> 50]

3体構成を可視化する：

Wolfram Language code: Animate[ ParametricPlot[p[t, m3]//Evaluate, {t, 0, 4EllipticK[m3]}, Epilog -> MapIndexed[{ColorData[1]@@#2, PointSize[Large], Point[#1]}&, p3[u, m3]]], {u, 0, 12EllipticK[m3] / 3}, SaveDefinitions -> True]

5体構成：

Wolfram Language code: p5[t_, m_] := With[{τ = 4 EllipticK[m]}, Table[p[t + (k/5) τ, m], {k, -2, 2}]]
Wolfram Language code: m5 = m /. FindRoot[With[{t = 3 / 5EllipticK[m]}, First[Mean[p5[t, m]]]] == 0, {m, 1 / 2}, WorkingPrecision -> 50]
Wolfram Language code: Animate[ ParametricPlot[p[t, m5]//Evaluate, {t, 0, 4 EllipticK[m5]}, Epilog -> MapIndexed[{ColorData[1]@@#2, PointSize[Large], Point[#1]}&, p5[u, m5]]], {u, 0, 4EllipticK[m5]}, SaveDefinitions -> True]

5体構成では質量の中心を固定する2つの楕円パラメータが使用できる：

Wolfram Language code: m5a = m /. FindRoot[With[{t = 3 / 5EllipticK[m]}, First[Mean[p5[t, m]]]] == 0, {m, 999 / 1000}, WorkingPrecision -> 50]
Wolfram Language code: Animate[ ParametricPlot[p[t, m5a]//Evaluate, {t, 0, 4 EllipticK[m5a]}, Epilog -> MapIndexed[{ColorData[1]@@#2, PointSize[Large], Point[#1]}&, p5[u, m5]]], {u, 0, 8 / m5a ^ 2}, SaveDefinitions -> True]

コスタ(Costa)の極小曲面のパラメータ化[MathWorld]：

Wolfram Language code: x[w_, m_] := With[{c = 2EllipticK[m]}, Re[((π/2) + (c^2/4))w - (c/2)(JacobiEpsilon[c w, m] + JacobiCN[c w, m] JacobiDS[c w, m]) - (π/4c)JacobiSD[c w, m](JacobiNC[c w, m] + JacobiCN[c w, m])]];
Wolfram Language code: y[w_, m_] := With[{c = 2EllipticK[m]}, Im[((π/2) - (c^2/4))w + (c/2)(JacobiEpsilon[c w, m] + JacobiCN[c w, m] JacobiDS[c w, m]) - (π/4c)JacobiSD[c w, m](JacobiNC[c w, m] + JacobiCN[c w, m])]];
Wolfram Language code: z[w_, m_] := With[{c = 2EllipticK[m]}, Sqrt[(π/8)]Log[Abs[JacobiCN[c w, m]^2]]];
Wolfram Language code: ParametricPlot3D[With[{w = u + I v}, {x[w, 1 / 2], y[w, 1 / 2], z[w, 1 / 2]}], {u, 0, 1}, {v, 0, 1}, Mesh -> False]

特性と関係  (4)

逆関数で構成する：

Wolfram Language code: {JacobiCN[InverseJacobiCN[z, m], m], InverseJacobiCN[JacobiCN[z, m], m]}

PowerExpandを使って逆関数の多価性を無視する：

Wolfram Language code: PowerExpand[%]

CosをJacobiAmplitudeに適用した結果として評価する：

Wolfram Language code: Cos[JacobiAmplitude[z, m]]

超越方程式を解く：

Wolfram Language code: Solve[JacobiCN[x, m]^2 + 2JacobiCN[x, m] == a, x]//Quiet

積分：

Wolfram Language code: Integrate[JacobiCN[z, m] ^ 3, z]

考えられる問題  (2)

機械精度の入力では正しい答を出すには不十分である：

Wolfram Language code: JacobiCN[10. ^ 15, 4 / 5]
Wolfram Language code: N[JacobiCN[10 ^ 15, 4 / 5], 20]

現在のところヤコビ関数には簡単な簡約規則しか組み込まれていない：

Wolfram Language code: JacobiSN[z, m] ^ 2 + JacobiCN[z, m] ^ 2 - 1//FullSimplify
Wolfram Language code: JacobiCN[u, m]JacobiND[u, m]JacobiDC[u, m]//FullSimplify
Wolfram Research (1988), JacobiCN, Wolfram言語関数， https://reference.wolfram.com/language/ref/JacobiCN.html.

テキスト

Wolfram Research (1988), JacobiCN, Wolfram言語関数， https://reference.wolfram.com/language/ref/JacobiCN.html.

CMS

Wolfram Language. 1988. "JacobiCN." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/JacobiCN.html.

APA

Wolfram Language. (1988). JacobiCN. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JacobiCN.html

BibTeX

@misc{reference.wolfram_2026_jacobicn, author="Wolfram Research", title="{JacobiCN}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/JacobiCN.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_jacobicn, organization={Wolfram Research}, title={JacobiCN}, year={1988}, url={https://reference.wolfram.com/language/ref/JacobiCN.html}, note=[Accessed: 03-November-2026]}