WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ReadByteArray[src]

src のコンテンツをByteArrayオブジェクトとして与える．

ReadByteArray[src,n]

src から最初の n バイトを読む．

ReadByteArray[src,term]

終端条件 term が満足されるまで読む．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
TimeConstraint  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ReadByteArray

ReadByteArray[src]

src のコンテンツをByteArrayオブジェクトとして与える．

ReadByteArray[src,n]

src から最初の n バイトを読む．

ReadByteArray[src,term]

終端条件 term が満足されるまで読む．

詳細とオプション

  • ReadByteArray[src,…]の src は，"filename"またはFile["filename"]として与えられるファイル，InputStreamのような入力指向ストリーム，あるいは頭部ProcessObjectを持つ外部プロセスでよい．
  • ReadByteArray["file",…]とReadByteArray[File["file"],…]は，"file"がまだ開かれていなければ読むためにこれを開く．その場合，デフォルトのターミネータであるEndOfFileが使われているなら，読み終るとファイルは閉じられる．
  • 終端条件 term は次のいずれでもよい．
  • nn バイトまで読む
    ByteArray[…]バイトのリテラル列に遭遇する
    EndOfBuffer読込み可能なコンテンツがなくなる
    EndOfFileソースの終端に達する（デフォルト）
    EndOfLine行末に相当するバイト列
    {term1,term2,…}termiのいずれか
  • 終端条件がバイト列からなる場合，その列は削除され，バイト配列の一部としては返されない．
  • ReadByteArray[src]またはReadByteArray[src,EndOfFile]は，現行位置から始めて，ストリームが終るまで，または入力を提供する外部プロセスが終了するまで読む．
  • ReadByteArrayがすでに尽きたコンテンツのソースに対して呼ばれた場合は，EndOfFileが返される．
  • ReadByteArrayは，デフォルトで，指定されたものが何であれ，それを読むまで何も返さないブロッキング関数である．
  • TimeConstraint->t のオプション設定のときは，ReadByteArrayは最大 t 秒待ってからそこまでに読んだものを返す．
  • ReadByteArray[src,EndOfBuffer]はブロックせず，入力バッファにあるものを，それが何であれ返す．

例題

すべて開く すべて閉じる

例  (2)

画像ファイルをバイト配列として読み込む：

Wolfram Language code: ba = ReadByteArray["ExampleData/rose.gif"]

バイト配列には，さらに操作するためのファイルのコンテンツが入っている：

Wolfram Language code: ImportByteArray[ba] == Import["ExampleData/rose.gif"]

テキストをファイルにエキスポートする：

Wolfram Language code: file = CreateFile[]; Export[file, "aαℵ", "Text"];

ファイルをバイト配列として読み込む：

Wolfram Language code: ba = ReadByteArray[file]

個々のバイトを見る：

Wolfram Language code: Normal[ba]

バイトを文字列に再変換する：

Wolfram Language code: ByteArrayToString[ba]

スコープ  (5)

WXFファイルを読み込む：

Wolfram Language code: ba = ReadByteArray["ExampleData/atoms.wxf"]

EndOfFileターミネータを明示的に指定してファイルを読み込む：

Wolfram Language code: % == ReadByteArray["ExampleData/atoms.wxf", EndOfFile]

データを式に変換する：

Wolfram Language code: BinaryDeserialize[ba]

「Alice in Wonderland」（不思議の国のアリス）の本文の最初の行をバイト配列として読み込む：

Wolfram Language code: ba = ReadByteArray["ExampleData/Text/AliceInWonderland.txt", EndOfLine]
Wolfram Language code: ByteArrayToString[ba]

本文の次の行を読む：

Wolfram Language code: ReadByteArray["ExampleData/Text/AliceInWonderland.txt", EndOfLine]

ファイルを閉じる：

Wolfram Language code: Close["ExampleData/Text/AliceInWonderland.txt"]

アメリカ合衆国憲法の最初の70バイトを読む：

Wolfram Language code: ba = ReadByteArray["ExampleData/USConstitution.txt", 70]

バイトをテキストに変換する：

Wolfram Language code: ByteArrayToString[%]

70バイトを読むまで，あるいは行の終りになるまで読む：

Wolfram Language code: ReadByteArray["ExampleData/USConstitution.txt", {70, EndOfLine}]

このプロセスを繰り返す：

Wolfram Language code: ReadByteArray["ExampleData/USConstitution.txt", {70, EndOfLine}]

ファイルを閉じる：

Wolfram Language code: Close["ExampleData/USConstitution.txt"]

StartProcessを使ってシステムシェルを開く：

Wolfram Language code: process = StartProcess[$SystemShell]

ウェルカムテキストがあれば，それを取り除く：

