WOLFRAM

Wolfram 语言与系统参考资料中心

JulianDate[]

给出在格林威治时区，自公元前 4714 年 11 月 24 日午时起至现在的天数.

JulianDate[date]

给出指定日期的天数.

JulianDate["type"]

给出儒略日期指定类型的变体.

JulianDate["type",date]

给出指定日期的变体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
TimeSystem  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

JulianDate

JulianDate[]

给出在格林威治时区，自公元前 4714 年 11 月 24 日午时起至现在的天数.

JulianDate[date]

给出指定日期的天数.

JulianDate["type"]

给出儒略日期指定类型的变体.

JulianDate["type",date]

给出指定日期的变体.

更多信息和选项

  • 儒略日期，也称为儒略日或儒略日数，在天文学中广泛用于测量时间.
  • JulianDate 的结果是使用 GMT 时区从预测儒略历中公元前 4713 年 1 月 1 日中午开始的天数，或在预测格里高利历中公元前 4714 年 11 月 24 日. 它包括根据自格林威治标准时间前一个中午以来时间的一个比例.
  • 在 JulianDate[date] 中，date 可以是 DateObject 表达式、日期字符串、{y,m,d,h,m,s} 日期列表或与绝对时间指定相对应的数字.
  • JulianDate[date] 假定给定的 date 在 $TimeZone 中，除非它是有明确的 TimeZone 选项值的 DateObject 或 TimeObject 表达式.
  • 假定没有明确时间系统的输入日期在 "SmearedUTC" 时间系统中给出，这是在引入前一天闰秒被模糊的 UTC 格式.
  • 可以使用选项 TimeSystem 指定输出时间系统. 此选项的可能值包括 "SmearedUTC", "UT1", "TAI", "TT" 等.
  • 儒略日期不能表示增加闰秒，因此 TimeSystem"UTC" 等价于函数 JulianDate 中的 TimeSystem"SmearedUTC".
  • 在 JulianDate[{y,m,…}] 中可使用较短的列表：{y} 等价于 {y,1,1,0,0,0}，{y,m} 等价于 {y,m,1,0,0,0} 等等.
  • 在 m、d、h、m、s 正常范围外的值被适当调整. d、h、m、s 可以为非整数值.
  • 可能的儒略日期的变体包括：
  • "Reduced"相对于 1858 年 11 月 16 日午时
    "Modified"相对于 1858 年 11 月 17 日午夜 (MJD)
    "Truncated"相对于 1968 年 5 月 24 日午夜 (TJD)
    "Dublin"相对于 1899 年 12 月 31 日午时 (DJD)
    "Full"相对于公元前 4714 年 11 月 24 日午时 (JD)
  • 缺省的儒略日期的变体设置为 "Full". 所有参考日期都使用外推格列高利历.

范例

打开所有单元 关闭所有单元

基本范例  (3)

以公元前 4714 年 11 月 24 日中午以来的天数为单位的当前儒略历日期：

Wolfram Language code: JulianDate[]

儒略日期的变体有不同的纪元日期：

Wolfram Language code: JulianDate["Modified"]
Wolfram Language code: JulianDate["Truncated"]

将日期对象转换为儒略日期：

Wolfram Language code: JulianDate[DateObject[{2021, 10, 8, 11, 13, 15}, "Instant", "Gregorian", -5.]]

将日期字符串转换为儒略日期：

Wolfram Language code: DateString[]
Wolfram Language code: JulianDate[%]

范围  (6)

假定输入日期为 $TimeZone 的日期. Block 可用来指定不同的时区：

Wolfram Language code: $TimeZone
Wolfram Language code: JulianDate["2021-10-8"]
Wolfram Language code: Block[{$TimeZone = 0}, JulianDate["2021-10-8"]]

用 DateObject 来指定输入为不同的 TimeZone：

Wolfram Language code: JulianDate["Dublin", DateObject[{2021, 2, 19, 11, 0, 0}, TimeZone -> 0]]
Wolfram Language code: JulianDate["Dublin", DateObject[{2021, 2, 19, 11, 0, 0}, TimeZone -> -5]]

没有指明的情况下，假定有分隔符：

Wolfram Language code: Block[{$TimeZone = -5}, JulianDate["Dublin", {"2/23/2020", {"Month", "Day", "Year"}}]]

明确指定分隔符：

Wolfram Language code: Block[{$TimeZone = -5}, JulianDate["Dublin", {"2/23/2020", {"Month", "/", "Day", "/", "Year"}}]]

日期列表被转换成标准归一化格式：

Wolfram Language code: JulianDate["Truncated", {2021, 2, 31}]
Wolfram Language code: JulianDate["Truncated", {2021, 3, 3}]

在输入日期列表中，天、小时、分钟和秒的值可以为非整数：

Wolfram Language code: JulianDate[{2021, 3, 15.5}]
Wolfram Language code: JulianDate[{2021, 3, 15, 12.3}]

