WOLFRAM

Wolfram 语言与系统参考资料中心

Weights

不同拟合函数和其它函数的选项，指定与数据元素相关的权重.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

Weights

Weights

不同拟合函数和其它函数的选项，指定与数据元素相关的权重.

更多信息

  • Weights->Automatic，所有数据元素有权重 1.
  • Weights->{w1,w2,…}，第 i 个数据元素有权重 wi.
  • 使用Weights->func，则第 i 个数据元素有权重 func[xi1,xi2,…,yi].
  • 用 VarianceEstimatorFunction->(1&) 和 Weights->{1/Δy12,1/Δy22,…} 时，Δyi 是测量yi 的已知不准确度，而参数标准误差仅根据权重有效计算. »

范例

打开所有单元 关闭所有单元

基本范例  (1)

用相同的权重拟合一个模型：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x]//Normal

得到数据点的明确权重：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> 1 / Range[10]]//Normal

从 值计算权重：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> (Sqrt[#]&)]//Normal

从响应值计算权重：

Wolfram Language code: LinearModelFit[Range[10] ^ 2, x, x, Weights -> (Sqrt[#2]&)]//Normal

范围  (2)

在一个非线性模型中使用权重：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
Wolfram Language code: NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x]//Normal

给出数据点的明确权重：

Wolfram Language code: (nlm = NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x, Weights -> {1, (1/2), (1/3), (1/4)}])//Normal

一个广义线性模型：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 10}};
Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Poisson"]//Normal
Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Poisson", Weights -> {1, 2, 3, 4}]//Normal

对数模型：

Wolfram Language code: LogitModelFit[{.01, .3, .5, .7, .9}, x, x]//Normal
Wolfram Language code: LogitModelFit[{.01, .3, .5, .7, .9}, x, x, Weights -> (1 / Sqrt[#]&)]//Normal

概率模型：

Wolfram Language code: ProbitModelFit[{.01, .3, .5, .7, .9}, x, x]//Normal
Wolfram Language code: ProbitModelFit[{.01, .3, .5, .7, .9}, x, x, Weights -> (1 / Sqrt[#]&)]//Normal

多元变量的函数的权重：

Wolfram Language code: data = {{2.8, 1.8, 4.5}, {1.8, 2.2, 2.7}, {0.6, 4.6, 1.6}, {2.8, 4.1, 2.6}, {3., 0.1, 3.7}};
Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}, Weights -> (Sqrt[#1 ^ 2 + #2 ^ 2]&)]//Normal

用缺省的相等权重：

Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}]//Normal

根据响应值计算权重：

Wolfram Language code: LinearModelFit[data, {x, y}, {x, y}, Weights -> (Log[#3]&)]//Normal

应用  (1)

用测试误差作为权重拟合一个非线性模型：

Wolfram Language code: data = {{2.8, 1.8, 4.5}, {1.8, 2.2, 2.7}, {0.6, 4.6, 0.6}, {2.8, 4.1, 2.6}, {3., 0.1, 3.7}};
Wolfram Language code: Δys = {.1, .15, .12, .2, .08};
Wolfram Language code: nlm = NonlinearModelFit[data, a x Exp[b Sin[y]], {a, b}, {x, y}, Weights -> 1 / Δys ^ 2, VarianceEstimatorFunction -> (1&)]

得到参数的标准误差：

Wolfram Language code: nlm["ParameterErrors"]

与重量的估计比较，权重假设不从测量误差得到：

Wolfram Language code: nlm["ParameterErrors", VarianceEstimatorFunction -> Automatic]

属性和关系  (2)

权重影响拟合中相关的数据：

Wolfram Language code: LinearModelFit[Range[10], x ^ 2, x, Weights -> Range[10]]//Normal

常数的缩放并不改变参数估计：

Wolfram Language code: LinearModelFit[Range[10], x ^ 2, x, Weights -> Range[10] / Total[Range[10]]]//Normal

从一个加权线性拟合得到参数估计：

Wolfram Language code: data = RandomReal[10, {5, 2}]; wts = {1, 2, 3, 2, 1};
Wolfram Language code: LinearModelFit[data, {x, Sin[x]}, x, Weights -> wts]["BestFitParameters"]

当考虑权重时，LeastSquares 给出相等的结果：

Wolfram Language code: dm = DesignMatrix[data, {x, Sin[x]}, x]; resp = data[[All, -1]]; LeastSquares[Sqrt[wts]dm, Sqrt[wts]resp]
Wolfram Research (2008)，Weights，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Weights.html.

文本

Wolfram Research (2008)，Weights，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Weights.html.

CMS

Wolfram 语言. 2008. "Weights." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Weights.html.

APA

Wolfram 语言. (2008). Weights. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Weights.html 年

BibTeX

@misc{reference.wolfram_2026_weights, author="Wolfram Research", title="{Weights}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Weights.html}", note=[Accessed: 03-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_weights, organization={Wolfram Research}, title={Weights}, year={2008}, url={https://reference.wolfram.com/language/ref/Weights.html}, note=[Accessed: 03-September-2026]}