WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Signature[list]

標準的な順序で list の要素を置換するのに必要な符号を与える．

詳細
Details and Options Details and Options
例題  
例  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Signature

Signature[list]

標準的な順序で list の要素を置換するのに必要な符号を与える．

詳細

  • 置換の符号は(-1)nである．n は，この転置を組み立てるのに合成しなければならない要素のペアの互換の数である．
  • list の任意の2つの要素が同じ場合，Signature[list]は，0を与える．
  • Signatureは，Listに限らず任意の頭部の式に使うことができる．

例題

すべて開く すべて閉じる

例  (1)

Wolfram Language code: {Signature[{a, b, c}], Signature[{a, c, b}]}
Wolfram Language code: Signature[{a, b, b}]

アプリケーション  (3)

偶数の置換を求める：

Wolfram Language code: Select[Permutations[{a, b, c, d}], Signature[#] == 1&]

階数3で完全に反対称(Levi-Civita)のテンソル：

Wolfram Language code: Array[Signature[{##}]&, {3, 3, 3}]

Levi-Civitaテンソルの収縮：

Wolfram Language code: Table[Sum[Signature[{i, j, k, l}]Signature[{i, j, k, lp}], {i, 4}, {j, 4}, {k, 4}], {l, 4}, {lp, 4}]

特性と関係  (2)

3Dの外積の要素を求める：

Wolfram Language code: Table[Sum[Signature[{i, j, k}]{ax, ay, az}[[j]]{bx, by, bz}[[k]], {j, 3}, {k, 3}], {i, 3}]
Wolfram Language code: Cross[{ax, ay, az}, {bx, by, bz}]

行列式を計算する：

Wolfram Language code: Sum[Signature[{i, j, k}]Array[a, {3, 3}][[1, i]]Array[a, {3, 3}][[2, j]]Array[a, {3, 3}][[3, k]], {i, 3}, {j, 3}, {k, 3}]

組込みのDetと比較する：

Wolfram Language code: Det[Array[a, {3, 3}]] == %

考えられる問題  (2)

数の精度が数の順序に影響する：

Wolfram Language code: Signature[{1, 1.}]
Wolfram Language code: Signature[{1, 1}]

Signatureは記号的な引数についても評価する：

Wolfram Language code: sign = Signature[{a, b, c}]

Unevaluatedを使って未評価のSignatureを挿入する：

Wolfram Language code: sign = Unevaluated[Signature[{a, b, c}]]; Table[sign, {a, 3}, {b, 3}, {c, 3}]

Signatureを直接Table内で使う：

Wolfram Language code: Table[Signature[{a, b, c}], {a, 3}, {b, 3}, {c, 3}]

おもしろい例題  (1)

Wolfram Language code: ArrayPlot[1 + Partition[Flatten[Array[Signature[{##}]&, Table[6, {6}]]], 6 ^ 3]]
Wolfram Research (1988), Signature, Wolfram言語関数， https://reference.wolfram.com/language/ref/Signature.html.

テキスト

Wolfram Research (1988), Signature, Wolfram言語関数， https://reference.wolfram.com/language/ref/Signature.html.

CMS

Wolfram Language. 1988. "Signature." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Signature.html.

APA

Wolfram Language. (1988). Signature. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Signature.html

BibTeX

@misc{reference.wolfram_2026_signature, author="Wolfram Research", title="{Signature}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Signature.html}", note=[Accessed: 15-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_signature, organization={Wolfram Research}, title={Signature}, year={1988}, url={https://reference.wolfram.com/language/ref/Signature.html}, note=[Accessed: 15-November-2026]}