年份没有指明的情况下，默认为当前年份：

Wolfram Language code: Block[{$TimeZone = 4}, JulianDate[{"2/15", {"Month", "Day"}}]]

选项  (1)

TimeSystem  (1)

取一个日期对象：

Wolfram Language code: date = DateObject[{2021, 8, 1, 0, 0, 0}]

以原子时间计算其儒略日期：

Wolfram Language code: JulianDate[date, TimeSystem -> "TAI"]

与 UTC 中的儒略日期进行比较：

Wolfram Language code: % - JulianDate[date, TimeSystem -> "UTC"]

日期差为 37 闰秒：

Wolfram Language code: 86400%

属性和关系  (6)

标准儒略日期在 UTC 时间系统的 GMT 中午的小数部分为零：

Wolfram Language code: JulianDate[DateObject[{2021, 2, 17, 12, 0, 0}, TimeZone -> 0]]
Wolfram Language code: MixedFractionParts[%]

因此，午夜时的小数部分为 0.5：

Wolfram Language code: JulianDate[DateObject[{2021, 2, 18, 0, 0, 0}, TimeZone -> 0]]
Wolfram Language code: MixedFractionParts[%]

现代儒略日期是大数字，几乎是两百万：

Wolfram Language code: jd = JulianDate[]

要跟踪计算机的时钟精度（以天为单位），需要的不仅仅是机器精度：

Wolfram Language code: {Precision[jd], Accuracy[jd]}

下面是以秒为单位的准确度：

Wolfram Language code: Accuracy[86400jd]

它与用实数表示秒的其他日期表示的准确度一致：

Wolfram Language code: Accuracy /@ {AbsoluteTime[], DateList[]}

JulianDate[date] 将 date 转换为儒略日期格式：

Wolfram Language code: JulianDate[{2000, 1, 1, 0, 0, 0}]

FromJulianDate 将儒略日期格式转换为 DateObject 表达式：

Wolfram Language code: FromJulianDate[%]

儒略日期 0 对应于格林尼治标准时区的前公历日期：

Wolfram Language code: FromJulianDate[0, TimeZone -> 0]

它对应于格林尼治标准时区的儒略日期 年 1 月 1 日：

Wolfram Language code: CalendarConvert[%, "Julian"]
Wolfram Language code: DateObject[{-4713, 1, 1, 12, 0, 0}, "Instant", "Julian", 0.]

转换回儒略日期 0：

Wolfram Language code: JulianDate[%]

JulianDate 函数的结果对应 GMT 时区的 "JulianDate" 日历：

Wolfram Language code: date = DateObject[{2021, 1, 1, 0, 0, 0}, TimeZone -> "GMT"]
Wolfram Language code: JulianDate[date]//DecimalForm[#, 8]&
Wolfram Language code: CalendarConvert[date, "JulianDate"]
Wolfram Language code: DateObject[{(4918431/2)}, "Instant", "JulianDate", "GMT"]
Wolfram Language code: JulianDate[%]//DecimalForm[#, 8]&

JulianDate 是 AbsoluteTime 的仿射变换：是从秒到天数的重新缩放，并添加了一个常数：

Wolfram Language code: a = 1 / 86400;
Wolfram Language code: b = JulianDate[{1900, 1, 1, 0, 0, 0}]
Wolfram Language code: toJulianDate[t_] := a t + b

接受任何日期：

Wolfram Language code: date = {2000, 1, 1, 0, 0, 0};

这是来计算儒略历日期的另一种方法：

Wolfram Language code: toJulianDate[AbsoluteTime[date]]
Wolfram Language code: % == JulianDate[date]

可能存在的问题  (1)

即使在有闰秒的日期，儒略日期在 UTC 日中点的小数部分也为零：

Wolfram Language code: DateObject[{2020, 12, 31, 12, 0, 0}, TimeZone -> 0, TimeSystem -> "UTC"]
Wolfram Language code: DecimalForm[JulianDate[%], {Infinity, 6}]

同样发生在有闰秒增加的日期中：

Wolfram Language code: DateObject[{2016, 12, 31, 12, 0, 0.5}, TimeZone -> 0, TimeSystem -> "UTC"]
Wolfram Language code: DecimalForm[JulianDate[%], {Infinity, 6}]
Wolfram Research (2015)，JulianDate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/JulianDate.html （更新于 2021 年）.

文本

Wolfram Research (2015)，JulianDate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/JulianDate.html （更新于 2021 年）.

CMS

Wolfram 语言. 2015. "JulianDate." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/JulianDate.html.

APA

Wolfram 语言. (2015). JulianDate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/JulianDate.html 年

BibTeX

@misc{reference.wolfram_2026_juliandate, author="Wolfram Research", title="{JulianDate}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/JulianDate.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_juliandate, organization={Wolfram Research}, title={JulianDate}, year={2021}, url={https://reference.wolfram.com/language/ref/JulianDate.html}, note=[Accessed: 31-October-2026]}