WOLFRAM

Wolfram 语言与系统参考资料中心

ListConvolve[ker,list]

构造 list 与核 ker 的卷积.

ListConvolve[ker,list,k]

形成循环卷积，其中 ker 中的 k 个元素和 list 中的每个元素对齐.

ListConvolve[ker,list,{kL,kR}]

形成循环卷积，它的第一个元素包含 list[[1]]ker[[kL]]，最后一个元素包含 list[[-1]]ker[[kR]].

ListConvolve[ker,list,klist,p]

形成卷积，其中 list 放置在重复元素 p 的结尾.

ListConvolve[ker,list,klist,{p1,p2,…}]

形成卷积，其中list 放置在循环重复 pi 的结尾.

ListConvolve[ker,list,klist,padding,g,h]

形成广义卷积，g 代替 Times，h 代替 Plus.

ListConvolve[ker,list,klist,padding,g,h,lev]

在 ker 和 list 的 lev 层上使用元素形成卷积.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
延伸和对齐  
数据填充  
更高维数  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ListConvolve

ListConvolve[ker,list]

构造 list 与核 ker 的卷积.

ListConvolve[ker,list,k]

形成循环卷积，其中 ker 中的 k 个元素和 list 中的每个元素对齐.

ListConvolve[ker,list,{kL,kR}]

形成循环卷积，它的第一个元素包含 list[[1]]ker[[kL]]，最后一个元素包含 list[[-1]]ker[[kR]].

ListConvolve[ker,list,klist,p]

形成卷积，其中 list 放置在重复元素 p 的结尾.

ListConvolve[ker,list,klist,{p1,p2,…}]

形成卷积，其中list 放置在循环重复 pi 的结尾.

ListConvolve[ker,list,klist,padding,g,h]

形成广义卷积，g 代替 Times，h 代替 Plus.

ListConvolve[ker,list,klist,padding,g,h,lev]

在 ker 和 list 的 lev 层上使用元素形成卷积.

更多信息

  • 对于核 Kr 和列表 as，ListConvolve[ker,list] 计算 ，其中和式的极限使得核不会延伸出列表的任何一边.
  • ListConvolve[ker,list] 给出一个长度为 Length[list]-Length[ker]+1 的结果.
  • ListConvolve[ker,list] 不允许超出，它等价于 ListConvolve[ker,list,{-1,1}].
  • ListConvolve[ker,list,k] 等价于 ListConvolve[ker,list,{k,k}].
  • ListConvolve[ker,list,{kL,kR}] 中的 kL 和kR 的值决定在的每一边允许 list 延伸量.
  • {kL,kR} 的共同选项是：
  • {-1,1}无延伸量(缺省)
    {-1,-1}右端的最大延伸量
    {1,1}左端最大延伸量
    {1,-1}左右两端的最大延伸量
  • 仅在一端有最大延伸量，ListConvolve 得到的结果和 list 的长度相同.
  • ListConvolve[ker,list,{kL,kR},padlist] 实际上重复放置 padlist，然后在它们上加一个 list 的副本来形成结果的卷积.
  • padlist 的共同选项是：
  • p重复使用单个元素填充
    {p1,p2,…}循环使用元素序列填充
    list将 list 看作循环填充 (缺省)
    {}不填充
  • ListConvolve 对多维核和数据列表起使用.
  • ListConvolve[ker,list,{{kL 1,kL 2,…},{kR 1,kR 2,…}}] 形成循环卷积，它的 {1,1,…} 元素包含 ker[[kL 1,kL 2,…]]list[[1,1,…]]，它的 {-1,-1,…} 元素包含 ker[[kR 1,kR 2,…]]list[[-1,-1,…]].
  • {kL,kR} 等价于 {{kL,kL,…},{kR,kR,…}}.
  • 当一个函数 h 被指定用作替换 Plus，用一个深度等于 ker 的深度产生明确的嵌套 h 表达式.
  • ListConvolve 对精确数、符号数及近似数起作用.

范例

打开所有单元 关闭所有单元

基本范例  (4)

核 {x,y} 与列表数据的卷积：

Wolfram Language code: ListConvolve[{x, y}, {a, b, c, d, e, f}]

制作一个循环卷积，它的深度和原数据相同：

Wolfram Language code: ListConvolve[{x, y}, {a, b, c, d, e, f}, 1]

将核元素 2 与数据内的连续元素对齐：

Wolfram Language code: ListConvolve[{x, y}, {a, b, c, d, e, f}, 2]

用 zzz 填充，而不是循环使用数据：

Wolfram Language code: ListConvolve[{x, y}, {a, b, c, d, e, f}, 1, zzz]

