WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

JoinedCurve[{segment1,segment2,…}]

segment1，segment2等順に続く線分からなる曲線である．

JoinedCurve[{component1,component2,…}]

別々の成分曲線component1，component2等のリストである．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイル付け  
座標  
領域  
オプション  
CurveClosed  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

JoinedCurve

JoinedCurve[{segment1,segment2,…}]

segment1，segment2等順に続く線分からなる曲線である．

JoinedCurve[{component1,component2,…}]

別々の成分曲線component1，component2等のリストである．

詳細とオプション

  • JoinedCurveは，Graphics（二次元グラフィックス）で使える．
  • JoinedCurve[segment]は，JoinedCurve[{segment}]に等しい．
  • segmenti に使える形式
  • Line[{pt1,pt2,…}]直線
    BezierCurve[{pt1,pt2,…},…]ベジエ(Bézier)曲線
    BSplineCurve[{pt1,pt2,…},…]Bスプライン曲線
  • segmenti の最初の点は，segmenti-1の最後の点とされる．JoinedCurve[{pr1[{p1,…,pi}],pr2[{q1,…,qj}],…}]は，JoinedCurve[{pr1[{p1,…,pi}],pr2[{pi,q1,…,qj}],…}]に等しい．
  • 設定JoinedCurve[{component1,component2,…},CurveClosed->{close1,close2,…}]は，個々の成分曲線が閉じられるべきであるかどうかを指定する．
  • JoinedCurve[{component1,…},CurveClosed->close]は，すべての成分曲線が閉じられるべきであることを示す．
  • 以下を使って座標を指定することができる
  • {x,y}通常の座標
    Scaled[{x,y}]スケールした座標
    ImageScaled[{x,y}]画像をスケールした座標
    Offset[{dx,dy},{x,y}]絶対オフセット座標
  • 線分の個々の座標と座標のリストは，Dynamicオブジェクトでもよい．
  • 曲線の太さは，ThicknessあるいはAbsoluteThicknessを使っても，Thick，Thin等を使っても，指定することができる．
  • 曲線の破線は，DashingあるいはAbsoluteDashingを使っても，Dashed，Dotted等を使っても，指定することができる．
  • 曲線の色付けと透過性は，CMYKColor，GrayLevel，Hue，Opacity，RGBColorのいずれかを使って指定することができる．
  • 曲線線分の継ぎ目は，JoinFormを使って指定することができる．
  • 曲線のキャップは，CapFormを使って指定することができる．
  • Lineに対するVertexColorsおよびVertexNormalsのオプションは，JoinedCurveのコンストラクト内では効果がない．

例題

すべて開く すべて閉じる

例  (4)

混合曲線線分を持つ曲線：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};
Wolfram Language code: Graphics[JoinedCurve[{BezierCurve[a], Line[b]}]]

2つの曲線成分を持つ曲線：

Wolfram Language code: pts = {{-1, -1 / 2}, {0, 1}, {1, -1 / 2}};
Wolfram Language code: Graphics[JoinedCurve[{{Line[2pts]}, {Line[pts]}}]]

2つの閉成分を持つ曲線：

Wolfram Language code: Graphics[JoinedCurve[{{Line[2pts]}, {Line[pts]}}, CurveClosed -> True]]

さまざまなスタイルを付けた曲線：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};curve = JoinedCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}];
Wolfram Language code: {Graphics[{Dashed, curve}], Graphics[{Pink, curve}], Graphics[{Thick, curve}], Graphics[{Thick, Dashed, Pink, curve}]}

曲がった矢印：

Wolfram Language code: Graphics[{Arrowheads[{-0.1, 0.1}], Arrow[JoinedCurve[{Line[{{0, 0}, {1, 0}}], BezierCurve[{{2, 0}, {2, 1}}]}]]}]

スコープ  (18)

グラフィックス  (12)

指定  (3)

単一の開いた線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[Line[{{-1, 0}, {-1, 1}, {0, 2}, {1, 1}, {1, 0}}]]]

単一の閉じた線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[Line[{{-1, 0}, {-1, 1}, {0, 2}, {1, 1}, {1, 0}}], CurveClosed -> True]]

単一の開いたベジエ曲線の線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}]]]

単一の閉じたベジエ曲線の線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}], CurveClosed -> True]]

