WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SelectFirst[data,crit]

crit[ei]がTrueになる data の最初の eiを返す．見付からない場合はMissing["NotFound"]を返す．

SelectFirst[data,critprop]

選択された要素の特性 prop を返す．

SelectFirst[data,crit,default]

crit[ei]がTrueになるdata の eiが存在しない場合に default を返す．

SelectFirst[crit]

式に適用可能なSelectFirstの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
入力データ  
特性の形式
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

SelectFirst

SelectFirst[data,crit]

crit[ei]がTrueになる data の最初の eiを返す．見付からない場合はMissing["NotFound"]を返す．

SelectFirst[data,critprop]

選択された要素の特性 prop を返す．

SelectFirst[data,crit,default]

crit[ei]がTrueになるdata の eiが存在しない場合に default を返す．

SelectFirst[crit]

式に適用可能なSelectFirstの演算子形を表す．

詳細

  • SelectFirstは，与えられた基準 crit がTrueを与える最初の要素を保持する．
  • SelectFirst[data,crit]はFirst[Select[data,crit]]に等しい．
  • data は，以下の追加的な形式と解釈を持つことができる．
  • {e1,e2,…}値のリスト »
    f[e1,e2,…]任意の頭部 f »
    Association値の連想 »
    QuantityArray[…]数量配列あるいはその他の構造化配列
    Tabular[…]一貫した型の表形式データ »
    TabularColumn[…]一貫した型の列データ »
    Dataset[…]一般的な階層データ
  • 特性y prop は以下の形式と解釈を持つことができる．
  • "Element"選択された値 »
    "Index"選択された値のインデックスを返す »
    "BitVectorMask"選択された値には True，それ以外の値にはFalseを返すブールマスク »
    {prop1,prop2,…}複数の形式のリスト »
    All要素，インデックス，ビットベクトルマスクを与える連想 »
  • SelectFirst[data,crit,default]の default は，crit[ei]がTrueになる data が eiがない場合にのみ評価される．
  • SelectFirst[crit][data]はSelectFirst[data,crit]に等しい．

例題

すべて開く すべて閉じる

例  (6)

偶数である最初の要素を選ぶ：

Wolfram Language code: SelectFirst[{1, 2, 4, 7, 6, 2}, EvenQ]

選択された要素のインデックスを返す：

