WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

expr//.rules

expr がこれ以上変わらなくなるまで，繰り返し置き換えを行う．

ReplaceRepeated[rules]

式に適用可能なReplaceRepeatedの演算子形である．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ReplaceRepeated

expr//.rules

expr がこれ以上変わらなくなるまで，繰り返し置き換えを行う．

ReplaceRepeated[rules]

式に適用可能なReplaceRepeatedの演算子形である．

詳細とオプション

  • expr//.rules は，効果的に，この結果が変わらなくなるまで，/.を繰り返し実行する．
  • 式に対して/.を使用してひと通り完全な手続きを実行した上で，次の手続きに移行する．
  • 演算子//.を使用するときには，無限ループを避けるように十分気を付けること．例えば，コマンドx//.x->x+1は，無限ループに陥る．
  • ReplaceRepeatedは，与えられた規則を適用する最大の回数を指定するオプションMaxIterationsを取り込む．このデフォルト設定はMaxIterations->65536である．MaxIterations->Infinityの設定では制限がない．
  • ReplaceRepeated[rules][expr]はReplaceRepeated[expr,rules]に等しい．

例題

すべて開く すべて閉じる

例  (3)

実数の対数についてベキと積の法則に関する規則を繰り返し適用する：

Wolfram Language code: rules = {Log[x_ y_] :> Log[x] + Log[y], Log[x_ ^ k_] :> k Log[x]};
Wolfram Language code: Log[Sqrt[a(b c ^ d) ^ e]] //. rules

ReplaceAllは置換を1回だけ行う：

Wolfram Language code: Log[Sqrt[a (b c ^ d) ^ e]] /. rules

ネストしたものも含め，出現したすべての頭部を削除する：

Wolfram Language code: {f[f[x]], f[x], g[f[x]], f[g[f[x]]]} //. f[x_] -> x

ReplaceAllは一番外側の頭部のみを削除する：

Wolfram Language code: {f[f[x]], f[x], g[f[x]], f[g[f[x]]]} /. f[x_] -> x

ReplaceRepeatedを演算子形で使う：

Wolfram Language code: ReplaceRepeated[f[x_] -> x][{f[f[x]], f[g[f[x]]]}]

スコープ  (3)

マッチする規則がないと，入力式が返される：

Wolfram Language code: x //. {y -> 2, z -> 3}

f に1と厳密に1個の整数が続いたものを置換する：

Wolfram Language code: {f[1], f[1, f[1, 2]], f[1, f[1, 2, 3]]} //. f[1, x_Integer] :> 1

f に1と1つまたは複数の整数が続いたものを置換する：

Wolfram Language code: {f[1], f[1, f[1, 2]], f[1, f[1, 2, 3]]} //. f[1, x__Integer] :> 1

f に1と0個以上の整数が続いたものを置換する：

Wolfram Language code: {f[1], f[1, f[1, 2]], f[1, f[1, 2, 3]]} //. f[1, x___Integer] :> 1

ReplaceRepeatedはホールドされた式の中で使うことができる：

Wolfram Language code: Hold[{f[f[x]], f[x], g[f[x]], f[g[f[x]]]} ] //. f[x_] -> x

置換の前に規則の右辺は評価しない：

Wolfram Language code: Hold[{f[f[x]], f[x], g[f[x]], f[g[f[x]]]} ] //. f[x_] :> x + x

置換の前に右辺を評価する：

Wolfram Language code: Hold[{f[f[x]], f[x], g[f[x]], f[g[f[x]]]} ] //. f[x_] -> x + x

アプリケーション  (1)

関数の引数の「カリー化」をやめる：

Wolfram Language code: f[a][b][c][d] //. g_[x_][y__] -> g[x, y]

特性と関係  (5)

空リストはマッチする規則を持たないとみなされる：

Wolfram Language code: x //. {}

置換にリストのリストが使われた場合，結果は同じ長さのリストになる：

Wolfram Language code: x //. {{x -> 1}, {y -> 2}}

置換してホールドされた式になる場合は，評価は強制されない：

Wolfram Language code: {g[g[1]], Hold[g[g[1]]]} //. g[n_] -> n + 1

ReplaceRepeatedは，事実上，ReplaceAllとFixedPointの組合せである：

Wolfram Language code: f[f[f[f[2]]]] //. f[2] -> 2
Wolfram Language code: FixedPoint[# /. f[2] -> 2&, f[f[f[f[2]]]]]

ReplaceRepeatedは式の上から複数回スキャンする：

Wolfram Language code: rules = {f[x_] -> f[x, 5], f[x__] -> {x, 1}};
Wolfram Language code: {f[a], f[f[a, b]]} //. rules

ReplaceAllは可能な限り最大の部分式を置換し，そこで停止する：

Wolfram Language code: {f[a], f[f[a, b]]} /. rules
Wolfram Language code: %% == (% /. rules /. rules)

レベル指定がAllのReplaceは，すべての部分式を厳密に1回置換しようとする：

Wolfram Language code: Replace[{f[a], f[f[a, b]]}, rules, All]
Wolfram Research (1988), ReplaceRepeated, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReplaceRepeated.html （2018年に更新）.

テキスト

Wolfram Research (1988), ReplaceRepeated, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReplaceRepeated.html （2018年に更新）.

CMS

Wolfram Language. 1988. "ReplaceRepeated." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/ReplaceRepeated.html.

APA

Wolfram Language. (1988). ReplaceRepeated. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ReplaceRepeated.html

BibTeX

@misc{reference.wolfram_2026_replacerepeated, author="Wolfram Research", title="{ReplaceRepeated}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/ReplaceRepeated.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_replacerepeated, organization={Wolfram Research}, title={ReplaceRepeated}, year={2018}, url={https://reference.wolfram.com/language/ref/ReplaceRepeated.html}, note=[Accessed: 03-November-2026]}