二维卷积：

Wolfram Language code: ListConvolve[{{1, 1}, {1, 1}}, {{a, b, c}, {d, e, f}, {g, h, i}}]

范围  (9)

延伸和对齐  (4)

沿着数据“放映”核，不允许延伸：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}]

在开始处最大延伸；末端没有延伸：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, 1]

末端的最大延伸，开始处无延伸：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, -1]

开始和末端的最大延伸：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, {1, -1}]

将核元素 1 和数据的第一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, 1]

将核元素 2 和数据的第一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, 2]

将核元素 3 和数据的第一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, 3]

将核元素的最后一个元素和数据的第一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, -1]

将核元素的最后一个元素和数据的第一个元素、最后一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, {1, 1}]

将核元素 2 和数据的第一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, {2, 1}]

将核元素 2 和数据的最后一个元素对齐：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, {1, 2}]

数据填充  (2)

用填充 aa：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5}, 1, aa]

循环使用填充元素列表：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5}, 1, {aa, bb}]
Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3, 4, 5}, 1, {aa, bb, cc}]
Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3}, {1, -1}, {aa, bb, cc}]

更高维数  (3)

不允许延伸：

Wolfram Language code: ListConvolve[{{a, b}, {c, d}}, {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

对齐核和数据的 {1,1} 元素：

Wolfram Language code: ListConvolve[{{a, b}, {c, d}}, {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, 1]

结果和输入数据有相同的维数：

Wolfram Language code: Dimensions[%]

在每个方向给出不同的延伸：

Wolfram Language code: ListConvolve[{{a, b}, {c, d}}, {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, {{1, 1}, {2, 2}}]

推广和延伸  (4)

ListConvolve 对稀疏数组起作用：

Wolfram Language code: ListConvolve[{a, b, c}, SparseArray[6 -> x, 20]]

用 f 替代 Times：

Wolfram Language code: ListConvolve[{x, y}, {1, 2, 3, 4}, 1, 0, f]

用 g 替代 Plus：

Wolfram Language code: ListConvolve[{x, y}, {1, 2, 3, 4}, 1, 0, f, g]
Wolfram Language code: ListConvolve[{x, y}, {1, 2, 3, 4}, 1, 0, f, List]

用 f 和 g 替代 Times 和 Plus，用空数据填充：

Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3}, 1, {}, f, g]
Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3}, -1, {}, f, g]
Wolfram Language code: ListConvolve[{x, y, z}, {1, 2, 3}, {1, -1}, {}, f, g]

可将 ListConvolve 用于 TimeSeries：

Wolfram Language code: ts = TimeSeries[Table[Subscript[x, t], {t, 12}]]
Wolfram Language code: ts["Path"]
Wolfram Language code: ListConvolve[{1 / 2, 1 / 2}, ts, {1}]
Wolfram Language code: %["Path"]

应用  (9)

求一个移动平均数：

Wolfram Language code: ListConvolve[{1, 1} / 2, {a, b, c, d, e}]

或使用函数 MovingAverage：

Wolfram Language code: MovingAverage[{a, b, c, d, e}, 2]

平滑带有噪声的数据：

