WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ScalingTransform[{sx,sy,…}]

原点から各座標軸に沿った siの因子のスケーリングを表すTransformationFunctionを与える．

ScalingTransform[{sx,sy,…},p]

点 p を中心としたスケーリングを与える．

ScalingTransform[s,v]

ベクトル v の方向に沿った s の因子でスケーリングを与える．

ScalingTransform[s,v,p]

v の方向に沿って点 p を中心としてスケーリングを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連するワークフロー
履歴
引用書式

ScalingTransform

ScalingTransform[{sx,sy,…}]

原点から各座標軸に沿った siの因子のスケーリングを表すTransformationFunctionを与える．

ScalingTransform[{sx,sy,…},p]

点 p を中心としたスケーリングを与える．

ScalingTransform[s,v]

ベクトル v の方向に沿った s の因子でスケーリングを与える．

ScalingTransform[s,v,p]

v の方向に沿って点 p を中心としてスケーリングを与える．

詳細

例題

すべて開く すべて閉じる

例  (2)

座標軸に沿ってスケールする：

Wolfram Language code: ScalingTransform[{a, b, c}]

ベクトル{1,1}に沿って因子 s でスケールする：

Wolfram Language code: t = ScalingTransform[s, {1, 1}]

スケールする方向のベクトルは因子 s でスケールされる：

Wolfram Language code: t[{1, 1}]//Together

スコープ  (4)

点{px,py}を中心として座標軸に沿ってスケールする：

Wolfram Language code: t = ScalingTransform[{Subscript[s, x], Subscript[s, y]}, {Subscript[p, x], Subscript[p, y]}]
Wolfram Language code: t[{x, y}]

点{px,py}を中心として因数 s でベクトル{1,1}に沿ってスケールする：

Wolfram Language code: t = ScalingTransform[s, {1, 1}, {Subscript[p, x], Subscript[p, y]}]
Wolfram Language code: t[{x, y}]

2Dの形に適用された変換：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ScalingTransform[.65, {1, 1}]]}]

3Dの形に適用された変換：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ScalingTransform[.65, {1, 1, 0}]]}, Boxed -> False]

アプリケーション  (2)

投影はスケーリングの特殊ケースと見ることができる：

Wolfram Language code: Graphics3D[{Opacity[.5], Cuboid[], GeometricTransformation[Cuboid[], ScalingTransform[10 ^ -3, {1, 1, 1}, #]]& /@ {{0, 0, 0}, {1, 1, 1}}}, Boxed -> False]

円を異なる方向にスケールする：

Wolfram Language code: Graphics[ GeometricTransformation[Circle[], ScalingTransform[.25, #]]& /@ Table[{Cos[u], Sin[u]}, {u, Pi / 10Range[10]}]]

特性と関係  (3)

ScalingTransform[s,v]の逆はScalingTransform[1/s,v]で与えられる：

Wolfram Language code: Composition[ScalingTransform[s, {1, 1}], ScalingTransform[1 / s, {1, 1}]]//Simplify

ScalingTransform[{s1,…,sn}]の逆はScalingTransform[{1/s1,…,1/sn}]で与えられる：

Wolfram Language code: Composition[ScalingTransform[{s1, s2}], ScalingTransform[1 / {s1, s2}]]//Simplify

それに沿ってスケールが適用される方向が対角状のときは，変換がなされる：

Wolfram Language code: t1 = ScalingTransform[s1, {1, 1}]; t2 = ScalingTransform[s2, {1, -1}];

この場合，変換が適用される順番は問題ではない：

Wolfram Language code: Composition[t1, t2][{x, y}] - Composition[t2, t1][{x, y}]//Simplify

考えられる問題  (1)

スケール変換が適用される順序は重要である：

Wolfram Language code: t1 = ScalingTransform[s1, {1, 1}]; t2 = ScalingTransform[s2, {1, 2}];

異なる順序で変換を適用することの違い：

Wolfram Language code: Composition[t1, t2][{x, y}] - Composition[t2, t1][{x, y}]//Simplify

おもしろい例題  (1)

3Dオブジェクトを点 p についてスケールする：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

軸に沿ってスケールする：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, ScalingTransform[k, {1, 0, 0}, p]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

軸に沿ってスケールする：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, ScalingTransform[k, {0, 1, 0}, p]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

軸に沿ってスケールする：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, ScalingTransform[k, {0, 0, 1}, p]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007), ScalingTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/ScalingTransform.html.

テキスト

Wolfram Research (2007), ScalingTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/ScalingTransform.html.

CMS

Wolfram Language. 2007. "ScalingTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ScalingTransform.html.

APA

Wolfram Language. (2007). ScalingTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ScalingTransform.html

BibTeX

@misc{reference.wolfram_2026_scalingtransform, author="Wolfram Research", title="{ScalingTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ScalingTransform.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_scalingtransform, organization={Wolfram Research}, title={ScalingTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/ScalingTransform.html}, note=[Accessed: 03-November-2026]}