WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

e1||e2||…

論理和（OR関数）である．これは，与えられた引数を順に評価していき，いずれかがTrueを与えると直ちにTrueを返し，すべてがFalseを与えるとFalseを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Or

e1||e2||…

論理和（OR関数）である．これは，与えられた引数を順に評価していき，いずれかがTrueを与えると直ちにTrueを返し，すべてがFalseを与えるとFalseを返す．

詳細

  • Or[e1,e2,…]は，e_(1)∨e_(2)∨...としてStandardFormとInputFormに入力することができる．記号∨は||，orまたは\[Or]として入力される．
  • Orは属性HoldAllを持ち，引数の評価を明示的に制御する．e_(1)||e_(2)||...において，e_(i)は順番に評価さる．そのいずれかがTrueと判明した時点で評価は中止される．
  • Orは，必要に応じてFalseである初期の引数を削除し，記号的な結果を与える．

例題

すべて開く すべて閉じる

例  (4)

2つのアサーションを||で繋ぐ：

Wolfram Language code: 1 > 2 || Pi > 3

記号的論理和：

Wolfram Language code: a || b || !c

方程式系：

Wolfram Language code: x + 2y == 3 || 4x + 5y == 6

orを使って入力する：

Wolfram Language code: p∨q

スコープ  (5)

Orは，引数がいくつでも構わない：

Wolfram Language code: Or[x, y, z]

Orは結合である：

Wolfram Language code: Or[x, Or[y, z]]//FullForm

明示的なTrueあるいはFalse引数を持つOrは簡約される：

Wolfram Language code: Or[x, False, z]
Wolfram Language code: Or[x, True, z]

Orは引数を順に評価し，引数の評価がTrueとなったところで停止する：

Wolfram Language code: Or[Print[1];True, Print[2];False]
Wolfram Language code: Or[Print[1];False, Print[2];False]

引数順が重要なことがある：

Wolfram Language code: x == 0 || y == 1 / x /. x -> 0
Wolfram Language code: y == 1 / x || x == 0 /. x -> 0

記号的な変換では引数順は保存されない：

Wolfram Language code: z || y || y || x
Wolfram Language code: Simplify[%]

TraditionalFormによる表示：

Wolfram Language code: x || y || z//TraditionalForm

アプリケーション  (6)

Wolfram言語プログラムで条件を連結する：

Wolfram Language code: NotRealNegativeQ[x_ ? NumberQ] := Head[x] === Complex || x ≥ 0
Wolfram Language code: NotRealNegativeQ[-2]

Orの引数を評価するとTrueになる場合，続く引数は評価されない：

Wolfram Language code: NotRealNegativeQ[I]

Orの引数順は重要である．最後の2引数の順序を入れ替えるとI≥0が評価される：

Wolfram Language code: NotRealNegativeQ2[x_ ? NumberQ] := x ≥ 0 || Head[x] === Complex
Wolfram Language code: NotRealNegativeQ2[I]

仮定を結合する：

Wolfram Language code: Refine[Sqrt[(x ^ 2 - 1) ^ 2], x ≤ -1 || x ≥ 1]

方程式と不等式を結合する．Orは入力と出力の両方に使われている：

Wolfram Language code: Reduce[x ^ 2 == 1 || x ^ 3 ≤ 1 / 8, x, Reals]

||を使って条件を結合する：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 || x + y > 0, {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: RegionPlot3D[x ^ 2 + y ^ 2 + z ^ 2 < 1 || (x - 1) ^ 2 + y ^ 2 + z ^ 2 < 1, {x, -1, 2}, {y, -1, 1}, {z, -1, 1}]

Orに基づいたセルオートマトン：

Wolfram Language code: ArrayPlot[Boole[CellularAutomaton[{Or@@#&, {}}, {{True}, False}, 20]]]

代数条件で与えられた集合の共通部分の面積を求める：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 < 1 || (x - 1) ^ 2 + y ^ 2 < 2], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

集合を示す：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 || (x - 1) ^ 2 + y ^ 2 < 2, {x, -1.5, 2.5}, {y, -2, 2}]

特性と関係  (7)

2引数のOrの真理値表：

Wolfram Language code: BooleanTable[{x, y, Or[x, y]}, {x, y}]//Grid

3引数のOr：

Wolfram Language code: BooleanTable[{x, y, z, Or[x, y, z]}, {x, y, z}]//Grid

引数がないOrはFalseである：

Wolfram Language code: Or[]

1引数のOrは，値にかかわらず，引数を評価して返す：

Wolfram Language code: Or[2 + 2]

&&は||より優先順位が高い：

Wolfram Language code: p || q && r//FullForm

BooleanConvertを使ってAndをOrについて展開する：

Wolfram Language code: (a || b) && (c || d || e)
Wolfram Language code: BooleanConvert[%]

ド・モルガン(De Morgan)の法則はAnd，Or，Notを関連付ける：

Wolfram Language code: BooleanConvert[!(a && b)]
Wolfram Language code: BooleanConvert[!(a || b || c)]

条件の論理和はBoole関数の最大のもの(Max)に相当する：

Wolfram Language code: Max[Boole[a], Boole[b]] - Boole[a || b]
Wolfram Language code: Simplify[%]
Wolfram Research (1988), Or, Wolfram言語関数， https://reference.wolfram.com/language/ref/Or.html （1996年に更新）.

テキスト

Wolfram Research (1988), Or, Wolfram言語関数， https://reference.wolfram.com/language/ref/Or.html （1996年に更新）.

CMS

Wolfram Language. 1988. "Or." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Or.html.

APA

Wolfram Language. (1988). Or. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Or.html

BibTeX

@misc{reference.wolfram_2026_or, author="Wolfram Research", title="{Or}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Or.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_or, organization={Wolfram Research}, title={Or}, year={1996}, url={https://reference.wolfram.com/language/ref/Or.html}, note=[Accessed: 04-November-2026]}