Sech

Sech[z]

z の双曲線正割を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
1/Cosh[z]は自動的にSech[z]へ変換される．TrigFactorList[expr]は分割を行う．
特別な引数の場合，Sechは自動的に厳密値を計算する．
Sechは任意の数値精度で評価できる．
Sechは自動的にリストに縫い込まれる． »
SechはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

Sechは，双曲線正割関数である．これは，三角法で頻繁に使われる，Sec円関数の双曲線バージョンのようなものである．これは，双曲線余弦関数の逆数として，と定義される．これは，実数について，の面積が，単位双曲線と交わる原点からの放射線と軸との間の面積の2倍になるようにすることで定義される．Sech[α]は，したがって，交点の水平座標の逆数を表す．双曲線正割の同様の定義にがある．ただし，は自然対数Logの底である．
Sechは，その引数が有理数の（自然）対数であるときは，自動的に厳密値に評価される．引数として厳密な数式が与えられると，Sechは任意の数値精度に評価されることがある．TrigFactorListを使って，Sechを含む式をSinh，Cosh，Sin，Cosを含む項に因子分解することができる．Sechを含む記号式の操作に便利なその他の演算には，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
Sechは要素単位でリストおよび行列に縫い込まれる．対照的に，個々の行列要素の双曲線正割関数とは違って，MatrixFunctionは正方行列の双曲線正割（つまり，通常のベキが行列のベキで置き換えられた双曲線正割関数のベキ級数）を与えるのに使うことができる．
Sech[x]x がに近付くにつれて，指数的に減少する．Sechは，Secによって満足されるような，ピタゴラス(Pythagorean)の恒等式に似た恒等式を満足する．双曲線正割関数の定義は，恒等式によって，複素引数にまで拡張される．Sechは整数について値において極を持ち，これらの点で評価するとComplexInfinityになる．Sech[z]は，原点付近で級数展開 $sum_(k=0)^infty(TemplateBox[{{2, , k}}, EulerE])/((2 k)!)z^(2 k)$ を持つ．これはオイラー(Euler)数EulerEによって表すことができる．
Sechの逆関数はArcSechである．他の関連する数学関数には，CoshおよびCschがある．

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: Sech[1.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Sech[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Sech[z], {z, -2 - 2I π, 2 + 2I π}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Sech[x], {x, 0, 10}]

特異点における漸近展開：

Wolfram Language code: Series[Sech[x], {x, (I π/2), 3}]//Normal

スコープ (47)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Sech[1.8]

高精度で評価する：

Wolfram Language code: N[Sech[18 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Sech[1.80000000000000000000000]

Sechは複素数の入力が取れる：

Wolfram Language code: Sech[2.5 + I]

Sechを高精度で効率よく評価する：

Wolfram Language code: Sech[1.8`500]//Timing

Wolfram Language code: Sech[1.8`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Sech[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

MatrixFunctionを使って行列のSech関数を計算することもできる：

Wolfram Language code: MatrixFunction[Sech[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Sech[Interval[{0, Log[3]}]]

Wolfram Language code: Sech[CenteredInterval[-1, 1 / 100]]

Wolfram Language code: Sech[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Sech[Around[(2/Sqrt[3]), 0.1]]

特定の値 (4)

固定された純粋な虚点におけるSechの値：

Wolfram Language code: Table[Sech[I (π/6) n], {n, -2, 2}]

無限大における値：

Wolfram Language code: Sech[Infinity]

Wolfram Language code: Sech[ComplexInfinity]

Sechの最大値：

Wolfram Language code: Sech[0]

最大値をの根として求める：

Wolfram Language code: sol = Solve[D[Sech[x], x] == 0, x, Reals]

値を代入する：

Wolfram Language code: xmax = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Sech[x], {x, -5, 5}, Epilog -> Style[Point[{xmax, Sech[xmax]}], PointSize[Large], Red]]

単純な厳密値は自動的に生成される：

Wolfram Language code: Sech[I Pi / 3]

より複雑な場合には明示的にFunctionExpandを使う必要がある：

Wolfram Language code: Sech[I Pi / 24]

Wolfram Language code: FunctionExpand[%]

可視化 (3)

Sech関数をプロットする：

Wolfram Language code: Plot[Sech[x], {x, -2.5, 2.5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Sech[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Sech[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

の極プロット：

Wolfram Language code:

Table[PolarPlot[Sech[k ϕ], {ϕ, -2π, 2π}, Sequence[Frame -> True, Axes -> False, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-0.2, 1}, {-0.6, 0.6}}, FrameTicks -> {{{-0.5, 0.5}, None}, {{0, 1}, None}}]], {k, 1, 6}]

関数の特性 (12)

Sechはすべての実数値について定義される：

Wolfram Language code: FunctionDomain[Sech[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Sech[z], z, Complexes]

Sechは区間からのすべての実数値に達する：

Wolfram Language code: FunctionRange[Sech[x], x, y]

Sechは偶関数である：

Wolfram Language code: Sech[-x]

Sechは鏡特性を持つ：

Wolfram Language code: FullSimplify[Sech[Conjugate[z]] == Conjugate[Sech[z]]]

Sechは実数上での解析関数である：

Wolfram Language code: FunctionAnalytic[Sech[x], x]

複素平面上では解析的ではないが，有理型ではある：

Wolfram Language code: FunctionAnalytic[Sech[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[Sech[x], x]

Sechは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[Sech[x], x]

Sechは単射ではない：

Wolfram Language code: FunctionInjective[Sech[x], x]

Wolfram Language code: Plot[{Sech[x], .3}, {x, -5, 5}]

Sech全射ではない：

Wolfram Language code: FunctionSurjective[Sech[x], x]

Wolfram Language code: Plot[{Sech[x], 2}, {x, -5, 5}]

Sechは非負である：

Wolfram Language code: FunctionSign[Sech[x], x]

Sechは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Sech[x], x]

Wolfram Language code: FunctionDiscontinuities[Sech[x], x]

Sechは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Sech[x], x]

TraditionalFormによる表現：

Wolfram Language code: Sech[u]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Sech[x], x]

高次導関数：

Wolfram Language code: Table[D[Sech[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Sech[x], {x, n}]

積分 (3)

Sechの不定積分：

Wolfram Language code: Integrate[Sech[x], x]

原点を中心とする区間上での偶関数の不定積分：

Wolfram Language code: Integrate[Sech[x], {x, -2, 2}]//FullSimplify

これは，半分の区間では2倍の積分になる：

Wolfram Language code: 2Integrate[Sech[x], {x, 0, 2}]

その他の積分例：

Wolfram Language code: Integrate[Sech[x]Sinh[x], x]

Wolfram Language code: Table[Integrate[x ^ n Sech[x], x], {n, 2}]

Wolfram Language code: Integrate[Sech[z] ^ a, z]

級数展開： (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Sech[x], {x, 0, 7}]

の周りのSechの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Sech[x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{Sech[x], terms}, {x, -1.2, 1.2}]

Sechの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Sech[x], {x, 0, n}]

Sechのフーリエ級数における初項：

Wolfram Language code: FourierSeries[Sech[z], z, 1]

Sechはベキ級数に適用できる：

Wolfram Language code: Sech[x + (x^2/2) + (x^3/9) + O[x]^4]

積分変換 (2)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[Sech[t], t, s]

FourierTransform：

Wolfram Language code: FourierTransform[Sech[t], t, ω]

関数の恒等式と簡約 (6)

倍角のSech：

Wolfram Language code: Expand[Sech[2x], Trig -> True]

総和のSech：

Wolfram Language code: TrigExpand[Sech[x + y]]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Sech[4x]]

Wolfram Language code: TrigReduce[%]

双曲線関数の和を積に変換する：

Wolfram Language code: TrigFactor[Sech[x] + Sech[y]]

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[Sech[x + I y]]

指数関数に変換する：

Wolfram Language code: TrigToExp[Sech[z]]

関数表現 (4)

Cosを介した表現：

Wolfram Language code: Simplify[1 / Cos[I y]]

ベッセル関数を介した表現：

Wolfram Language code: Simplify[Sqrt[( 2/Pi x)] / BesselI[-(1/2), x], x > 0]

Wolfram Language code: Simplify[-Sqrt[( 2/Pi I y)] / BesselY[(1/2), I y], y > 0]

ヤコビ関数を介した表現：

Wolfram Language code: Simplify[1 / JacobiCN[I y, 0]]

Wolfram Language code: Simplify[1 / JacobiCD[I y, 0]]

MeijerGによる表現：

Wolfram Language code: (1/Sqrt[2] π^3 / 2 MeijerG[{{}, {(3/4)}}, {{0}, {(3/4), (1/2)}}, (x/2), (1/2)])//FullSimplify

アプリケーション (7)

追跡曲線をプロットする：

Wolfram Language code: ParametricPlot[{t - Tanh[t], Sech[t]}, {t, 0, 2}]

擬球をプロットする：

Wolfram Language code: ParametricPlot3D[{Cos[p]Sech[t], -Sech[t]Sin[p], t - Tanh[t]}, {t, 0, 4}, {p, 0, 2Pi}]

無限大に拡大する曲面の有限範囲を計算する：

Wolfram Language code: 2Pi Integrate[Sech[u]Tanh[u], {u, 0, Infinity}]

Korteweg–de Vries方程式におけるソリトン：

Wolfram Language code: u[x_, t_] := Sech[(x - t / 3) / (2Sqrt[3])] ^ 2

Wolfram Language code: D[u[x, t], t] + u[x, t]D[u[x, t], x] + D[u[x, t], x, x, x]//Simplify

零エネルギー解を持つシュレーディンガー(Schrödinger)方程式：

Wolfram Language code:

ψ[x_] = Sech[x];
v[x_] = 1 - 2Sech[x]^2;

Wolfram Language code: -ψ''[x] + v[x]ψ[x] == 0//Simplify

双曲線正割の確率密度関数の累積分布関数を計算する：

Wolfram Language code: pdf[x_] := Sech[Pi x / 2] / 2

Wolfram Language code: Integrate[pdf[x], {x, -Infinity, x}]

確率密度関数と累積分布関数をプロットする：

Wolfram Language code: Plot[{pdf[x], %}, {x, -5, 5}]

微分方程式を解く：

Wolfram Language code: DSolve[y'[x] - y[x] - Sech[x] == 0, y, x]

ソリトンプロファイルが周期ポテンシャルによって摂動された非線形シュレディンガー方程式を計算する：

Wolfram Language code:

L = 50;
usol = NDSolveValue[{I D[u[t, x], t] + D[u[t, x], x, x] + 2Abs[u[t, x]] ^ 2u[t, x] == 0.1(1 - Cos[Pi x / L]), u[0, x] == Sech[x]Exp[I x], u[t, -L] == u[t, L]}, u, {t, 0, 10}, {x, -L, L}]

Wolfram Language code: Plot3D[Abs[usol[t, x]], {t, 0, 10}, {x, -L, L}, PlotPoints -> 50, MaxRecursion -> 4, Mesh -> None]

特性と関係 (11)

Sechの基本的なパリティと周期性の特性は自動的に適用される：

Wolfram Language code: Sech[x + I Pi]

Wolfram Language code: Sech[-x]

Wolfram Language code: Sech[I x]

双曲線関数を含む式は自動的には簡約されない：

Wolfram Language code: Sech[x] ^ 2 + Tanh[x] ^ 2

Wolfram Language code: Simplify[%]

Refine，SimplifyおよびFullSimplifyを使ってSechを含む式を簡約する：

Wolfram Language code: Refine[Abs[Sech[x]] < 2, x∈Reals]

Wolfram Language code: Simplify[Sech[2z](2 - Sech[z] ^ 2)]

Wolfram Language code: FullSimplify[Sech[Log[GoldenRatio]]]

FunctionExpandを使って累乗根の特別な値を表す：

Wolfram Language code: FunctionExpand[Sech[I Pi / 16] ]

逆関数で構成する：

Wolfram Language code: {Sech[ArcSech[z]], Sech[2ArcSech[z]], Sech[3ArcSech[z]]}

Wolfram Language code: FunctionExpand[%]

双曲線方程式を解く：

Wolfram Language code: Reduce[Sech[z] + Sech[z + 1] == 1, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Sech[z]^3 - 3 Sech[z + 1] + z == 2, {z, 0}]

双曲線方程式を簡約する：

Wolfram Language code: Reduce[Sech[a x + b] == 1, x]

総和，積，積分からSechを得る：

Wolfram Language code: Sum[1 / (z + Pi I (k + 1 / 2)) ^ 2, {k, -Infinity, Infinity}]

Wolfram Language code: Product[Pi ^ 2(2k - 1) ^ 2 / (Pi ^ 2(2k - 1) ^ 2 + 4z ^ 2), {k, 1, Infinity}]

Wolfram Language code: Integrate[t ^ (2 I z / Pi) / (t ^ 2 + 1), {t, 0, Infinity}, Assumptions -> -Pi / 2 < Im[z] < Pi / 2]

Sechは，特殊関数の特殊な場合に見られる：

Wolfram Language code: {1 / BesselJ[-1 / 2, I z], 1 / HypergeometricPFQ[{}, {1 / 2}, z ^ 2 / 4], JacobiCN[z, 1]}

Sechは数値関数である：

Wolfram Language code: Attributes[Sech]

Wolfram Language code: NumericQ[Sech[2 + E]]

考えられる問題 (5)

機械精度の入力は，正しい答を得るためには不十分である：

Wolfram Language code: Sech[10. ^ 40 I]

厳密な入力だと，正しい答が得られる：

Wolfram Language code: N[Sech[10 ^ 40 I], 20]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Sech[10 ^ 100 I], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Sech[10 ^ 100 I], 20]]

Sechの逆数を評価するとCoshになる：

Wolfram Language code: 1 / Sech[x]

無限大にはベキ級数は存在しない．無限大においてSechは真性特異点を持つ：

Wolfram Language code: Series[Sech[x], {x, Infinity, 2}]

TraditionalFormの場合は引数の前後に丸カッコが必要である：

Wolfram Language code: sech x

Wolfram Language code: sech(x)

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Sech

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開： (4)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (7)

特性と関係 (11)

考えられる問題 (5)

テキスト

CMS

APA

BibTeX

BibLaTeX

Sech

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開： (4)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (7)

特性と関係 (11)

考えられる問題 (5)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX