WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

LocatorPane[{x,y},back]

{x,y}の位置にあるロケータと背景 back を含むペインを示す．

LocatorPane[Dynamic[pt],back]

動的に更新される pt の現行値をロケータの位置とする．ロケータが移動されると pt はリセットされる．

LocatorPane[{pt1,pt2,…},back]

位置 pt1, pt2, …にある複数のロケータを設定する．

LocatorPane[Dynamic[{pt1,pt2,…}],back]

ロケータ位置を動的に更新される pti の現行値とする．

LocatorPane[pts,back,{{xmin,ymin},{xmax,ymax}}]

ロケータ座標の範囲を指定する．

LocatorPane[pts,back,{{xmin,ymin},{xmax,ymax},{dx,dy}}]

ジャンプ dx, dy を使う．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
LocatorPaneのコンテンツ  
LocatorPaneのコントロール  
オプション  
Appearance  
AutoAction  
Background  
ContinuousAction  
Enabled  
LocatorAutoCreate  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

LocatorPane

LocatorPane[{x,y},back]

{x,y}の位置にあるロケータと背景 back を含むペインを示す．

LocatorPane[Dynamic[pt],back]

動的に更新される pt の現行値をロケータの位置とする．ロケータが移動されると pt はリセットされる．

LocatorPane[{pt1,pt2,…},back]

位置 pt1, pt2, …にある複数のロケータを設定する．

LocatorPane[Dynamic[{pt1,pt2,…}],back]

ロケータ位置を動的に更新される pti の現行値とする．

LocatorPane[pts,back,{{xmin,ymin},{xmax,ymax}}]

ロケータ座標の範囲を指定する．

LocatorPane[pts,back,{{xmin,ymin},{xmax,ymax},{dx,dy}}]

ジャンプ dx, dy を使う．

詳細とオプション

  • ロケータペインの背景はグラフィックスでも任意の式でもよい．
  • Graphicsオブジェクト g について，LocatorPane[pt,g]はデフォルトで，pt の座標範囲を g におけるPlotRangeに対応するグラフィックスの座標範囲であるとする．
  • 一般的な式については，LocatorPane[pt,expr]は pt の座標範囲が各方向に0から1であるとする．
  • 次のオプションを使うことができる．
  • Appearance Automaticロケータの外観
    AutoAction Falseマウスが上に来たときに，ロケータを自動的に動かすかどうか
    BaselinePositionAutomatic周囲のテキストのベースラインとどのように揃えるか
    BaseStyle{}ロケータペインのベーススタイル指定
    ContinuousAction Trueロケータが動かされている間，継続的に更新するかどうか
    Enabled Automaticロケータペインを有効にするか，そのロケータを無効（灰色表示）にするか
    Exclusions{}除外する特定の点
    LocatorAutoCreate Falseクリックによる新たなロケータの作成を許容するかどうか
    TouchscreenAutoZoomFalseタッチスクリーン上でアクティベートされた場合にフルスクリーンにズームするかどうか
  • Appearance->g の設定の場合，ロケータペイン中のすべてのロケータが g として表示される．ただし，g は任意のグラフィックスまたは他の式である． »
  • Appearance->{g1,g2,…}の場合は，i 番目のロケータが gi として表示される． »
  • LocatorPane[{pt1,pt2,…},back,{range1,range2,…}]は，ロケータによって異なる範囲を指定する．
  • LocatorPane[pts,back,range]は，デフォルトで，任意のクリックを直近のロケータに向ける．
  • BaseStyleの設定値は，一般に現行スタイルシートの"LocatorPane"スタイルで与えられるデフォルトスタイルに加えられる．

例題

すべて開く すべて閉じる

例  (2)

ロケータが1つで背景画像が円板のロケータペインを作成する：

Wolfram Language code: LocatorPane[{1, 1} / 2, Graphics[{Gray, Disk[]}]]

複数のロケータを作る：

