WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

StringMatchQ["string",patt]

"string"が文字列パターン patt にマッチするかどうかを判定する．

StringMatchQ["string",RegularExpression["regex"]]

"string"が指定された正規表現にマッチするかどうかを判定する．

StringMatchQ["string",{patt1,patt2,…}]

"string"が pattiのいずれかとマッチするかどうかを判定する．

StringMatchQ[{"string1","string2",…},patt]

各"stringi"の結果のリストを与える．

StringMatchQ[patt]

式に適用可能なStringMatchQの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
IgnoreCase  
SpellingCorrection  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

StringMatchQ

StringMatchQ["string",patt]

"string"が文字列パターン patt にマッチするかどうかを判定する．

StringMatchQ["string",RegularExpression["regex"]]

"string"が指定された正規表現にマッチするかどうかを判定する．

StringMatchQ["string",{patt1,patt2,…}]

"string"が pattiのいずれかとマッチするかどうかを判定する．

StringMatchQ[{"string1","string2",…},patt]

各"stringi"の結果のリストを与える．

StringMatchQ[patt]

式に適用可能なStringMatchQの演算子形を表す．

詳細とオプション

  • StringMatchQでは，通常のStringExpression文字列パターンと次のメタキャラクタを含む文字列パターンの省略形の両方が使える．
  • *任意数（零を含む）の文字
    @大文字を除く任意数（零を含まない）の文字
    \\* 等文字通りの * 等
  • Verbatim["p"]は，*や@を含んだ string が文字通り解釈されるように指定する．
  • オプションIgnoreCase->Trueの設定では，StringMatchQは，大文字と小文字を同じものとして取り扱う．
  • オプションSpellingCorrection->Trueの設定では，StringMatchQは列を構成するごく一部の文字が異なる場合でもこの列のマッチを認める．
  • StringMatchQ[form][expr]はStringMatchQ[expr,form]に等しい．
  • StringMatchQ[BioSequence["type","seq"],patt]は，文字列"seq"と patt をチェックする．この場合，patt 内の縮重記号は，生体分子配列のタイプに基づいてワイルドカードパターンとして解釈される．Verbatim["patt"]を使って縮重記号を文字通りにマッチングする．
  • BioSequenceのドキュメントには，各生体分子配列タイプについてサポートされる縮重記号がリストされている．
  • StringMatchQが操作する生体分子配列が環状なら，ラップアラウンドマッチングが可能である．

例題

すべて開く すべて閉じる

例  (4)

文字列パターンにマッチするかどうかテストする：

Wolfram Language code: StringMatchQ["apppbb", "p" ~~ ___ ~~ "b"]
Wolfram Language code: StringMatchQ["apppbb", "a" ~~ ___ ~~ "b"]

省略された文字列パターンを使う：

Wolfram Language code: StringMatchQ["apppbb", "a*b"]

文字列のリストを入力として与える：

Wolfram Language code: StringMatchQ[{"a", "b", "ab", "abcd", "bcde"}, "a" ~~ ___]

StringMatchQの演算子形を使う：

Wolfram Language code: StringMatchQ["a*b"]["apppbb"]

演算子形を使って文字列を選択する：

Wolfram Language code: Select[{"CAC1", "CTG1", "ACT1", "CGA1", "CTC1"}, StringMatchQ["*G*"]]

スコープ  (10)

文字列パターンを使う：

Wolfram Language code: StringMatchQ["tester", "t" ~~ __ ~~ "t"]
Wolfram Language code: StringMatchQ["acggtaagc", Characters["acgt"]..]
Wolfram Language code: StringMatchQ["MATCH", "*H"]

正規表現を使う：

Wolfram Language code: StringMatchQ["acggtaagc", RegularExpression["[acgt]+"]]

正規表現と文字列パターンを混ぜて使う：

Wolfram Language code: StringMatchQ["abc 123 a", RegularExpression["a.*"] ~~ DigitCharacter..]

日付のパターンマッチを使う：

Wolfram Language code: StringMatchQ["31/12/2003", DatePattern[{"Day", "Month", "Year"}]]

どちらかのパターンが出現するかどうか判定する：

Wolfram Language code: StringMatchQ["abcdabcdcd", {"a*", "*d"}]
Wolfram Language code: StringMatchQ["abcdabcdcd", "a*" | "*d"]

StringMatchQは自動的に文字列のリストに縫い込まれる：

Wolfram Language code: StringMatchQ[{"ability", "listable", "argument"}, "a" ~~ __ ~~ "t" ~~ ___]

生体分子配列が文字列パターンにマッチするかどうかチェックする：

Wolfram Language code: StringMatchQ[BioSequence["DNA", "ATG"], "AT" ~~ ("C" | "G")]

パターンにワイルドカードを使って生体分子配列と比較する：

Wolfram Language code: StringMatchQ[BioSequence["DNA", "ATGGC"], "AN" ~~ ___]

"N"は生体分子配列においてのみ縮重記号である：

Wolfram Language code: StringMatchQ["ATGGC", "AN" ~~ ___]

Verbatimを使って縮重マッチを避ける：

Wolfram Language code: StringMatchQ[BioSequence["DNA", "ATGGC"], ___ ~~ Verbatim["N"] ~~ ___]
Wolfram Language code: StringMatchQ[BioSequence["DNA", "ATGNC"], ___ ~~ Verbatim["N"] ~~ ___]

環状配列は折返しのマッチをサポートする：

Wolfram Language code: StringMatchQ[BioSequence["CircularDNA", "ACGCT"], "TA" ~~ ("S"..)]
Wolfram Language code: StringMatchQ[BioSequence["CircularDNA", "ACGCT"], "AT" ~~ ("S"..)]

オプション  (3)

