WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

WithCleanup[expr,cleanup]

expr を評価し，expr の評価中に，放棄，スロー等が生成された場合でも，結果を返す前に cleanup を実行する．

WithCleanup[init,expr,cleanup]

expr の評価の前に init を評価し，init と cleanup の両方の放棄やスロー等をブロックする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

WithCleanup

WithCleanup[expr,cleanup]

expr を評価し，expr の評価中に，放棄，スロー等が生成された場合でも，結果を返す前に cleanup を実行する．

WithCleanup[init,expr,cleanup]

expr の評価の前に init を評価し，init と cleanup の両方の放棄やスロー等をブロックする．

詳細

  • WithCleanup内の init と cleanup では，次のタイプの操作がさまざまな方法でブロックされる．
  • 中断Abortおよびインタラクティブな中断
    制約条件TimeConstrainedやMemoryConstrainedに基づいた終了
    コントロールの転送Throw，Confirm，Goto，Break，Continue …
  • init の評価中に中断が起動されても，即座にそうなる訳ではなく，expr は評価されないが cleanup は評価される．
  • expr の評価中に中断が起動されると，その評価は中断されるが cleanup は実行される．
  • cleanup の評価中に中断が起動されても，cleanup の評価が終了するまで延期される．
  • TimeConstrained[... WithCleanup[...]... ]等の構築によって外部的に生成された制約は，WithCleanupの中では中断のように振る舞う
  • WithCleanup[...]の外部へのコントロールの転送が init あるいは expr の中で起こると，init あるいは expr の評価が終了され，cleanup が評価され，その後で転送が行われる．
  • コントロールの転送は，cleanup の評価中に起こった場合は延期されない．

例題

すべて開く すべて閉じる

例  (2)

結果を返す前に x への割当てを削除する：

Wolfram Language code: WithCleanup[x = 7;x ^ 2, Clear[x]]

評価されているメインの式が中断されてもクリーンアップは行われる：

Wolfram Language code: WithCleanup[Echo[1], Abort[];Echo[2], Echo[3]]

他のタイプの例外があっても同じことが起る：

Wolfram Language code: Catch[WithCleanup[Echo[1], Throw[x];Echo[2], Echo[3]]]

スコープ  (2)

たとえ評価が中断されてもクリーンアップは実行される：

Wolfram Language code: f[WithCleanup[Abort[], Echo[1]]]
Wolfram Language code: f[WithCleanup[Echo[1];Abort[];Echo[2], Echo[3], Echo[4]]]

メインの式の評価中に外部制約に達してもクリーンアップは行われる：

Wolfram Language code: TimeConstrained[WithCleanup[Echo[1], Pause[5];Echo[2], Echo[3]], 1]
Wolfram Language code: MemoryConstrained[WithCleanup[Echo[1], Expand[(x + y)^10];Echo[2], Echo[3]], 1000]

WithCleanup内部の制約も特別な扱いは受けない：

Wolfram Language code: WithCleanup[Echo[1], TimeConstrained[Pause[5], 1];Echo[2], Echo[3]]

アプリケーション  (1)

計算が中断された場合でも，作業ファイルが確実に適切に閉じられるようにする：

Wolfram Language code: TimeConstrained[WithCleanup[file = CreateFile[], Do[Pause[.9];Write[file, i], {i, Infinity}], Close[file]], 3]

データは安全にディスクに書き込まれた：

Wolfram Language code: FilePrint[file]

同様に，計算がどのように終っても一時ファイルが確実に削除されるようにする：

Wolfram Language code: TimeConstrained[WithCleanup[Do[Pause[.9];Write[file, i], {i, Infinity}], Close[file];DeleteFile[file]], 3]

ファイルは成功裏に削除された：

Wolfram Language code: FileExistsQ[file]

特性と関係  (3)

初期化またはクリーンアップの最中に中断されても，これらの評価の終了を妨げはしない：

Wolfram Language code: WithCleanup[Abort[];Print[init], Print[main], Print[cleanup]]
Wolfram Language code: WithCleanup[Print[init], Print[main], Abort[];Print[cleanup]]

メインの式の評価中に中断があると，評価が即座に終了される：

Wolfram Language code: WithCleanup[Print[init], Abort[];Print[main], Print[cleanup]]

任意の引数での外部制御転送は，その引数の評価を即座に終了する：

Wolfram Language code: WithCleanup[Print["before throw"];Throw[end];Print["after throw"], Print[main], Print[cleanup]]//Catch

転送が前の引数で開始された場合はクリーンアップの評価が行われるので注意のこと：

Wolfram Language code: WithCleanup[Print[init], Print["before throw"];Throw[end];Print["after throw"], Print[cleanup]]//Catch

最後の引数では，制御転送がすぐに有効になる：

Wolfram Language code: WithCleanup[Print[init], Print[main], Print["before throw"];Throw[end];Print["after throw"]]//Catch

初期化とクリーンアップは，事実上，AbortProtectで包み込まれる：

Wolfram Language code: Print[1];AbortProtect[Abort[];Print[2]]
Wolfram Language code: WithCleanup[Print[1], Abort[];Print[2]]

考えられる問題  (1)

初期化とクリーンナップ内の計算はインタラクティブに中断したり時間制約を課したりできない：

Wolfram Language code: TimeConstrained[WithCleanup[Print["main"], Pause[5];Print["essential"]], 1]//AbsoluteTiming

本質的ではないすべてのコードをメインの式に移動する：

Wolfram Language code: TimeConstrained[WithCleanup[Print["main"];Pause[5], Print["essential"]], 1]//AbsoluteTiming
Wolfram Research (2020), WithCleanup, Wolfram言語関数， https://reference.wolfram.com/language/ref/WithCleanup.html.

テキスト

Wolfram Research (2020), WithCleanup, Wolfram言語関数， https://reference.wolfram.com/language/ref/WithCleanup.html.

CMS

Wolfram Language. 2020. "WithCleanup." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WithCleanup.html.

APA

Wolfram Language. (2020). WithCleanup. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WithCleanup.html

BibTeX

@misc{reference.wolfram_2026_withcleanup, author="Wolfram Research", title="{WithCleanup}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/WithCleanup.html}", note=[Accessed: 25-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_withcleanup, organization={Wolfram Research}, title={WithCleanup}, year={2020}, url={https://reference.wolfram.com/language/ref/WithCleanup.html}, note=[Accessed: 25-June-2026]}