Wolfram Language code: LocatorPane[{{1, 1} / 2, {-1, 1} / 2, {1, -1} / 2}, Graphics[{Gray, Disk[]}]]

Dynamicを使ってロケータ位置を変数と繋ぐ：

Wolfram Language code: DynamicModule[{pt = {1, 1} / 2}, {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}]], Dynamic[pt]}]

複数のロケータに同じことをする：

Wolfram Language code: DynamicModule[{pt = {{1, 1} / 2, {-1, 1} / 2, {1, -1} / 2}}, {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}]], Dynamic[pt]}]

スコープ  (8)

LocatorPaneのコンテンツ  (2)

背景としてグラフィックスを使う：

Wolfram Language code: LocatorPane[{5, 0.5}, Plot[Sin[x], {x, 0, 10}]]

空のグラフィックスを入れる：

Wolfram Language code: LocatorPane[{1, 1} / 2, Framed@Graphics[]]

任意の式を背景として使う：

Wolfram Language code: LocatorPane[{0.5, 0.5}, Graphics3D[Sphere[]]]
Wolfram Language code: LocatorPane[{.2, .6}, MatrixForm[HilbertMatrix[3]]]

LocatorPaneのコントロール  (6)

ロケータの座標範囲を指定する：

Wolfram Language code: LocatorPane[{1, 1} / 2, Graphics[{Gray, Disk[]}], {{-1, -1} / 2, {1, 1} / 2}]

ロケータの範囲とジャンプサイズの両方を指定する：

Wolfram Language code: LocatorPane[{1, 1} / 2, Graphics[{Gray, Disk[]}], {{-1, -1} / 2, {1, 1} / 2, {1 / 5, 1 / 5}}]

ロケータの外観として任意の式を使う：

Wolfram Language code: LocatorPane[{1, 1} / 2, Graphics[{Gray, Disk[]}], Appearance -> Framed[x + y]]

複数のロケータを使う：

Wolfram Language code: LocatorPane[{{0, 1 / 2}, {1 / 2, 0}, {0, 0}}, Graphics[{Gray, Disk[]}]]

動的な設定を使う：

Wolfram Language code: {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}]], Dynamic[pt]}

Slider2Dに動的な設定値を接続する：

Wolfram Language code: {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}]], Slider2D[Dynamic[pt], {-1, 1}]}

オプション  (15)

Appearance  (3)

LocatorPane中のロケータの外観として任意の式を使う：

Wolfram Language code: Table[LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}], Appearance -> a], {a, {Style["", Large], "文字列", Framed[x + y], Graphics[Rectangle[], ImageSize -> 20]}}]

異なる外観の複数のロケータ：

Wolfram Language code: LocatorPane[{{-1, 0}, {1, 0}, {0, 1}} / 2, Graphics[{Gray, Disk[]}], Appearance -> {Style["", Large], "文字列", Framed[x + y]}]

不可視のロケータにAppearance->Noneを使う：

Wolfram Language code: LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}], Appearance -> None]

条件付きの動きを実装するために不可視のロケータを使う：

Wolfram Language code: LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[], Red, PointSize[Large], Dynamic[Point[Normalize[pt]]]}, PlotRange -> 1.2], Appearance -> None]

AutoAction  (2)

デフォルトで，ロケータはロケータペインがクリックされるまで変化しない：

Wolfram Language code: LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}]]

AutoActionと設定すると，ロケータはロケータペイン上をマウスが動くと変化する：

Wolfram Language code: LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}], AutoAction -> True]

Background  (2)

背景色を変える：

Wolfram Language code: Table[LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}], Background -> c], {c, {Pink, Green, Yellow}}]

背景色を動的に変える：

Wolfram Language code: LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}], Background -> Dynamic[Hue[Norm[pt]]]]

ContinuousAction  (2)

デフォルトで，変数は連続的に更新される：

Wolfram Language code: {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}]], Dynamic[pt]}

ContinuousActionをFalseにすると，変数はロケータが解放されたときだけ更新されるようになる：