IgnoreCase  (2)

IgnoreCaseTrueを使って文字列のマッチで大文字と小文字が同じものとして扱われるかどうかをちぇっくする：

Wolfram Language code: StringMatchQ["acggtATTCaagc", __ ~~ "aT" ~~ __, IgnoreCase -> True]

大文字小文字を無視したチェックの演算子表現：

Wolfram Language code: StringMatchQ["ac", IgnoreCase -> True]["AC"]

SpellingCorrection  (1)

オプションSpellingCorrection -> Trueで自動的にスペル訂正が行われる：

Wolfram Language code: StringMatchQ["commit", "comit", SpellingCorrection -> True]

アプリケーション  (1)

同じ文字が重続く言葉を探す：

Wolfram Language code: Select[{"hi", "letter", "boolean", "fruitful"}, StringMatchQ[#, StringExpression[___, x_, x_, ___] ]&]

特性と関係  (9)

文字通りの文字列の場合，SameQはStringMatchQと等価である：

Wolfram Language code: "abbaab" === "abbab"
Wolfram Language code: StringMatchQ["abbaab", "abbab"]

リストから素早く要素を抽出したければPickを使う：

Wolfram Language code: dna = Table[StringJoin[RandomChoice[{"a", "c", "g", "t"}, 10]], {50000}];
Wolfram Language code: Pick[dna, StringMatchQ[dna, "a" ~~ ___ ~~ "ggg" ~~ ___]]//Timing//First

Selectと比較する：

Wolfram Language code: Select[dna, StringMatchQ[#, "a" ~~ ___ ~~ "ggg" ~~ ___]&]//Timing//First

StringMatchQは第1引数内の文字列のリストに縫い込まれる：

Wolfram Language code: StringMatchQ[{"a", "Z", "9", "."}, LetterCharacter]

StringMatchQ["string",{patt1,patt2,…}]はStringMatchQ["string",Alternatives[patt1,patt2,…]]に等しい：

Wolfram Language code: StringMatchQ["acd", {"a*", "b*"}]
Wolfram Language code: StringMatchQ["acd", "a*" | "b*"]

StringFreeQを使ってパターンにマッチする部分文字列がないことを確認する：

Wolfram Language code: StringFreeQ["commit", "om" ~~ __]

StringFreeQがTrueのときはStringMatchQは一般にFalseを返す：

Wolfram Language code: StringFreeQ["commit", "am" ~~ __]
Wolfram Language code: StringMatchQ["commit", "am" ~~ __]

StringContainsQを使って部分文字列がパターンにマッチするかどうかをチェックする：

Wolfram Language code: StringContainsQ["commit", "om" ~~ __]

StringMatchQは文字列全体がパターンにマッチするかどうかをチェックする：

Wolfram Language code: StringMatchQ["commit", "om" ~~ __]

StringMatchQは，StringContainsQがFalseのときは一般にFalseを返す：

Wolfram Language code: StringContainsQ["commit", "am" ~~ __]
Wolfram Language code: StringMatchQ["commit", "am" ~~ __]

StringContainsQ["string",patt]はStringMatchQ["string",___~~patt~~___]に等しい：

Wolfram Language code: StringContainsQ[{"commit", "giveup"}, "om"]
Wolfram Language code: StringMatchQ[{"commit", "giveup"}, ___ ~~ "om" ~~ ___]

StringStartsQ["string",patt]はStringMatchQ["string",StartOfString~~patt~~___]に等しい：

Wolfram Language code: StringStartsQ[{"commit", "omit"}, "om"]
Wolfram Language code: StringMatchQ[{"commit", "omit"}, StartOfString ~~ "om" ~~ ___]

StringEndsQ["string",patt]はStringMatchQ["string",___~~patt~~EndOfString]に等しい：

Wolfram Language code: StringEndsQ[{"omit", "omen"}, "it"]
Wolfram Language code: StringMatchQ[{"omit", "omen"}, ___ ~~ "it" ~~ EndOfString]

考えられる問題  (3)

StringMatchQはメタ文字をサポートする：

Wolfram Language code: StringMatchQ["aaa", "a*a"]

他の文字列関数はほとんどサポートしないため，明らかに矛盾した結果につながる可能性がある：

Wolfram Language code: StringFreeQ[ "aaa", "a*a"]

Verbatimで文字列パターンをラップしてメタ文字を無効して関数間の一貫性を保つ：

Wolfram Language code: StringMatchQ["aaa", Verbatim["a*a"]]

StringMatchQは埋込まれた書式情報を持つ文字列には使えない：

Wolfram Language code: StringMatchQ["StyleBox[teStyleBox["ste",FontColor->RGBColor[1, 0, 0]]r]", "t" ~~ __]
Wolfram Language code: StringMatchQ["tester", "t" ~~ __]

スペル修正は文字による文字列パターンにのみ有効である：

Wolfram Language code: StringMatchQ["abcde", "A@", SpellingCorrection -> True]
Wolfram Research (1988), StringMatchQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/StringMatchQ.html （2020年に更新）.

テキスト

Wolfram Research (1988), StringMatchQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/StringMatchQ.html （2020年に更新）.

CMS

Wolfram Language. 1988. "StringMatchQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/StringMatchQ.html.

APA

Wolfram Language. (1988). StringMatchQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StringMatchQ.html

BibTeX

@misc{reference.wolfram_2026_stringmatchq, author="Wolfram Research", title="{StringMatchQ}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/StringMatchQ.html}", note=[Accessed: 07-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_stringmatchq, organization={Wolfram Research}, title={StringMatchQ}, year={2020}, url={https://reference.wolfram.com/language/ref/StringMatchQ.html}, note=[Accessed: 07-November-2026]}