WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Join[list1,list2,…]

リストあるいは同じ頭部を共有しているその他の式を鎖状に連結する．

Join[list1,list2,…,n]

各 listiのレベル n のオブジェクトを繋ぐ．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Join

Join[list1,list2,…]

リストあるいは同じ頭部を共有しているその他の式を鎖状に連結する．

Join[list1,list2,…,n]

各 listiのレベル n のオブジェクトを繋ぐ．

詳細

  • listiの頭部がListである必要はないが，すべての頭部が等しくなければならない．
  • Joinは，指定された任意のキーに関連する最後の値を保って，Associationオブジェクトに使うことができる．
  • Joinは，対応する通常のリストに効果的に結合する形でSparseArrayオブジェクトに作用する． »
  • Join[list1,list2,…,n]は，実質的に各 listiのレベル n で連続する要素をすべて連結することで不調和配列を扱う． »

例題

すべて開く すべて閉じる

例  (3)

Wolfram Language code: Join[{a, b, c}, {x, y}, {u, v, w}]

挿入構文：

Wolfram Language code: {a, b, c}~Join~{x, y}~Join~{u, v, w}

2つの連想を連結する：

Wolfram Language code: Join[<|a -> b|>, <|c -> d, a -> e|>]

スコープ  (4)

2つの行列を連結して列を長くする：

Wolfram Language code: Join[{{a, b}, {c, d}}, {{1, 2}, {3, 4}}]

2つの行列の列を連結して行を長くする：

Wolfram Language code: Join[{{a, b}, {c, d}}, {{1, 2}, {3, 4}}, 2]

不調和配列の場合，続く要素は実質的に連結される：

Wolfram Language code: Join[{{1}, {5, 6}}, {{2, 3}, {7}}, {{4}, {8}}, 2]

第2行は何もないところに{3,4}を加えたものである：

Wolfram Language code: Join[{{x}}, {{1, 2}, {3, 4}}, 2]

深さ3の配列を異なるレベルで連結する：

Wolfram Language code: aa = Array[Subscript[a, #]&, {2, 2, 2}]; bb = Array[Subscript[b, #]&, {2, 2, 2}];
Wolfram Language code: Join[aa, bb]
Wolfram Language code: Join[aa, bb, 2]
Wolfram Language code: Join[aa, bb, 3]

一般化と拡張  (2)

任意の頭部を持つ式を繋ぐ：

Wolfram Language code: Join[f[a, b, c], f[x, y], f[u, v, w]]

JoinはSparseArrayオブジェクトに使うことができる：

Wolfram Language code: SparseArray[Range[5]]
Wolfram Language code: Join[%, %, %]

アプリケーション  (2)

1行加えて行列に引数を与える：

Wolfram Language code: Join[IdentityMatrix[3], {{1, 2, 3}}]//MatrixForm

列を引数にする：

Wolfram Language code: Join[IdentityMatrix[3], Transpose[{{1, 2, 3}}], 2]//MatrixForm

ブロック行列を作る：

Wolfram Language code: Join[Join[(⁠| | | | | :- | :- | :- | | a1 | a1 | a1 | | a2 | a2 | a2 | | a3 | a3 | a3 |⁠), (⁠| | | | | :- | :- | :- | | b1 | b1 | b1 | | b2 | b2 | b2 | | b3 | b3 | b3 |⁠), 2], Join[(⁠| | | | | :- | :- | :- | | c1 | c1 | c1 | | c2 | c2 | c2 | | c3 | c3 | c3 |⁠), (⁠| | | | | :- | :- | :- | | d1 | d1 | d1 | | d2 | d2 | d2 | | d3 | d3 | d3 |⁠), 2]]//MatrixForm

以下はArrayFlattenでも行える：

Wolfram Language code: ArrayFlatten[(⁠| | | | :-- | :-- | | (⁠\| \| \| \| \| :- \| :- \| :- \| \| a1 \| a1 \| a1 \| \| a2 \| a2 \| a2 \| \| a3 \| a3 \| a3 \|⁠) | (⁠\| \| \| \| \| :- \| :- \| :- \| \| b1 \| b1 \| b1 \| \| b2 \| b2 \| b2 \| \| b3 \| b3 \| b3 \|⁠) | | (⁠\| \| \| \| \| :- \| :- \| :- \| \| c1 \| c1 \| c1 \| \| c2 \| c2 \| c2 \| \| c3 \| c3 \| c3 \|⁠) | (⁠\| \| \| \| \| :- \| :- \| :- \| \| d1 \| d1 \| d1 \| \| d2 \| d2 \| d2 \| \| d3 \| d3 \| d3 \|⁠) |⁠)]//MatrixForm

特性と関係  (1)

Join[list1,list2,…]はFlatten[{list1,list2,…},1]に等しい：

Wolfram Language code: Join[{1, 2}, {{a, b}, {c, d}}, {3, 4, 5}]
Wolfram Language code: Flatten[{{1, 2}, {{a, b}, {c, d}}, {3, 4, 5}}, 1]

おもしろい例題  (2)

あるリストにそのリスト自身を加えることで連続的にリストを2倍にしていく：

Wolfram Language code: NestList[Join[#, #]&, {x}, 4]

Thue–Morse数列を構築する [詳細]：

Wolfram Language code: NestList[Join[#, 1 - #]&, {1}, 5]
Wolfram Research (1988), Join, Wolfram言語関数， https://reference.wolfram.com/language/ref/Join.html （2014年に更新）.

テキスト

Wolfram Research (1988), Join, Wolfram言語関数， https://reference.wolfram.com/language/ref/Join.html （2014年に更新）.

CMS

Wolfram Language. 1988. "Join." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Join.html.

APA

Wolfram Language. (1988). Join. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Join.html

BibTeX

@misc{reference.wolfram_2026_join, author="Wolfram Research", title="{Join}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Join.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_join, organization={Wolfram Research}, title={Join}, year={2014}, url={https://reference.wolfram.com/language/ref/Join.html}, note=[Accessed: 01-November-2026]}