単一の開いたBスプライン曲線の線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[BSplineCurve[{{-1, 0}, {-1, 1}, {0, 0}, {1, 1}, {1, 0}}]]]

単一の閉じたBスプライン曲線の線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[BSplineCurve[{{-1, 0}, {-1, 1}, {0, 0}, {1, 1}, {1, 0}}], CurveClosed -> True]]

混合曲線の線分による曲線：

Wolfram Language code: Graphics[JoinedCurve[{BSplineCurve[{{-2, 0}, {-1, 1}, {0, -1}, {1, 1}, {2, 0}}], Line[{{2, -1}, {-2, -1}}]}, CurveClosed -> True]]

2本の曲線成分による曲線：

Wolfram Language code: Graphics[JoinedCurve[{{Line[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {Line[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}, CurveClosed -> True]]

複数の曲線成分による曲線：

Wolfram Language code: pts = {{-(Sqrt[3]/2), -(1/2)}, {0, 1}, {(Sqrt[3]/2), -(1/2)}};
Wolfram Language code: Graphics[JoinedCurve[{{BezierCurve[3pts]}, { Line[2pts]}, {BezierCurve[pts]}}, CurveClosed -> True]]

スタイル付け  (6)

さまざまな厚みの曲線：

Wolfram Language code: Table[Graphics[{Thickness[i], JoinedCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}, CurveClosed -> True]}], {i, {.005, .025, .05}}]

破線曲線：

Wolfram Language code: Table[Graphics[{d, JoinedCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}, CurveClosed -> True]}], {d, {Dotted, Dashed, DotDashed}}]

色指示子は曲線の線の色を指定する：

Wolfram Language code: Table[Graphics[{c, JoinedCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}, CurveClosed -> True]}], {c, {Red, Green, Blue, Orange}}]

CapFormを使って各曲線成分のキャップが指定できる：

Wolfram Language code: Table[Graphics[{CapForm[cap], Thickness[.1], JoinedCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}, PlotLabel -> cap], {cap, {"Butt", "Round", "Square"}}]

JoinFormを使って線分の結合タイプが指定できる：

Wolfram Language code: a = {{-2, 0}, {0, 2}, {2, 0}, {0, -2}};curve = JoinedCurve[{{Line[2a]}, {Line[a]}}];
Wolfram Language code: {Graphics[{JoinForm["Bevel"], Thickness[0.07], curve}, PlotRange -> 5], Graphics[{JoinForm["Meter"], Thickness[0.07], curve}, PlotRange -> 5]Graphics[{JoinForm["Round"], Thickness[0.07], curve}, PlotRange -> 5]}

Arrowで曲線を包み込んで曲線による矢印を作ることができる：

Wolfram Language code: Graphics[{Arrowheads[Large], Arrow[JoinedCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]]}]

座標  (3)

Scaled座標を使う：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{Scaled[{0, 0}], Scaled[{.5, 1}], Scaled[{1, 0}]}]], Frame -> True]

ImageScaled座標を使う：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{ImageScaled[{0, 0}], ImageScaled[{.5, 1}], ImageScaled[{1, 0}]}]], Frame -> True]

Offset座標を使う：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{Offset[{10, 10}, {0, 0}], Offset[{0, 50}, {.5, 1}], Offset[{-10, 10}, {1, 0}]}]], Frame -> True]

領域  (6)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[JoinedCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

幾何学次元：

Wolfram Language code: RegionDimension[JoinedCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

点の帰属テスト：

Wolfram Language code: {RegionMember[JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}], {1, 0}], RegionMember[JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}], {1, 2}]}

弧の長さ：

Wolfram Language code: ℛ = JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}];
Wolfram Language code: {ArcLength[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Gray, ℛ}, {Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}];
Wolfram Language code: {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {0, 0}]}

結合曲線から最近点までの距離：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 4}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 0}], SignedRegionDistance[ℛ, {0, 0}]}

結合曲線までの符号付き距離：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

結合曲線は有界である：

Wolfram Language code: ℛ = JoinedCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}], Line[{{0, -(2/3)}, {-1, 0}}]}];
Wolfram Language code: BoundedRegionQ[ℛ]

その領域を取得する：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

オプション  (1)

CurveClosed  (1)

1つの開いたベジエ曲線線分を持った曲線：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}]]]

