WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TimeSystem

時間関数のオプションで，時間の定義に使用される時間系を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

TimeSystem

TimeSystem

時間関数のオプションで，時間の定義に使用される時間系を指定する．

詳細

  • 時間系は標準時，時間の尺度，あるいは時間基準としても知られている．
  • 時間系は時の進み方の計測方法を決定する，原子の振動，地球の自転，他の天文現象等の物理過程を示す．
  • 適切な時間系を選ぶことは正確な時間の制御に欠かせない．数十秒の誤差も数十年に渡って積み重ねられるかもしれず，数時間が数千年間に渡って積み重ねられるかもしれない．
  • 時間系の選択は暦や時刻帯の選択からは独立している．
  • 使用可能な時間系には以下がある．
  • "TAI"原子時計で計測された原子時
    "TCB"太陽系座標時
    "TCG"地球座標時
    "TDB","ET"太陽系力学時，暦表時
    "TT"地球の海面で測定された地球時
    "UTC"閏秒を含む協定世界時
    "UT1"地球の回転角に比例した世界時
    "UT"閏秒を前日から重複する世界時，あるいはUTC時代（1960年から現在まで）を除く太陽世界時(solar UT1)
  • TimeSystemのデフォルト値はAutomaticである．これは，与えられている場合には入力の時間系を継承し，その他の場合は"UT"をデフォルトとする．

例題

すべて開く すべて閉じる

例  (3)

ある瞬間を協定世界時で定義する：

Wolfram Language code: DateObject[{2021, 8, 1, 0, 0, 0}, TimeSystem -> "UTC", TimeZone -> 0]

閏秒のために協定世界時より現在37秒進んでいる原子時に変換する：

Wolfram Language code: TimeSystemConvert[%, "TAI"]

協定世界時の日付を地球時でユリウス暦の日付に変換する：

Wolfram Language code: JulianDate[DateObject[{2000, 1, 1, 12, 0, 0}, TimeZone -> 0], TimeSystem -> "TT"]

協定世界時によるユリウス暦の日付への変換と比較する：

Wolfram Language code: % - JulianDate[DateObject[{2000, 1, 1, 12, 0, 0}, TimeZone -> 0], TimeSystem -> "UTC"]

この日付における差は64.184秒である：

Wolfram Language code: 86400%

以下は37回の閏秒によって隔てられた時間の差である：

Wolfram Language code: DateObject[{2020, 1, 1, 12, 0, 0}, TimeSystem -> "UTC", TimeZone -> 0] - DateObject[{2020, 1, 1, 12, 0, 0}, TimeSystem -> "TAI", TimeZone -> 0]

スコープ  (3)

DateObject式で異なる時間系を指定する：

Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> Automatic]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "UTC"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "UT1"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "TAI"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "TT"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "TDB"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "TCG"]
Wolfram Language code: DateObject[{2000, 1, 1, 12, 0, 0}, TimeSystem -> "TCB"]

異なる時間系を異なる暦と組み合せて使う：

Wolfram Language code: Now
Wolfram Language code: TimeZoneConvert[%, 0]
Wolfram Language code: CalendarConvert[%, "JulianDate"]
Wolfram Language code: TimeSystemConvert[%, "TT"]

"TDB"時間系は暦表時"ET"としても知られている：

Wolfram Language code: DateObject[TimeSystem -> "TDB", TimeZone -> 0]

"ET"に変換しても日付の数値は変わらない：

Wolfram Language code: TimeSystemConvert[%, "ET"]

アプリケーション  (1)

最後に加えられた閏秒，2016年の終りに加えられたものについて探ってみる：

Wolfram Language code: DateObject[#, TimeZone -> 0, TimeSystem -> "TAI"]& /@ DateRange[{2017, 1, 1, 0, 0, 33}, {2017, 1, 1, 0, 0, 40}, Quantity[1, "Seconds"]]
Wolfram Language code: TimeSystemConvert[#, "UTC"]& /@ %

特性と関係  (2)

TimeSystemオプションを使ってDateObject式の時間系を指定する：

Wolfram Language code: DateObject[{1990, 1, 1, 12, 0, 0}, TimeSystem -> "TDB", TimeZone -> 0]

TimeSystemConvertを使って日付を異なる時間系の表現に変換する：

Wolfram Language code: TimeSystemConvert[%, "TAI"]

指定された時刻帯のUT1による時刻は対応する中心子午線における平均太陽時に相当する：

Wolfram Language code: {DateObject[TimeSystem -> "UT1", TimeZone -> 0], SolarTime["MeanTime", GeoPosition[{0, 0}]]}

おもしろい例題  (1)

1960から1972までの間，"UTC"は頻繁に分数秒を加え"UT1"とより近く調整されていた：

Wolfram Language code: DateListPlot[{#, DateDifference[DateObject[#, TimeSystem -> "UT1"], DateObject[#, TimeZone -> 0, TimeSystem -> "UTC"], "Second"]}& /@ DateRange[{1960, 1, 2}, {1973, 1, 1}, "Month"], PlotRange -> {-.7, 1}]

"UTC"は1972年からは"UT1"との差が1秒以内になるように必要に応じて完全な閏秒だけを加えるようになった：

Wolfram Language code: DateListPlot[{#, DateDifference[DateObject[#, TimeSystem -> "UT1"], DateObject[#, TimeZone -> 0, TimeSystem -> "UTC"], "Second"]}& /@ DateRange[{1970, 1, 1}, {2020, 1, 1}, "Month"]]

"TAI"と"UTC"の差は"UTC"の開始以来加えられた閏秒の秒数を示す：

Wolfram Language code: DateListPlot[{#, DateDifference[DateObject[#, TimeSystem -> "TAI"], DateObject[#, TimeZone -> 0, TimeSystem -> "UTC"], "Second"]}& /@ DateRange[{1960, 1, 2, 0, 0, 0}, {2021, 1, 1}, "Month"]]
Wolfram Research (2021), TimeSystem, Wolfram言語関数， https://reference.wolfram.com/language/ref/TimeSystem.html.

テキスト

Wolfram Research (2021), TimeSystem, Wolfram言語関数， https://reference.wolfram.com/language/ref/TimeSystem.html.

CMS

Wolfram Language. 2021. "TimeSystem." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TimeSystem.html.

APA

Wolfram Language. (2021). TimeSystem. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSystem.html

BibTeX

@misc{reference.wolfram_2026_timesystem, author="Wolfram Research", title="{TimeSystem}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSystem.html}", note=[Accessed: 10-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_timesystem, organization={Wolfram Research}, title={TimeSystem}, year={2021}, url={https://reference.wolfram.com/language/ref/TimeSystem.html}, note=[Accessed: 10-October-2026]}