WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

PolygonalNumber[n]

n 番目の三角数 を与える．

PolygonalNumber[r,n]

n 番目の r 角数 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

PolygonalNumber

PolygonalNumber[n]

n 番目の三角数 を与える．

PolygonalNumber[r,n]

n 番目の r 角数 を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • PolygonalNumber[n]は，一般に，TemplateBox[{{n, +, 1}, 2}, Binomial]と定義できる．
  • PolygonalNumber[r,n]は，一般に，と定義できる．
  • PolygonalNumber[r,n]は，r 本の辺を有する n-1多角形の形に並べられた点の数として解釈することができる．例えば r=3で n=4の場合は以下となる．
  • PolygonalNumberは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (2)

最初の10個の三角数を返す：

Wolfram Language code: Table[PolygonalNumber[n], {n, 10}]

いくつかの正多角形の10番目の r 角数を返す：

Wolfram Language code: Table[PolygonalNumber[r, 10], {r, 3, 10}]

スコープ  (4)

PolygonalNumberを整数の引数とともに使う：

Wolfram Language code: PolygonalNumber[5, 3]
Wolfram Language code: PolygonalNumber[3, 5]

RegularPolygonを使って正多角形の辺の数を指定する：

Wolfram Language code: PolygonalNumber[RegularPolygon[5], 3]
Wolfram Language code: PolygonalNumber[RegularPolygon[{0, 3}, 2, 5], 3]

PolygonalNumberは自動的にリストに縫い込まれる：

Wolfram Language code: PolygonalNumber[4, Range[5, 10]]
Wolfram Language code: PolygonalNumber[Range[10, 20, 2], Range[5, 10]]

PolygonalNumberを記号入力とともに使う：

Wolfram Language code: PolygonalNumber[r, n]

アプリケーション  (2)

八角数をランダムに生成する：

Wolfram Language code: SeedRandom[1]; numbers = RandomInteger[100, 10]; PolygonalNumber[8, numbers]

最初の50個の三角数，四角数，五角数をプロットする：

Wolfram Language code: DiscretePlot[{PolygonalNumber[3, n], PolygonalNumber[4, n], PolygonalNumber[5, n]}, {n, 1, 50}, PlotLegends -> {"Triangular", "Square", "Pentagonal"}]

特性と関係  (9)

任意の多角形の0番目の多角数は0である：

Wolfram Language code: Table[PolygonalNumber[r, 0], {r, 3, 10}]

任意の正多角形の最初の多角数は1である：

Wolfram Language code: Table[PolygonalNumber[r, 1], {r, 3, 10}]

三角数は1つおきに六角数である：

Wolfram Language code: numbers = Range[100]; PolygonalNumber[2numbers - 1] == PolygonalNumber[6, numbers]

連続する2つの三角数の和は四角数である：

Wolfram Language code: numbers = Range[100]; PolygonalNumber[numbers - 1] + PolygonalNumber[numbers] == PolygonalNumber[4, numbers]

五角数はすべて三角数の三分の1である：

Wolfram Language code: numbers = Range[100]; PolygonalNumber[5, numbers] == 1 / 3 PolygonalNumber[3numbers - 1]

n 番目の r 角数と n 番目の (r+1)角数の差は(n-1)番目の三角数である：

Wolfram Language code: sides = Range[3, 102]; numbers = Range[100]; (PolygonalNumber[#1 + 1, #2] - PolygonalNumber[#1, #2] == PolygonalNumber[#2 - 1])&[sides, numbers]

偶数の完全数はメルセンヌ素数指数に関連している三角数である：

Wolfram Language code: mersennePrime[n_] := 2 ^ MersennePrimeExponent[n] - 1; range = Range[40];
Wolfram Language code: PerfectNumber[range, "Even"] == PolygonalNumber[mersennePrime[range]]

偶数の完全数はメルセンヌ素数指数に関連している六角数である：

Wolfram Language code: powertwo[n_] := 2 ^ (MersennePrimeExponent[n] - 1); range = Range[40];
Wolfram Language code: PerfectNumber[range, "Even"] == PolygonalNumber[6, powertwo[range]]

6より大きいすべての完全数は，k のある値について次の形式を取る：

Wolfram Language code: number[k_] := 1 + 9PolygonalNumber[8k + 2];
Wolfram Language code: PerfectNumber[2, "Even"] == number[0]
Wolfram Language code: PerfectNumber[3, "Even"] == number[1]
Wolfram Language code: PerfectNumber[4, "Even"] == number[5]
Wolfram Language code: PerfectNumber[5, "Even"] == number[341]
Wolfram Language code: PerfectNumber[6, "Even"] == number[5461]

おもしろい例題  (1)

多角数を可視化する：

Wolfram Language code: Manipulate[With[{ps = points[Range[0, n - 1], r]}, Labeled[Graphics[{PointSize[Large], Point /@ ps, Line /@ ps, Opacity[0.2], Polygon /@ ps}], PolygonalNumber[r, n]]], {{r, 4, "sides"}, 3, 10, 1}, {{n, 5, "steps"}, 1, 10, 1}, Initialization :> { points[0, r_] := {{0, 0}};points[n_Integer, r_] := Flatten[Subdivide[#1, #2, n]&@@@Partition[CirclePoints[-Last[CirclePoints[n, r]], n, r], 2, 1, 1], 1];points[ns_List, r_] := points[#, r]& /@ ns}]
Wolfram Research (2016), PolygonalNumber, Wolfram言語関数， https://reference.wolfram.com/language/ref/PolygonalNumber.html.

テキスト

Wolfram Research (2016), PolygonalNumber, Wolfram言語関数， https://reference.wolfram.com/language/ref/PolygonalNumber.html.

CMS

Wolfram Language. 2016. "PolygonalNumber." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PolygonalNumber.html.

APA

Wolfram Language. (2016). PolygonalNumber. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PolygonalNumber.html

BibTeX

@misc{reference.wolfram_2026_polygonalnumber, author="Wolfram Research", title="{PolygonalNumber}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/PolygonalNumber.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_polygonalnumber, organization={Wolfram Research}, title={PolygonalNumber}, year={2016}, url={https://reference.wolfram.com/language/ref/PolygonalNumber.html}, note=[Accessed: 09-November-2026]}