Wolfram Language code: ReadByteArray[process, EndOfBuffer]

出力を生成するプロセスにコマンドを書く：

Wolfram Language code: WriteString[process, "echo hello "];

使用可能な出力をバイト配列として読む：

Wolfram Language code: ReadByteArray[process, EndOfBuffer]

バイトを文字列に変換すると，それが行末文字を含むことが分かる：

Wolfram Language code: ByteArrayToString[%]

プロセスに再度コマンドを書く：

Wolfram Language code: WriteString[process, "echo hello "];

今回は，行末まで読む：

Wolfram Language code: ReadByteArray[process, EndOfLine]

バイト配列はもはや行末を符号化しない：

Wolfram Language code: ByteArrayToString[%]

プロセスを終了する：

Wolfram Language code: KillProcess[process]

ソケット接続を開く：

Wolfram Language code: socket = SocketConnect["http://exampledata.wolfram.com"]

ソケットにリクエストを書く：

Wolfram Language code: WriteString[socket, "GET /cellularautomaton.gif HTTP/1.0 "]

GIF89に相当するバイト列が読まれるまで読む：

Wolfram Language code: header = StringToByteArray["GIF89"]
Wolfram Language code: ReadByteArray[socket, header]

HTTPヘッダ内のデータをテキストに変換する：

Wolfram Language code: ByteArrayToString[%]//Short

残っている全バイトを読む：

Wolfram Language code: ReadByteArray[socket]

バイトとGIFヘッダを接合し，画像をインポートする：

Wolfram Language code: ImportByteArray[Join[header, %], "GIF"]

ソケットを閉じる：

Wolfram Language code: Close[socket]

オプション  (1)

TimeConstraint  (1)

シェルを開始し，スタートアップ時の出力を削除する：

Wolfram Language code: process = StartProcess[$SystemShell] ReadByteArray[process, EndOfBuffer];

5バイト読もうとするが，2秒後にはその時点までに得られたもので戻ることを強制する：

Wolfram Language code: ReadByteArray[process, 5, TimeConstraint -> 2]

シェルにコマンドを書き，これを出力させる：

Wolfram Language code: WriteString[process, "echo hello "]

時間的制約がある中で読もうとする．今回は5バイト読んですぐに戻る：

Wolfram Language code: ReadByteArray[process, EndOfLine, TimeConstraint -> 2]

プロセスを終了する：

Wolfram Language code: KillProcess[process]

特性と関係  (5)

ReadByteArray[src]は，事実上ByteArray[BinaryReadList[src]]に等しい：

Wolfram Language code: ReadByteArray["ExampleData/strings"] == ByteArray[BinaryReadList["ExampleData/strings"]]

ReadByteArray[src]は，事実上StringToByteArray[ReadString[src], "ISO8859-1"]に等しい：

Wolfram Language code: ReadByteArray["ExampleData/spikey.tiff"] == StringToByteArray[ReadString["ExampleData/spikey.tiff"], "ISO8859-1"]

ReadByteArray[src,n]は一度に n バイト読む：

Wolfram Language code: ba = ReadByteArray["ExampleData/strings", 10]

BinaryRead[src]は一度に1バイト読む：

Wolfram Language code: SetStreamPosition["ExampleData/strings", 0];
Wolfram Language code: table = Table[BinaryRead["ExampleData/strings"], 10]

データはReadByteArrayが読み込むものに等しい：

Wolfram Language code: ByteArray[table] == ba

ストリームを閉じる：

Wolfram Language code: Close["ExampleData/strings"];

ReadByteArray[src]は，事実上StringToByteArray[Import[src,"String"],"ISO8859-1"]に等しい：

Wolfram Language code: ReadByteArray["ExampleData/strings"] == StringToByteArray[Import["ExampleData/strings", "String"], "ISO8859-1"]

ImportByteArray[ReadByteArray[src]]は，事実上Import[src]に等しい：

Wolfram Language code: {ImportByteArray[ReadByteArray["ExampleData/spikey.tiff"]], Import["ExampleData/spikey.tiff"]}
Wolfram Research (2018), ReadByteArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReadByteArray.html.

テキスト

Wolfram Research (2018), ReadByteArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReadByteArray.html.

CMS

Wolfram Language. 2018. "ReadByteArray." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ReadByteArray.html.

APA

Wolfram Language. (2018). ReadByteArray. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ReadByteArray.html

BibTeX

@misc{reference.wolfram_2026_readbytearray, author="Wolfram Research", title="{ReadByteArray}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/ReadByteArray.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_readbytearray, organization={Wolfram Research}, title={ReadByteArray}, year={2018}, url={https://reference.wolfram.com/language/ref/ReadByteArray.html}, note=[Accessed: 06-November-2026]}