1つの閉じたベジエ曲線線分を持った曲線：

Wolfram Language code: Graphics[JoinedCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}], CurveClosed -> True]]

それぞれの成分を閉じるかどうかを個別に指定する：

Wolfram Language code: Graphics[JoinedCurve[{{Line[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}, CurveClosed -> {True, False}]]

アプリケーション  (2)

曲線でフォントの輪郭を定義する：

Wolfram Language code: a = JoinedCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, {Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}, CurveClosed -> True];
Wolfram Language code: Graphics[a]

グリフから曲線の輪郭を抽出する：

Wolfram Language code: g = First[[image]] /. FilledCurve[a__] :> JoinedCurve[a];
Wolfram Language code: Head[g]

原点の周りでグリフを回転させる：

Wolfram Language code: Graphics[{Thick, Table[{Hue[(t/2 π)], Rotate[g, t, {0, 0}]}, {t, 0, 2 π, (π/6)}]}]

特性と関係  (1)

Bスプライン曲線を使って円形路を作成する：

Wolfram Language code: pts = {{0., -0.5}, {0.5, -0.5}, {0.5, 0.5}, {0., 0.5}, {-0.5, 0.5}, {-0.5, -0.5}, {0., -0.5}}; w = {1, .5, .5, 1, .5, .5, 1}; k = {0, 0, 0, 1 / 4, 1 / 2, 1 / 2, 3 / 4, 1, 1, 1}; path = {{BSplineCurve[2pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}, {BSplineCurve[pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}};

Arrowを曲線に使って，曲がった矢印を作成する：

Wolfram Language code: Graphics[{Arrow[JoinedCurve[path]]}]

Arrowheadsを使って，鏃の特性を指定する：

Wolfram Language code: Graphics[{Arrowheads[Table[{RandomReal[{0.05, 0.1}], i}, {i, 0.1, 1, 0.1}]], Arrow[JoinedCurve[path]]}]

FilledCurveと組み合せて，曲がった曲線を境界とする形を得る：

Wolfram Language code: Graphics[{EdgeForm[], FaceForm[Pink], FilledCurve[path], Arrowheads[Table[{RandomReal[{0.05, 0.1}], i}, {i, 0.1, 1, 0.1}]], Arrow[JoinedCurve[path]]}]

おもしろい例題  (2)

ランダムの曲線：

Wolfram Language code: Module[{a = JoinedCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, {Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}, CurveClosed -> True]}, Graphics[Table[{Thick, Hue[RandomReal[]], Translate[Rotate[Scale[a, RandomReal[5]], RandomReal[2Pi]], RandomReal[20, {2}]]}, {30}]]]

競争する矢印：

Wolfram Language code: DynamicModule[{curve = First[First[ ImportString[ExportString[Style["M8", FontFamily -> "Times", FontSize -> 72], "PDF"], {"PDF", "PageGraphics"}, "TextOutlines" -> True]]] /. {Thickness[_] :> {}, FilledCurve[args__] :> {FaceForm[ColorData["HTML", "Crimson"]], FilledCurve[args], Dashed, Arrow[JoinedCurve[args, CurveClosed -> True]]}}}, Animate[Graphics[{ Arrowheads[{{0.05, t}, {0.05, Mod[t + (1/3), 1]}, {0.05, Mod[t + (2/3), 1]}}], curve}], {t, 0, 1}, SaveDefinitions -> True, AnimationRunning -> False]]
Wolfram Research (2010), JoinedCurve, Wolfram言語関数， https://reference.wolfram.com/language/ref/JoinedCurve.html.

テキスト

Wolfram Research (2010), JoinedCurve, Wolfram言語関数， https://reference.wolfram.com/language/ref/JoinedCurve.html.

CMS

Wolfram Language. 2010. "JoinedCurve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/JoinedCurve.html.

APA

Wolfram Language. (2010). JoinedCurve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JoinedCurve.html

BibTeX

@misc{reference.wolfram_2026_joinedcurve, author="Wolfram Research", title="{JoinedCurve}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/JoinedCurve.html}", note=[Accessed: 07-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_joinedcurve, organization={Wolfram Research}, title={JoinedCurve}, year={2010}, url={https://reference.wolfram.com/language/ref/JoinedCurve.html}, note=[Accessed: 07-July-2026]}