WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

PillaiTraceTest[m1,m2]

行列 m1と m2が独立かどうかの検定を行う．

PillaiTraceTest[…,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
Method  
SignificanceLevel  
VerifyTestAssumptions  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

PillaiTraceTest

PillaiTraceTest[m1,m2]

行列 m1と m2が独立かどうかの検定を行う．

PillaiTraceTest[…,"property"]

"property"の値を返す．

詳細とオプション

  • PillaiTraceTestは，m1と m2に対して，行列が線形独立であるという帰無仮説 と，そうではないという対立仮説 で仮説検定を行う．
  • デフォルトで，確率値つまり 値が返される．
  • 小さい 値は が真である可能性が低いことを示す．
  • 引数 v1と v2は任意の同じ長さの実ベクトルあるいは実行列でよい．
  • PillaiTraceTestはPillaiTrace[m1,m2]で計算されたPillaiのトレースの統計量に基づく．
  • PillaiTraceTest[m1,m2,"HypothesisTestData"]はHypothesisTestDataオブジェクト htd を返す．このオブジェクトは，htd["property"] の形を使って追加的な検定結果と特性の抽出に使うことができる．
  • PillaiTraceTest[m1,m2,"property"]を使って"property"の値を直接与えることができる．
  • 検定結果のレポートに関連する特性
  • "DegreesOfFreedom"検定に使われる自由度
    "PValue"検定の 値
    "PValueTable" 値を含むフォーマットされた表
    "ShortTestConclusion"検定結果の短い記述
    "TestConclusion"検定結果の記述
    "TestData"検定統計量と 値を含むリスト
    "TestDataTable" 値と検定統計量のフォーマットされた表
    "TestStatistic"検定統計量
    "TestStatisticTable"検定統計量のフォーマットされた表
  • 使用可能なオプション
  • Method Automatic 値の計算に使うメソッド
    SignificanceLevel 0.05診断とレポートのための切捨て
    VerifyTestAssumptions Automatic検証する仮定
  • 独立性の検定については， のときにのみ が拒絶されるような切捨て が選ばれる．"TestConclusion"特性と"ShortTestConclusion"特性に使われる の値はSignificanceLevelオプションで制御される． の値は正規性の診断検定にも使われる．デフォルトで， は0.05に設定されている．
  • IndependenceTestにおけるVerifyTestAssumptionsのための名前付き設定
  • "Normality"すべてのデータが正規分布に従っているかどうか検証する

例題

すべて開く すべて閉じる

例  (2)

2つのベクトルが独立かどうかの検定を行う：

Wolfram Language code: v1 = RandomVariate[NormalDistribution[], 10^3]; v2 = RandomVariate[NormalDistribution[], 10^3];
Wolfram Language code: ListPlot[Transpose[{v1, v2}]]
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "TestDataTable"]

2つの行列が独立かどうかの検定を行う：

Wolfram Language code: BlockRandom[ SeedRandom[2]; data1 = RandomVariate[BinormalDistribution[.5], 100]; data2 = RandomVariate[BinormalDistribution[.5], 100]; ]

0.05水準での独立性を棄却するための証拠は不十分である：

Wolfram Language code: PillaiTraceTest[data1, data2, "TestDataTable"]

スコープ  (8)

検定  (5)

2つのベクトルが独立かどうかの検定を行う：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: {v3, v4} = Transpose[RandomVariate[BinormalDistribution[.7], 100]];

ベクトルが独立しているときは 値が一般に大きくなる：

Wolfram Language code: PillaiTraceTest[v1, v2]

ベクトルが従属しているときは 値が一般に小さくなる：

Wolfram Language code: PillaiTraceTest[v3, v4]

2つの行列が独立しているかどうかの検定を行う：

Wolfram Language code: Σ1 = {{12.8, 0.3, 3., -1.5, 5.1}, {0.3, 2.4, 0.9, -0.3, -0.8}, {3., 0.9, 6.5, 0.8, 1.3}, {-1.5, -0.3, 0.8, 1.4, 2.}, {5.1, -0.8, 1.3, 2., 11.1}};
Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ1], 100];

行列が従属しているときは 値が一般に小さくなる：

Wolfram Language code: PillaiTraceTest[data1[[All, 1 ;; 2]], data1[[All, 3 ;; 5]]]