Wolfram Language code: {LocatorPane[Dynamic[pt], Graphics[{Gray, Disk[]}], ContinuousAction -> False], Dynamic[pt]}

Enabled  (2)

デフォルトで，LocatorPaneは有効になっている：

Wolfram Language code: LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}]]

Enabled->Falseとすると，ロケータは無効となり現行状態が可視で残る：

Wolfram Language code: LocatorPane[{0, 0}, Graphics[{Gray, Disk[]}], Enabled -> False]

LocatorAutoCreate  (4)

デフォルトで，ロケータペインをクリックするごとに一番近いロケータが動く：

Wolfram Language code: DynamicModule[{pts = {{-1, 1} / 2, {1, 1} / 2}}, LocatorPane[Dynamic[pts], Framed@Graphics[{}]]]

LocatorAutoCreate->Trueと設定すると，Alt+Clickを使ってロケータを作ったり削除したりできる：

Wolfram Language code: DynamicModule[{pts = {{-1, 1} / 2, {1, 1} / 2}}, LocatorPane[Dynamic[pts], Framed@Graphics[{}], LocatorAutoCreate -> True]]

LocatorAutoCreate->Allにすると，クリックごとに新たなロケータが作成される（削除にはAlt+Clickを使う）：

Wolfram Language code: DynamicModule[{pts = {{-1, 1} / 2, {1, 1} / 2}}, LocatorPane[Dynamic[pts], Framed@Graphics[{}], LocatorAutoCreate -> All]]

すべてのロケータを通るインタラクティブなプロットを作成する：

Wolfram Language code: DynamicModule[{pts = {{0, 0}, {3, 2}}}, LocatorPane[Dynamic[pts], Dynamic[Plot[InterpolatingPolynomial[pts, x], {x, 0, 3}, PlotRange -> 3]], LocatorAutoCreate -> True]]

アプリケーション  (6)

移動可能なランダムな点の配列を設定する：

Wolfram Language code: DynamicModule[{pt = RandomReal[{-1, 1}, {100, 2}]}, LocatorPane[Dynamic[pt], Graphics[{}, PlotRange -> 1], Appearance -> "∘"]]

曲線に従うように制約されたロケータを作る：

Wolfram Language code: LocatorPane[Dynamic[pt], Plot[Sin[x], {x, 0, 10}, Epilog -> {PointSize[Large], Point[Dynamic[{First[pt], Sin[First[pt]]}]]}], Appearance -> None]

CurrentValue["CurrentLocatorPaneThumb"]を使って点によって異なるドラッグ制限を矯正する：

