WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TriangleMeasurement[tri,type]

三角形 tri の指定されたタイプの測定値を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

TriangleMeasurement

TriangleMeasurement[tri,type]

三角形 tri の指定されたタイプの測定値を与える．

詳細

  • 三角形 tri は，{p1,p2,p3}，Triangle[{p1,p2,p3}]，あるいはPolygon[{p1,p2,p3}]として与えることができる．
  • 次は，使用可能な測定値のタイプである．
  • "Area"面積
    "Circumradius"外接円の半径
    {"Exradius",p}頂点 p の反対側の傍接円の半径
    {"ExteriorAngle",p}頂点 p における外角
    {"FullExteriorAngle",p}頂点 p における共役角
    {"Height",p}頂点 p から測った三角形の高さ
    "Inradius"内接円の半径
    {"InteriorAngle",p}頂点 p における内角
    "NinePointRadius"九点円の半径
    "Perimeter"外周
    "Semiperimeter"半外周
  • {"type",p}の形式の p は，GeometricSceneにおける記号点指定，{x,y}の形式の明示的な頂点，Point[{x,y}]，あるいは頂点の指標 i でよい．短縮形式の"type"で与えられた場合は頂点 p2が使われる．
  • 頂点 p を指定する任意のタイプでは，Allの値は頂点に対応する3つの値のリストを返す．
  • TriangleMeasurementは，GeometricSceneの記号による点と一緒に使うことができる．

例題

すべて開く すべて閉じる

例  (2)

三角形の半周長を計算する：

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {3, 4}}, "Semiperimeter"]

指定された頂点における三角形の傍接円の半径を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, {"Exradius", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Excircle", {0, 0}}], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]

すべての傍接円の半径を計算する：

Wolfram Language code: TriangleMeasurement[tri, {"Exradius", All}]

スコープ  (11)

三角形の面積を計算する：

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {0, 4}}, "Area"]

記号座標を使って面積を計算する：

Wolfram Language code: TriangleMeasurement[{{0, 0}, {b, 0}, {0, h}}, "Area"]

三角形の外接円の半径を計算する：

Wolfram Language code: tri = {{0, -2}, {1, 2}, {-1, 1}}; TriangleMeasurement[tri, "Circumradius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Circumcircle"]}]

指定された頂点における三角形の傍接円の半径を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[{{0, 0}, {3, 0}, {3, 4}}, {"Exradius", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Excircle", {0, 0}}], Style[Arrow[{{0, 0}, {9, 0}}], Dashed], Style[Arrow[{{0, 0}, {9, 12}}], Dashed]}]

指定された頂点における三角形の外角を計算する：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"ExteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

指定された頂点における三角形の共役角を計算する：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"FullExteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

三角形の高さを計算する：

Wolfram Language code: tri = {{2, 0}, {1, 3}, {-1, 0}}; TriangleMeasurement[tri, "Height"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

三角形の内半径を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Inradius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, "Incircle"]}]

指定された頂点における三角形の内角を計算する：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, {"InteriorAngle", {0, 0}}]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]]}]