行列が独立しているときは 値が一般に大きくなる：

Wolfram Language code: Σ2 = IdentityMatrix[5];
Wolfram Language code: data2 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ2], 100];
Wolfram Language code: PillaiTraceTest[data2[[All, 1 ;; 2]], data2[[All, 3 ;; 5]]]

繰り返し特性を抽出するためにHypothesisTestDataオブジェクトを作成する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];

抽出可能な特性：

Wolfram Language code: ℋ["Properties"]

HypothesisTestDataオブジェクトからいくつかの特性を抽出する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];

値と検定統計量：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

任意数の特性を同時に抽出する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];

値と検定統計量：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

レポート  (3)

検定からの結果を表にする：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];

検定結果の表：

Wolfram Language code: ℋ["TestDataTable"]

レポートをカスタマイズするために検定の表から項目を取り出す：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[.1], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: res = ℋ["TestData"]
Wolfram Language code: Labeled[ProgressIndicator[res[[2]]], Row[{Style["Pillai Trace: ", Bold, FontSize -> 14], res[[1]]}]]

値あるいは検定統計量を表にする：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = PillaiTraceTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

表からの 値：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

表からの検定統計量：

Wolfram Language code: ℋ["TestStatistic"]

オプション  (10)

Method  (4)

デフォルトで， 値は漸近的検定統計分布を使って計算される：

Wolfram Language code: {v1, v2} = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100];
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> Automatic]
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> "Asymptotic"]

値は置換法を使って得ることができる：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> "Permutation"]

使用する置換回数を設定する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^4}]

デフォルトで，回のランダムな置換が使われる：

Wolfram Language code: PillaiTraceTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^3}]
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> Automatic}]

ランダム置換を生成するためのシードを設定する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 0}]
Wolfram Language code: PillaiTraceTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 9}]

SignificanceLevel  (2)

診断検定のための有意水準を設定する：

Wolfram Language code: BlockRandom[SeedRandom[2];{v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];];
Wolfram Language code: PillaiTraceTest[v1, v2, SignificanceLevel -> .0001]

デフォルトで0.05が使われる．このメッセージは2つの検定が行われたので0.025を示している：

Wolfram Language code: PillaiTraceTest[v1, v2]

"TestConclusion"と"ShortTestConclusion"にも有意水準が使われる：

Wolfram Language code: BlockRandom[SeedRandom[3];{v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 100]];];
Wolfram Language code: ℋ1 = PillaiTraceTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = PillaiTraceTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .000005];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (4)

デフォルトで適切な場合には正規性の検定が行われる：

Wolfram Language code: BlockRandom[SeedRandom[2];{v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];];
Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> Automatic]

診断はAllあるいはNoneを使ってまとめて制御される：

Wolfram Language code: BlockRandom[SeedRandom[2];{v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];];

すべての仮定を検証する：

Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> All]

仮定は検証しない：

Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> None]

診断は個別に制御することができる：

Wolfram Language code: BlockRandom[SeedRandom[2];{v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];];

正規性について検証する：

Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> "Normality"]

診断結果を明示的に設定する：

Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> {"Normality" -> True}]
Wolfram Language code: PillaiTraceTest[v1, v2, VerifyTestAssumptions -> {"Normality" -> False}]

シミュレーション目的の場合は診断検定をバイパスしたほうがよいことが多い：

