WOLFRAM

Wolfram 语言与系统参考资料中心

lhs:=rhs

将 rhs 延时赋给 lhs. rhs 保留未计算的形式. 当 lhs 出现时，用 rhs 对其进行替换，并且每次重新计算.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
左侧  
不同类型的值  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

SetDelayed

lhs:=rhs

将 rhs 延时赋给 lhs. rhs 保留未计算的形式. 当 lhs 出现时，用 rhs 对其进行替换，并且每次重新计算.

更多信息

  • SetDelayed 有属性 HoldAll，而不是 HoldFirst 属性.
  • 您可以进行诸如 lhs:=rhs/;test 的赋值，这里 test 给出使用每个变换规则的条件. 您可进行具有相同 lhs 而有不同 test 形式的赋值.
  • 如果指定的赋值可以执行，lhs:=rhs 返回 Null; 否则返回 $Failed.

范例

打开所有单元 关闭所有单元

基本范例  (1)

设置并计算 f 的延迟下值：

Wolfram Language code: f[x_] := Expand[x ^ 2] f[a + b]

范围  (9)

左侧  (4)

SetDelayed 定义的变量在每次使用时计算：

Wolfram Language code: r := RandomReal[] {r, r, r}

分别使用立即赋值和延迟赋值为特殊和一般情况制定定义：

Wolfram Language code: fact[1] = 1; fact[n_] := n fact[n - 1] fact[10]

设置条件定义：

Wolfram Language code: f[x_ /; x > 0] := Sqrt[2x]

因此，只有在条件满足的情况下，f 才进行计算：

Wolfram Language code: {f[2], f[-2]}

通过几个条件例子定义一个函数：

Wolfram Language code: unit[x_ /; x < 0] := 0 unit[x_ /; x ≥ 0] := 1 {unit[-2], unit[0], unit[1], unit[a]}

不同类型的值  (5)

本值：

Wolfram Language code: r := RandomReal[] OwnValues[r]

下值（downvalue）：

Wolfram Language code: f[x_] := x ^ 2 DownValues[f]

次值：　

Wolfram Language code: derivative[1][f][x_] := fg[x]; SubValues[derivative]

上值（upvalue）：　

Wolfram Language code: mod/:a_mod + b_mod := modPlus[a, b] UpValues[mod]

数值：

Wolfram Language code: NValues[f]

对 f 进行数值计算：

Wolfram Language code: N[f[2]]

应用  (3)

定义一个用牛顿方法计算平方根的过程：

Wolfram Language code: newton[r_] := FixedPoint[Function[x, (x + r / x) / 2], r] newton[5.0]

需要时执行计算并将结果放入缓存中：

Wolfram Language code: pi2 := pi2 = N[Pi ^ 2, 50] pi2

查看是否被缓存：

Wolfram Language code: Definition[pi2]

未计算表达式的定义可以执行名称的调用：

Wolfram Language code: SetAttributes[f, HoldFirst] f[sym_, val_] := (sym = val ^ 2)

赋给 x 一个全局值：

Wolfram Language code: x = 17;

现在计算 f，为 x 设置一个新值：

Wolfram Language code: f[x, 5]

全局变量确实已经被修改：

Wolfram Language code: x

属性和关系  (9)

当有定义时，计算立即定义的右边：

Wolfram Language code: x = RandomReal[]; {x, x, x}

每次调用定义时，延时计算定义的右边：

Wolfram Language code: y := RandomReal[]; {y, y, y}

定义左边的参数在定义前计算：

Wolfram Language code: x = 5; f[x] := 17 Definition[f]

有相同左边的定义，较早的被覆盖：

Wolfram Language code: f[x_] := x ^ 2 f[x_] := x ^ 3 f[2]

如果有必要，模式变量将在嵌套作用域内被重新命名：

Wolfram Language code: makedef[z_] := (f[x_] := z ^ 2;) makedef[x] Definition[f]

因此，输入会与模式变量匹配，而定义右侧的变量则不会与其匹配：

Wolfram Language code: f[5]

延时定义产生一个不影响全局变量的范围：

Wolfram Language code: x = 5; f[x_] := x ^ 2 {f[2], x}

立即赋值并不引入范围：