三角形の九点円の中心を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {1, 2}}; TriangleMeasurement[tri, "NinePointRadius"]
Wolfram Language code: Graphics[{Style[Triangle[tri], Opacity[0.2]], TriangleConstruct[tri, {"Foot", All}], TriangleConstruct[tri, {"Midpoint", All}], Midpoint[{TriangleConstruct[tri, "Orthocenter"], #}]& /@ tri, TriangleConstruct[tri, "NinePointCircle"]}]

三角形の周長を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Perimeter"]

三角形の半周長を計算する：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleMeasurement[tri, "Semiperimeter"]

特性と関係  (11)

TriangleMeasurement[{a,b,c}]はArea[Triangle[{a,b,c}]]に等しい：

Wolfram Language code: TriangleMeasurement[{{0, 0}, {3, 0}, {0, 4}}]
Wolfram Language code: Area[Triangle[{{0, 0}, {3, 0}, {0, 4}}]]

TriangleConstruct[{a,b,c},"Circumcircle"]はCircle[TriangleCenter[{a,b,c},"Circumcenter"],TriangleMeasurement[{a,b,c},"Circumradius"]]に等しい：

Wolfram Language code: tri = {{0, 0}, {1, 0}, {0, 1}}; TriangleConstruct[tri, "Circumcircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Circumcenter"], TriangleMeasurement[tri, "Circumradius"]]

TriangleConstruct[{a,b,c},"Excircle"]はCircle[TriangleCenter[{a,b,c},"Excenter"],TriangleMeasurement[{a,b,c},"Exradius"]]に等しい：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleConstruct[tri, "Excircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Excenter"], TriangleMeasurement[tri, "Exradius"]]

TriangleConstruct[{a,b,c},"ExteriorAngle"]はPlanarAngle[{a,b,c},"Exterior"]に等しい：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "ExteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "Exterior"]

TriangleConstruct[{a,b,c},"FullExteriorAngle"]はPlanarAngle[{a,b,c},"FullExterior"]に等しい：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "FullExteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "FullExterior"]

TriangleMeasurement[{a,b,c},"Height"]はArcLength[TriangleConstruct[{a,b,c},"Altitude"]]に等しい：

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Height"]
Wolfram Language code: TriangleConstruct[tri, "Altitude"]
Wolfram Language code: ArcLength[%]

TriangleConstruct[{a,b,c},"Incircle"]はCircle[TriangleCenter[{a,b,c},"Incenter"],TriangleMeasurement[{a,b,c},"Inradius"]]に等しい：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {3, 4}}; TriangleConstruct[tri, "Incircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "Incenter"], TriangleMeasurement[tri, "Inradius"]]

TriangleConstruct[{a,b,c},"InteriorAngle"]はPlanarAngle[{a,b,c},"Interior"]に等しい：

Wolfram Language code: tri = {{1, 1}, {0, 0}, {1, 0}}; TriangleMeasurement[tri, "InteriorAngle"]
Wolfram Language code: PlanarAngle[tri, "Interior"]

TriangleConstruct[{a,b,c},"NinePointCircle"]はCircle[TriangleCenter[{a,b,c},"NinePointCenter"],TriangleMeasurement[{a,b,c},"NinePointRadius"]]に等しい：

Wolfram Language code: tri = {{0, 0}, {3, 0}, {1, 2}}; TriangleConstruct[tri, "NinePointCircle"]
Wolfram Language code: Circle[TriangleCenter[tri, "NinePointCenter"], TriangleMeasurement[tri, "NinePointRadius"]]

TriangleConstruct[{a,b,c},"Perimeter"]はPerimeter[Triangle[{a,b,c}]]に等しい：

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Perimeter"]
Wolfram Language code: Perimeter[Triangle[tri]]

TriangleConstruct[{a,b,c},"Semiperimeter"]はPerimeter[Triangle[{a,b,c}]]/2に等しい：

Wolfram Language code: tri = {{-1, 0}, {2, 0}, {1, 2}}; TriangleMeasurement[tri, "Semiperimeter"]
Wolfram Language code: Perimeter[Triangle[tri]] / 2
Wolfram Research (2019), TriangleMeasurement, Wolfram言語関数， https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

テキスト

Wolfram Research (2019), TriangleMeasurement, Wolfram言語関数， https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

CMS

Wolfram Language. 2019. "TriangleMeasurement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TriangleMeasurement.html.

APA

Wolfram Language. (2019). TriangleMeasurement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TriangleMeasurement.html

BibTeX

@misc{reference.wolfram_2026_trianglemeasurement, author="Wolfram Research", title="{TriangleMeasurement}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/TriangleMeasurement.html}", note=[Accessed: 11-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_trianglemeasurement, organization={Wolfram Research}, title={TriangleMeasurement}, year={2019}, url={https://reference.wolfram.com/language/ref/TriangleMeasurement.html}, note=[Accessed: 11-November-2026]}