Wolfram Language code: BlockRandom[SeedRandom[2];data = RandomVariate[BinormalDistribution[0], {100, 35}]];
Wolfram Language code: AbsoluteTiming[T = PillaiTraceTest[Sequence@@Transpose[#]]& /@ data;]//Quiet

検定の仮定は設計上有効になっているので，時間が大幅に削減できる：

Wolfram Language code: AbsoluteTiming[T2 = PillaiTraceTest[Sequence@@Transpose[#], VerifyTestAssumptions -> None]& /@ data;]//Quiet

結果は等しい：

Wolfram Language code: SmoothHistogram[{T, T2}, PlotStyle -> {Thick, Dashed}]

特性と関係  (4)

PillaiTraceTestはPillaiTraceを使って検定棟計量を測る：

Wolfram Language code: n = 500;
Wolfram Language code: m1 = RandomVariate[BinormalDistribution[0], n]; m2 = RandomVariate[BinormalDistribution[0], n];
Wolfram Language code: t = PillaiTraceTest[m1, m2, "TestStatistic"]
Wolfram Language code: PillaiTrace[m1, m2]

値はChiSquareDistribution[r*s]を使って計算される：

Wolfram Language code: r = Dimensions[m1][[2]]; s = Dimensions[m2][[2]];
Wolfram Language code: SurvivalFunction[ChiSquareDistribution[r * s], n t]
Wolfram Language code: PillaiTraceTest[m1, m2]

PillaiTraceTestはIndependenceTestで使用可能な検定の一つである：

Wolfram Language code: BlockRandom[SeedRandom[2]; m1 = RandomVariate[BinormalDistribution[0], 50]; m2 = RandomVariate[BinormalDistribution[0], 50]; ]
Wolfram Language code: IndependenceTest[m1, m2, {"TestDataTable", All}]

IndependenceTestを使って検定の選択を自動化することができる：

Wolfram Language code: IndependenceTest[m1, m2, "TestDataTable"]

Pillaiのトレース検定は，入力がTimeSeriesのときにのみ値に使うことができる：

Wolfram Language code: ts1 = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ts2 = TemporalData[TimeSeries, {{{-1.2160757838495546, 0.5212591188357838, -0.0932747538180776, -2.306367634798702, -2.5366722726947994, -0.7924813212437647, -2.65435901675047, -1.1098678592653723, -0.7814091835518528, -1.9685555851254093, -0.0 ... 1001061264, -0.1887471329804458, -2.0547107874294928, -1.3896240275653011, -0.5073077090484948, 0.13302942350391606}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: PillaiTraceTest[ts1, ts2]
Wolfram Language code: PillaiTraceTest[ts1["Values"], ts2["Values"]]

Pillaiのトレース検定は，入力がTemporalDataのときはすべての値に同時に使うことができる：

Wolfram Language code: td = TemporalData[Automatic, {{{0.6327956976018951, 0.49307164456668334, -0.11865815946302549, -1.6346246228913748, -1.8053674367955113, -1.0171193599509663, -1.713536030590108, -0.2441834126183119, 1.468610531363788, 2.5403283801476966, 0.862 ... 135928877112, 0.8411464201445826, 0.36308201253335104, -0.45737292436875443, 0.289078430933834, 0.12996366812717347}}, {{0, 100, 1}}, 4, {"Continuous", 4}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: PillaiTraceTest[td]

時間データの選択された成分について明示的な検定を行う：

Wolfram Language code: paths = td["Components"]
Wolfram Language code: PillaiTraceTest[paths[[2]], paths[[3]]]

値を直接使う：

Wolfram Language code: {data[1], data[2], data[3], data[4]} = td["ValueList"];
Wolfram Language code: PillaiTraceTest[data[2], data[3]]

おもしろい例題  (1)

帰無仮説 が真であるときの統計量を計算する：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[0.], {1500, 100}];
Wolfram Language code: T1 = MapThread[PillaiTraceTest[#1, #2, "TestStatistic", VerifyTestAssumptions -> None]&, {data1[[All, All, 1]], data1[[All, All, 2]]}];

特定の対立仮説による検定統計：

Wolfram Language code: data2 = RandomVariate[BinormalDistribution[0.7], {1500, 100}];
Wolfram Language code: T2 = MapThread[PillaiTraceTest[#1, #2, "TestStatistic", VerifyTestAssumptions -> None]&, {data2[[All, All, 1]], data2[[All, All, 2]]}];

検定統計の分布を比較する：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0]は真", "SubscriptBox[H, 0]は偽"}]
Wolfram Research (2012), PillaiTraceTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/PillaiTraceTest.html.

テキスト

Wolfram Research (2012), PillaiTraceTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/PillaiTraceTest.html.

CMS

Wolfram Language. 2012. "PillaiTraceTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PillaiTraceTest.html.

APA

Wolfram Language. (2012). PillaiTraceTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PillaiTraceTest.html

BibTeX

@misc{reference.wolfram_2026_pillaitracetest, author="Wolfram Research", title="{PillaiTraceTest}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/PillaiTraceTest.html}", note=[Accessed: 13-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_pillaitracetest, organization={Wolfram Research}, title={PillaiTraceTest}, year={2012}, url={https://reference.wolfram.com/language/ref/PillaiTraceTest.html}, note=[Accessed: 13-November-2026]}