Wolfram Language code: g[x_] = x ^ 2; {g[2], x}

用一个规则执行特定表达式的转换：

Wolfram Language code: f[2 x y] + f[x y] //. f[a_ b_] :> f[a] + f[b]

用定义执行关于 g 的所有表达式的转换：

Wolfram Language code: g[a_ b_] := g[a] + g[b] g[2 x y] + g[x y] + f[x y]

将特殊定义放在普通定义前：

Wolfram Language code: fact[n_] := n fact[n - 1]; fact[1] = 1; Definition[fact]

用这些定义计算 f[10]：

Wolfram Language code: fact[10]

Definition 输出与符号相关的定义：

Wolfram Language code: f[x_] := x ^ 2 Definition[f]

Information 输出关于符号的各种信息，包括任何定义：

Wolfram Language code: ? f

DownValues 返回对应任何定义 downvalue 的规则列表：

Wolfram Language code: DownValues[f]

赋给 f 一个特殊定义和普通定义：

Wolfram Language code: f[-1] = I; f[x_] := x ^ 2 SetAttributes[f, Listable]

用 Unset (=.) 清除特定左边的定义：

Wolfram Language code: f[-1]=.

检查确保只保留了一般定义：

Wolfram Language code: Definition[f]

清除任何定义，但不包括属性：

Wolfram Language code: Clear[f] Definition[f]

用 ClearAll 也清除属性：

Wolfram Language code: ClearAll[f] Definition[f]

可能存在的问题  (4)

省略 _ 仅为文字值定义变换，而不是函数：

Wolfram Language code: f[x] := x ^ 2; g[x_] := x ^ 2; {f[x], g[x]}
Wolfram Language code: {f[2], g[2]}

计算一个表达式：

Wolfram Language code: Expand[(x + 1) ^ 3]

使用延迟定义可能会产生意想不到的后果：

Wolfram Language code: f[x_] := %

实际制定的定义及其行为：

Wolfram Language code: Definition[f]

计算只是重置为先前运算的结果：

Wolfram Language code: f[1]

再次计算一个表达式以供后续使用：

Wolfram Language code: Expand[(x + 1) ^ 3]

用 Evaluate 强制对右侧进行计算：

Wolfram Language code: g[x_] := Evaluate[%] Definition[g]

查看是否按预期进行计算：

Wolfram Language code: g[1]

再次计算一个表达式以供后续使用：

Wolfram Language code: Expand[(x + 1) ^ 3]

或用 Set 强制对右侧进行计算：

Wolfram Language code: h[x_] = %

检查定义：

Wolfram Language code: Definition[h]

用它来执行计算：

Wolfram Language code: h[1]

迭代限制的定义：

Wolfram Language code: f[x_] := f[x + 1] f[1]

通过提供基本的例子，迭代终止：

Wolfram Language code: g[10] = 10; g[x_] := g[x + 1] g[1]

循环限制的定义：

Wolfram Language code: f[x_] := f[Floor[x / 2]] + 1 f[10]

通过提供基本的例子，循环终止：

Wolfram Language code: g[1] = 0; g[x_] := g[Floor[x / 2]] + 1 g[10]

巧妙范例  (1)

用于斐波那契数列的动态编程使用缓存来保存已计算好的值：

Wolfram Language code: fib[1] = fib[2] = 1; fib[n_] := fib[n] = fib[n - 1] + fib[n - 2]

在 5 处进行计算：

Wolfram Language code: fib[5]

在计算过程中已使用了先前计算好的新定义：

Wolfram Language code: Definition[fib]
Wolfram Research (1988)，SetDelayed，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SetDelayed.html.

文本

Wolfram Research (1988)，SetDelayed，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SetDelayed.html.

CMS

Wolfram 语言. 1988. "SetDelayed." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SetDelayed.html.

APA

Wolfram 语言. (1988). SetDelayed. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SetDelayed.html 年

BibTeX

@misc{reference.wolfram_2026_setdelayed, author="Wolfram Research", title="{SetDelayed}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/SetDelayed.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_setdelayed, organization={Wolfram Research}, title={SetDelayed}, year={1988}, url={https://reference.wolfram.com/language/ref/SetDelayed.html}, note=[Accessed: 06-November-2026]}