WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Weights

さまざまなフィット関数およびその他の関数のオプションで，データ要素に関連する重みを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Weights

Weights

さまざまなフィット関数およびその他の関数のオプションで，データ要素に関連する重みを指定する．

詳細

  • Weights->Automaticは重み1をすべてのデータ要素に関連付ける．
  • Weights->{w1,w2,…}は重み wiを i 番目のデータ要素に関連付ける．
  • Weights->func は重み func[xi1,xi2,…,yi]を i 番目のデータ要素に関連付ける．
  • VarianceEstimatorFunction->(1&)とWeights->{1/Δy12,1/Δy22,…}を使うと，Δyiは尺度 yiの既知の不確実性として扱われ，パラメータの標準誤差は事実上重みだけで計算される． »

例題

すべて開く すべて閉じる

例  (1)

等しい重みを使ってモデルをフィットする：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x]//Normal

データ点に明示的な重みを与える：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> 1 / Range[10]]//Normal

の値から重みを計算する：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> (Sqrt[#]&)]//Normal

応答値から重みを計算する：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> (Sqrt[#2]&)]//Normal

スコープ  (2)

非線形モデルで重みを使う：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
Wolfram Language code: NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x]//Normal

データ点に明示的な重みを与える：

Wolfram Language code: (nlm = NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x, Weights -> {1, (1/2), (1/3), (1/4)}])//Normal

一般化された線形モデル：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 10}};
Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Poisson"]//Normal
Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Poisson", Weights -> {1, 2, 3, 4}]//Normal

ロジットモデル：

Wolfram Language code: LogitModelFit[{.01, .3, .5, .7, .9}, x, x]//Normal
Wolfram Language code: LogitModelFit[{.01, .3, .5, .7, .9}, x, x, Weights -> (1 / Sqrt[#]&)]//Normal

プロビットモデル：

Wolfram Language code: ProbitModelFit[{.01, .3, .5, .7, .9}, x, x]//Normal
Wolfram Language code: ProbitModelFit[{.01, .3, .5, .7, .9}, x, x, Weights -> (1 / Sqrt[#]&)]//Normal

複数の変数を持つ関数による重み：

Wolfram Language code: data = {{2.8, 1.8, 4.5}, {1.8, 2.2, 2.7}, {0.6, 4.6, 1.6}, {2.8, 4.1, 2.6}, {3., 0.1, 3.7}};
Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}, Weights -> (Sqrt[#1 ^ 2 + #2 ^ 2]&)]//Normal

デフォルトの等しい重みを使う：

Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}]//Normal

応答値から重みを計算する：

Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}, Weights -> (Log[#3]&)]//Normal

アプリケーション  (1)

測定誤差を重みとして使って非線形モデルをフィットする：

Wolfram Language code: data = {{2.8, 1.8, 4.5}, {1.8, 2.2, 2.7}, {0.6, 4.6, 0.6}, {2.8, 4.1, 2.6}, {3., 0.1, 3.7}};
Wolfram Language code: Δys = {.1, .15, .12, .2, .08};
Wolfram Language code: nlm = NonlinearModelFit[data, a x Exp[b Sin[y]], {a, b}, {x, y}, Weights -> 1 / Δys ^ 2, VarianceEstimatorFunction -> (1&)]

パラメータのための標準誤差を求める：

Wolfram Language code: nlm["ParameterErrors"]

測定誤差からとは想定されない重みによる推定と比較する：

Wolfram Language code: nlm["ParameterErrors", VarianceEstimatorFunction -> Automatic]

特性と関係  (2)

重みはフィットのデータ点の相対的な重要性に影響を与える：

Wolfram Language code: LinearModelFit[Range[10], x ^ 2, x, Weights -> Range[10]]//Normal

定数によるスケーリングはパラメータ推定を変えはしない：

Wolfram Language code: LinearModelFit[Range[10], x ^ 2, x, Weights -> Range[10] / Total[Range[10]]]//Normal

重み付きの線形フィットからパラメータ推定を得る：

Wolfram Language code: data = RandomReal[10, {5, 2}]; wts = {1, 2, 3, 2, 1};
Wolfram Language code: LinearModelFit[data, {x, Sin[x]}, x, Weights -> wts]["BestFitParameters"]

LeastSquaresは重みが組み込まれると同等の結果を与える：

Wolfram Language code: dm = DesignMatrix[data, {x, Sin[x]}, x]; resp = data[[All, -1]]; LeastSquares[Sqrt[wts]dm, Sqrt[wts]resp]
Wolfram Research (2008), Weights, Wolfram言語関数， https://reference.wolfram.com/language/ref/Weights.html.

テキスト

Wolfram Research (2008), Weights, Wolfram言語関数， https://reference.wolfram.com/language/ref/Weights.html.

CMS

Wolfram Language. 2008. "Weights." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Weights.html.

APA

Wolfram Language. (2008). Weights. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Weights.html

BibTeX

@misc{reference.wolfram_2026_weights, author="Wolfram Research", title="{Weights}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Weights.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_weights, organization={Wolfram Research}, title={Weights}, year={2008}, url={https://reference.wolfram.com/language/ref/Weights.html}, note=[Accessed: 01-November-2026]}