WOLFRAM

Wolfram 语言与系统参考资料中心

SubsetMap[f,{e1,e2,…},{i,j,…}]

产生列表 {e1,e2,…} 中的元素 ei, ej, … 被通过计算 f[{ei,ej,…}] 获得的对应列表元素取代的表达式.

SubsetMap[f,expr,{pos1,pos2,…}]

替代在位置 pos1, pos2, … 上的 expr 元素.

SubsetMap[f,{pos1,pos2,…}]

表示可应用于一个表达式的 SubsetMap 的算符格式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

SubsetMap

SubsetMap[f,{e1,e2,…},{i,j,…}]

产生列表 {e1,e2,…} 中的元素 ei, ej, … 被通过计算 f[{ei,ej,…}] 获得的对应列表元素取代的表达式.

SubsetMap[f,expr,{pos1,pos2,…}]

替代在位置 pos1, pos2, … 上的 expr 元素.

SubsetMap[f,{pos1,pos2,…}]

表示可应用于一个表达式的 SubsetMap 的算符格式.

更多信息

  • 在 SubsetMap[f,list,{i1,…,in}] 中，函数 f 接受 list 中长度为 n 的子列表，并预期返回长度为 n 的另一个列表，其元素会取代原始子列表.

范例

打开所有单元 关闭所有单元

基本范例  (5)

反向位置 2 和 4 的元素：

Wolfram Language code: SubsetMap[Reverse, {x1, x2, x3, x4, x5, x6}, {2, 4}]

提取、旋转并重新插入位置 2、4 和 5 的元素：

Wolfram Language code: SubsetMap[RotateLeft, {x1, x2, x3, x4, x5, x6}, {2, 4, 5}]

提取、累加并重新插入位置 2 和 5 的元素：

Wolfram Language code: SubsetMap[Accumulate, {x1, x2, x3, x4, x5, x6}, 2 ;; 5]

反向矩阵对角线的元素：

Wolfram Language code: SubsetMap[Reverse, Array[Subscript[x, ##]&, {3, 3}], {{1, 1}, {2, 2}, {3, 3}}]//MatrixForm

累加矩阵第二列的元素：

Wolfram Language code: SubsetMap[Accumulate, Array[Subscript[x, ##]&, {3, 3}], {All, 2}]//MatrixForm

范围  (4)

反向列表中偶位置中的元素：

Wolfram Language code: SubsetMap[Reverse, Range[10], {2, 4, 6, 8, 10}]

对位置参数使用等效的符号：

Wolfram Language code: SubsetMap[Reverse, Range[10], {{2}, {4}, {6}, {8}, {10}}]
Wolfram Language code: SubsetMap[Reverse, Range[10], 2 ;; -1 ;; 2]

作用于不规则数组：

Wolfram Language code: SubsetMap[Reverse, {{a, b}, {c}}, {{1, 1}, {2, 1}}]

其他符号：

Wolfram Language code: SubsetMap[Reverse, {{a, b}, {c}}, {All, 1}]

使用 SubsetMap 作为算符格式显示这些单词是“偶字母回文”：

Wolfram Language code: Characters[{"rehabilitate", "semiparasite"}]
Wolfram Language code: SubsetMap[Reverse, {2, 4, 6, 8, 10, 12}] /@ %

定期移动颜色列表的中心元素：

Wolfram Language code: NestList[SubsetMap[RotateRight, Range[5, 10]], Hue /@ Subdivide[0, 0.8, 12], 12]//MatrixForm

应用  (1)

实现排序网络，随机排序元素对直至排序所有元素：

Wolfram Language code: randomSort[list_] := With[{n = Length[list]}, NestWhileList[SubsetMap[Sort, #, Sort@RandomInteger[{1, n}, 2]]&, list, Not @* OrderedQ]]
Wolfram Language code: randomSort[Reverse@Range[4]]
Wolfram Language code: ListLinePlot[Transpose[%]]

对于更长列表，找到要重新排序的最后元素可能需要很多步骤：

Wolfram Language code: Length[list = randomSort[Reverse@Range[20]]]
Wolfram Language code: ListLinePlot[Transpose[list], ScalingFunctions -> {"Log", None}]

属性和关系  (4)

使用 SubsetMap 移动列表中元素子集的位置：

Wolfram Language code: alphabet = Alphabet[]
Wolfram Language code: SubsetMap[RotateRight, alphabet, {1, 13, 25}]

这也可以用 Cycles 符号和 Permute 紧凑表达：

Wolfram Language code: % === Permute[alphabet, Cycles[{{1, 13, 25}}]]

对于可列函数 f，SubsetMap[f,expr,pos] 等同于 MapAt[f,expr,pos]：

Wolfram Language code: SubsetMap[Sqrt, Range[10], {{2}, {3}, {5}, {7}}]
Wolfram Language code: MapAt[Sqrt, Range[10], {{2}, {3}, {5}, {7}}]

SubsetMap[f,expr,{}] 返回 expr：

Wolfram Language code: SubsetMap[Accumulate, {a, b, c, d, e, f}, {}]

SubsetMap[f,expr,All] 等同于 f[expr]：

Wolfram Language code: SubsetMap[Accumulate, {a, b, c, d, e, f}, All]

可能存在的问题  (2)

如果位置列表未按标准排序，则结果将继承该顺序：

Wolfram Language code: SubsetMap[Accumulate, {a, b, c}, {3, 2, 1}]

在 SubsetMap[f,expr,{i,j,…}] 中，列表 {i,j,…} 表示位置列表，等价于 {{i},{j},…}：

Wolfram Language code: expr = {x[1, a], x[2, b], x[3, c]};
Wolfram Language code: SubsetMap[Accumulate, expr, {1, 2}]
Wolfram Language code: SubsetMap[Accumulate, expr, {{1}, {2}}]

其他使用位置规范的函数，例如 Extract，把整数列表诠释为单个位置：

Wolfram Language code: Extract[expr, {1, 2}]
Wolfram Language code: Extract[expr, {{1}, {2}}]
Wolfram Research (2019)，SubsetMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SubsetMap.html.

文本

Wolfram Research (2019)，SubsetMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SubsetMap.html.

CMS

Wolfram 语言. 2019. "SubsetMap." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SubsetMap.html.

APA

Wolfram 语言. (2019). SubsetMap. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SubsetMap.html 年

BibTeX

@misc{reference.wolfram_2026_subsetmap, author="Wolfram Research", title="{SubsetMap}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/SubsetMap.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_subsetmap, organization={Wolfram Research}, title={SubsetMap}, year={2019}, url={https://reference.wolfram.com/language/ref/SubsetMap.html}, note=[Accessed: 03-November-2026]}