Wolfram Language code: data = Table[Sqrt[x] + RandomReal[], {x, 30}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: ListLinePlot[ListConvolve[{1, 1, 2, 1, 1} / 6, data]]

求列表的自动相关作用：

Wolfram Language code: data = Table[Mod[i ^ 2, 17], {i, 100}];
Wolfram Language code: ListLinePlot[ListConvolve[data, data, {1, 1}]]

应用一个简单的图像处理过滤：

Wolfram Language code: ArrayPlot[CellularAutomaton[150, {{1}, 0}, 30]]
Wolfram Language code: ArrayPlot[ListConvolve[{{-1, 1}, {1, -1}}, CellularAutomaton[150, {{1}, 0}, 30]]]

卷积系数列表和多项式相乘：

Wolfram Language code: CoefficientList[(a + b x + c x ^ 2)(1 + 2x + 3x ^ 2 + 4x ^ 3), x]
Wolfram Language code: ListConvolve[{a, b, c}, {1, 2, 3, 4}, {1, -1}, 0]

卷积数字列表和数的相乘：

Wolfram Language code: ListConvolve[IntegerDigits[24561], IntegerDigits[1247], {1, -1}, 0]
Wolfram Language code: FromDigits[%, 10]
Wolfram Language code: 24561 1247

Pascal 三角：

Wolfram Language code: Column[NestList[ListConvolve[{1, 1}, #, {1, -1}, 0]&, {1}, 5], Center]

以5为基数的加性细胞自动机：

Wolfram Language code: ArrayPlot[NestList[Mod[ListConvolve[{2, 3, 1}, #, 2], 5]&, SparseArray[50 -> 1, 101], 50]]

高阶多项式的快速乘法：

Wolfram Language code: p1[x_] = RandomInteger[9, 101].x ^ Range[0, 100]; p2[x_] = RandomInteger[9, 101].x ^ Range[0, 100];

用有最大延伸和零填充的 ListConvolve：

Wolfram Language code: c3 = ListConvolve[CoefficientList[p1[x], x], CoefficientList[p2[x], x], {1, -1}, 0] ;
Wolfram Language code: p3[x_] = c3.x ^ Range[0, Length[c3] - 1];
Wolfram Language code: p3[x] == Expand[p1[x] p2[x]]

属性和关系  (8)

生成两个随机向量：

Wolfram Language code: {a, b} = RandomReal[1, {2, 31}];

用于从向量构造循环矩阵的函数：

Wolfram Language code: circulant[v_] := ToeplitzMatrix[v, RotateRight[Reverse[v]]]

循环卷积相当于与循环矩阵相乘：

Wolfram Language code: ListConvolve[a, b, {1, 1}] == circulant[a].b

循环卷积也相当于离散傅立叶变换域中的乘法：

Wolfram Language code: ListConvolve[a, b, {1, 1}] == InverseFourier[Fourier[a] Fourier[b]] Sqrt[31]

生成两个随机向量：

Wolfram Language code: {a, b} = RandomReal[1, {2, 31}];

用于从向量构造下三角托普利兹矩阵的函数：

Wolfram Language code: lttoep[v_] := With[{n = Length[v]}, ToeplitzMatrix[v, First[v]UnitVector[n, 1]]]

带零填充的循环卷积相当于与下三角托普利兹矩阵相乘：

Wolfram Language code: ListConvolve[a, b, 1, 0] == lttoep[a].b

与单个元素的卷积：

Wolfram Language code: ListConvolve[{1}, {1, 2, 3, 4, 5, 6}]
Wolfram Language code: ListConvolve[{1}, {1, 2, 3, 4, 5, 6}, 2]

长度和数据相同的核（无延伸）类似一个颠倒的点积：

Wolfram Language code: ListConvolve[{x, y, z}, {a, b, c}]

连续差分：

Wolfram Language code: ListConvolve[{1, -1}, {a, b, c, d, e}]
Wolfram Language code: Differences[{a, b, c, d, e}]

与连续元素对齐：

Wolfram Language code: Table[ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, i], {i, 3}]//Column
Wolfram Language code: Table[ListConvolve[{x, y, z}, {1, 2, 3, 4, 5, 6}, i], {i, -3, -1}]//Column

改变对齐方式：

Wolfram Language code: Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {i, j}], {i, 4}, {j, 4}]//Grid
Wolfram Language code: Grid[Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {i, -j}], {i, 4}, {j, 4}]]
Wolfram Language code: Grid[Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {-i, j}], {i, 4}, {j, 4}]]

改变对齐方式，并填充：

Wolfram Language code: Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {i, j}, 0], {i, 4}, {j, 4}]//Grid
Wolfram Language code: Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {i, -j}, 0], {i, 4}, {j, 4}]//Grid
Wolfram Language code: Table[ListConvolve[{1, 1}, {1, 1, 1, 1}, {-i, j}, 0], {i, 4}, {j, 4}]//Grid

可能存在的问题  (1)

在缺省情况下，输出的长度和输入不一致：

Wolfram Language code: ListConvolve[{1, 1}, {1, 2, 3, 4, 5}]

应用延伸，使得输出的长度和输入一致：

Wolfram Language code: ListConvolve[{1, 1}, {1, 2, 3, 4, 5}, 1]

在二维中应用延伸，使得输出的长度和输入一致：

Wolfram Language code: ListConvolve[{{1, 1}, {1, 1}}, {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, 1]
Wolfram Research (1999)，ListConvolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ListConvolve.html.

文本

Wolfram Research (1999)，ListConvolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ListConvolve.html.

CMS

Wolfram 语言. 1999. "ListConvolve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ListConvolve.html.

APA

Wolfram 语言. (1999). ListConvolve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ListConvolve.html 年

BibTeX

@misc{reference.wolfram_2026_listconvolve, author="Wolfram Research", title="{ListConvolve}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/ListConvolve.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_listconvolve, organization={Wolfram Research}, title={ListConvolve}, year={1999}, url={https://reference.wolfram.com/language/ref/ListConvolve.html}, note=[Accessed: 31-October-2026]}