Wolfram Language code: DynamicModule[{pts = {{0, 0}, {1 / 2, 0}}}, {LocatorPane[Dynamic[pts, Switch[CurrentValue["CurrentLocatorPaneThumb"], 1, pts[[1, 2]] = #[[1, 2]], 2, pts[[2]] = #[[2]]]&], Graphics[{Gray, Disk[]}]], Dynamic[pts]}]

微分方程式 の線形系の解を可視化する：

Wolfram Language code: DynamicModule[{pt = {1, 0}, A = (| | | | ---- | --- | | -1.1 | 0.9 | | -1.4 | 0.3 |)}, LocatorPane[Dynamic[pt], Dynamic@ParametricPlot[MatrixExp[A t, pt], {t, 0, 10}, PlotRange -> 5]]]

インタラクティブな曲線はプロットにフィットする：

Wolfram Language code: DynamicModule[{pts = {{0, 0}, {1, 1}, {2, 0}, {3, 2}}}, LocatorPane[Dynamic[pts], Dynamic[Plot[InterpolatingPolynomial[pts, x], {x, 0, 3}, PlotRange -> 3]]]]

インタラクティブな3つの点の円 [詳細]：

Wolfram Language code: createCircle[{{x1_, y1_}, {x2_, y2_}, {x3_, y3_}}] := With[{a = Det[(| | | | | -- | -- | - | | x1 | y1 | 1 | | x2 | y2 | 1 | | x3 | y3 | 1 |)], d = -Det[(| | | | | ----------- | -- | - | | x1^2 + y1^2 | y1 | 1 | | x2^2 + y2^2 | y2 | 1 | | x3^2 + y3^2 | y3 | 1 |)], e = Det[(| | | | | ----------- | -- | - | | x1^2 + y1^2 | x1 | 1 | | x2^2 + y2^2 | x2 | 1 | | x3^2 + y3^2 | x3 | 1 |)], f = -Det[(| | | | | ----------- | -- | -- | | x1^2 + y1^2 | x1 | y1 | | x2^2 + y2^2 | x2 | y2 | | x3^2 + y3^2 | x3 | y3 |)]}, Circle[{-(d/2 a), -(e/2 a)}, Sqrt[(d^2 + e^2/4a^2) - (f/a)]]]
Wolfram Language code: DynamicModule[{pts = {{-1, 0}, {1, 0}, {1, 1}}}, LocatorPane[Dynamic[pts], Framed@Graphics[{Dynamic[createCircle[pts]], Point[Dynamic[pts]]}, PlotRange -> 5]]]

特性と関係  (2)

LocatorPaneはEventHandlerの特殊ケースである：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, LocatorPane[Dynamic[pt], Framed@Graphics[{}, PlotRange -> 10]]]
Wolfram Language code: DynamicModule[{pt = {0, 0}}, Deploy@EventHandler[Framed@Graphics[Disk[Dynamic[pt]], PlotRange -> 10], {"MouseDown" :> (pt = MousePosition["Graphics"]), "MouseDragged" :> (pt = MousePosition["Graphics"])}]]

Settingを使ってLocatorPaneの設定値を抽出する：

Wolfram Language code: Setting[LocatorPane[{1, 1} / 2, Graphics[{Gray, Disk[]}]]]
Wolfram Language code: Setting[LocatorPane[{{0, 1}, {1, 0}}, Graphics[{Gray, Disk[]}]]]

おもしろい例題  (3)

AutoActionを使ってマウス点に最も近いロケータを選ぶ：

Wolfram Language code: LocatorPane[RandomReal[{-1, 1}, {50, 2}], Graphics[{Gray, Disk[]}], Appearance -> Table[Style["●", Hue[h / 50]], {h, 50}], AutoAction -> True]

ロケータを円に制限する：

Wolfram Language code: DynamicModule[{pt = {0, 1}}, LocatorPane[Dynamic[pt], Graphics[{Circle[], PointSize[Large], Dynamic[Point[pt / Norm[pt]]]}], Appearance -> None]]

微分方程式 の線形系の解を可視化する：

Wolfram Language code: DynamicModule[{pt = {{2, 0}, {0, 1}, {-3, 0}}, A = (| | | | ---- | --- | | -1.1 | 0.9 | | -1.4 | 0.3 |)}, LocatorPane[Dynamic[pt], Dynamic@ParametricPlot[Evaluate[MatrixExp[A t, #]& /@ pt], {t, 0, 10}, PlotRange -> 5]]]
Wolfram Research (2007), LocatorPane, Wolfram言語関数， https://reference.wolfram.com/language/ref/LocatorPane.html （2012年に更新）.

テキスト

Wolfram Research (2007), LocatorPane, Wolfram言語関数， https://reference.wolfram.com/language/ref/LocatorPane.html （2012年に更新）.

CMS

Wolfram Language. 2007. "LocatorPane." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/LocatorPane.html.

APA

Wolfram Language. (2007). LocatorPane. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LocatorPane.html

BibTeX

@misc{reference.wolfram_2026_locatorpane, author="Wolfram Research", title="{LocatorPane}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/LocatorPane.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_locatorpane, organization={Wolfram Research}, title={LocatorPane}, year={2012}, url={https://reference.wolfram.com/language/ref/LocatorPane.html}, note=[Accessed: 09-August-2026]}