Wolfram Language code: SelectFirst[{1, 2, 4, 7, 6, 2}, # > 2& -> "Index"]

偶数が見付からない場合はデフォルトの x を与える：

Wolfram Language code: SelectFirst[{1, 3, 5}, EvenQ, x]

SelectFirstの演算子形を使う：

Wolfram Language code: SelectFirst[EvenQ][{1, 2, 4, 7, 6, 2}]

SelectFirstはAssociation内の値に作用する：

Wolfram Language code: SelectFirst[<|a -> 1, b -> 2, c -> 3, d -> 4|>, # > 2&]

SelectFirstをTabularオブジェクトに使う：

Wolfram Language code: Tabular[{{"cat", 2}, {"fox", 3}, {"dog", 5}}, {"a", "b"}]
Wolfram Language code: SelectFirst[%, OddQ[#b]&]
Wolfram Language code: Normal[%]

スコープ  (15)

基本的な用法  (5)

x を含む最初のペアを求める：

Wolfram Language code: SelectFirst[{{1, y}, {2, z}, {3, x}, {4, y}, {5, x}}, MemberQ[#, x]&]

純関数を使って要素をテストする：

Wolfram Language code: SelectFirst[{1, 2, 4, 7, 6, 2}, # > 2&]

選択基準として演算子形を使う：

Wolfram Language code: SelectFirst[Range[10], GreaterThan[3]]

SelectFirstの演算子形を使う：

Wolfram Language code: Range[10]//SelectFirst[GreaterThan[3]]

カスタムのデフォルト値を使う：

Wolfram Language code: SelectFirst[{1, 2, 3}, StringQ, "NoStrings"]

入力データ  (5)

SelectFirstは，Listだけでなく，任意の頭部に使うことができる：

Wolfram Language code: SelectFirst[f[1, a, 2, b, 3], IntegerQ]

SelectFirstはAssociation内の値に作用する：

Wolfram Language code: SelectFirst[<|"a" -> {.1, .3, .2}, "b" -> {"dog", "cat", "fox"}|>, AllTrue[#, StringQ]&]

SelectFirstはベクトルSparseArrayオブジェクトに使うことができる：

Wolfram Language code: s = SparseArray[Table[2 ^ i -> i, {i, 0, 5}]]
Wolfram Language code: SelectFirst[s, OddQ]

SelectFirstはTabularColumnオブジェクトに使うことができる：

Wolfram Language code: TabularColumn[RandomDate[10 ^ 5]]

11月の最初の日付を選択する：

Wolfram Language code: SelectFirst[SameQ[DateValue[#, "Month"], 11]&][%]

SelectFirstを名前付きの列があるTabularオブジェクトに使う：

Wolfram Language code: tab = ToTabular[{"a" -> {1, 2, 3}, "b" -> {.1, .3, .2}, "c" -> {"dog", "cat", "fox"}, "d" -> {DateObject[{2024, 8, 1}], DateObject[{2024, 8, 2}], DateObject[{2024, 8, 3}]}}, "Columns"]

最終列の日付が営業日である最初の行を選択する：

Wolfram Language code: SelectFirst[tab, Function[BusinessDayQ[#d]]]
Wolfram Language code: Normal[%]

特性の形式 (5)

選択された要素を返す：

Wolfram Language code: SelectFirst[{2, 3, 4, 5}, OddQ -> "Element"]

選択された要素のインデックスを返す：

Wolfram Language code: SelectFirst[{2, 3, 4, 5}, OddQ -> "Index"]

データのブールマスクを返す：

Wolfram Language code: SelectFirst[{2, 3, 4, 5}, OddQ -> "BitVectorMask"]
Wolfram Language code: Normal[%]

2つの形式を返す：

Wolfram Language code: SelectFirst[{2, 3, 4, 5}, OddQ -> {"Element", "Index"}]

すべての特性の連想を返す：

Wolfram Language code: SelectFirst[{2, 3, 4, 5}, OddQ -> All]

アプリケーション  (7)

9から99までで3と5の両方を法として1となる最初の数を選択する：

Wolfram Language code: SelectFirst[Range[9, 99], Mod[#, 3] == 1 && Mod[#, 5] == 1&]

逆に読んでも同じになる最初の4つ一組を選択する：

Wolfram Language code: SelectFirst[Tuples[{a, b}, 4], # == Reverse[#]&]

次元が1である，0と1の3×3行列を求める：

Wolfram Language code: SelectFirst[Tuples[{0, 1}, {3, 3}], Det[#] == 1&]

単位円内に存在する固有値を選択する：

Wolfram Language code: SelectFirst[Eigenvalues[RandomReal[1, {5, 5}]], Abs[#] < 1&]

名前が36文字以上の長さである組込みのWolfram言語オブジェクトを求める：

Wolfram Language code: SelectFirst[Names["*"], StringLength[#] >= 36&]

積から最初の数量を選択する：

Wolfram Language code: SelectFirst[z^4 π^2 x^2 y^2, NumericQ]

PoissonDistributionからのランダムなサンプル中の最初の素数の位置を求める：

Wolfram Language code: SelectFirst[RandomVariate[PoissonDistribution[100], 10 ^ 3], PrimeQ -> "Index"]

最初の素数の位置の分布を求める：

Wolfram Language code: sample = Table[SelectFirst[RandomVariate[PoissonDistribution[100], 10 ^ 3], PrimeQ -> "Index"], 10 ^ 4];
Wolfram Language code: Histogram[sample, Automatic, PDF]
Wolfram Language code: FindDistribution[sample]

特性と関係  (4)

デフォルト値は必要な場合にのみ評価される：

Wolfram Language code: SelectFirst[{1015177, "Junk", EndOfFile}, PrimeQ, Print["CriticalError"];$Failed]
Wolfram Language code: SelectFirst[{1015177, 2015177, 3015177}, PrimeQ, Print["CriticalError"];$Failed]

SelectFirstは最初にマッチしたもののみを返す：

Wolfram Language code: SelectFirst[{"1", a, Pi, Sqrt[2], E}, NumericQ]

Selectはマッチしたものをすべて返す：

Wolfram Language code: Select[{"1", a, Pi, Sqrt[2], E}, NumericQ]

SelectFirstは，SelectとReplaceの組合せで実装することができる：

Wolfram Language code: SelectFirst[{"1", a, Pi, Sqrt[2], E}, NumericQ] SelectFirst[{"1", a, Pi, Sqrt[2], E}, PrimeQ]
Wolfram Language code: Replace[Select[{"1", a, Pi, Sqrt[2], E}, NumericQ], {{} :> Missing["NotFound"], l_ :> First[l]}] Replace[Select[{"1", a, Pi, Sqrt[2], E}, PrimeQ], {{} :> Missing["NotFound"], l_ :> First[l]}]

SelectFirstは，パターンではなく関数を使う点を除いて，FirstCaseに似ている：

Wolfram Language code: data = <|a -> {3, 7}, b -> {7, 4}, c -> {3, 5}, d -> {6, 4}|>;

要素の合計が10未満である最初のリストを選ぶ：

Wolfram Language code: f = Total[#] < 10&;
Wolfram Language code: SelectFirst[data, f]

FirstCaseを使って同じ結果を得る：

Wolfram Language code: FirstCase[data, x_ /; f[x]]

考えられる問題  (1)

入力式の頭部は保持されない：

Wolfram Language code: SelectFirst[f[1, 2, 4, 7, 8], # > 2&]
Wolfram Research (2014), SelectFirst, Wolfram言語関数， https://reference.wolfram.com/language/ref/SelectFirst.html （2025年に更新）.

テキスト

Wolfram Research (2014), SelectFirst, Wolfram言語関数， https://reference.wolfram.com/language/ref/SelectFirst.html （2025年に更新）.

CMS

Wolfram Language. 2014. "SelectFirst." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/SelectFirst.html.

APA

Wolfram Language. (2014). SelectFirst. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SelectFirst.html

BibTeX

@misc{reference.wolfram_2026_selectfirst, author="Wolfram Research", title="{SelectFirst}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/SelectFirst.html}", note=[Accessed: 12-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_selectfirst, organization={Wolfram Research}, title={SelectFirst}, year={2025}, url={https://reference.wolfram.com/language/ref/SelectFirst.html}, note=[Accessed: 12-November-2026]}