WOLFRAM

Wolfram 语言与系统参考资料中心

BlockchainAddressData (for Bitcoin Cash)

BlockchainAddressData["address"]

返回比特币现金区块链上指定地址的相关信息.

BlockchainAddressData[assoc]

返回与 assoc 中匹配规范的属性相关的可用信息.

BlockchainAddressData[addressSpec,prop]

返回比特币现金区块链地址的指定属性.

更多信息

  • 区块链 address 可以按如下方式指定：
  • "address"比特币现金区块链上的地址
    "chain""address"指定公共区块链上的地址
    {"chain","network"}"address"比特币现金区块链中特定网络上的地址
  • 输入 addressSpec 指的是任何输入，无论它是一个 String 类型的 address，还是一个 Association 类型的 assoc.
  • 在 BlockchainAddressData[assoc] 中，关联 assoc 可以包含以下键的元素：
  • "Address"比特币现金区块链上的地址
    "TimeInterval"要包含的交易时间区间
    "BlockNumberInterval"要包含的交易区块区间
    "BlockNumber"与区块链上特定高度相关的编号
  • 属性包括：
  		• "Address"比特币现金地址
    "Balance"当前比特币现金余额的数值
    "ValueInUSDollars"当前余额的美元数值
    "TotalUTXO"与此地址关联的未花费交易输出的总数
    "UTXOList"此地址的未花费交易输出摘要列表
    "TotalTransactions"与此地址关联的交易总数
    "TransactionList"此地址的近期交易摘要列表
  • 如果关联 assoc 包含 "BlockNumber"、"BlockNumberInterval" 或 "TimeInterval"，则输出只会包含可用属性的一个子集.
  • "TransactionList" 提供一个以以下属性作为键的关联：
  • "TransactionID"交易哈希值
    "BlockNumber"包含该交易的区块编号
    "Timestamp"区块的时间戳
    "Inputs"交易的输入
    "Outputs"交易的输出
  • 可能的选择包括：
  • BlockchainBase $BlockchainBase设置区块链及其网络
    MaxItems 20返回的最大条目数
  • BlockchainAddressData 可以访问比特币现金主网（默认）和测试网网络. 要指定这些网络，请使用 BlockchainBase 选项.
  • 参数 MaxItems 用于指定结果中包含的最大事务数量.

范例

打开所有单元 关闭所有单元

基本范例  (8)

查看主网络中的比特币现金地址：

Wolfram Language code: BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", BlockchainBase -> "BitcoinCash"]//Dataset

在第一个参数中指定区块链：

Wolfram Language code: BlockchainAddressData["BitcoinCash" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m"]//Dataset

在第一个参数中指定区块链和网络：

Wolfram Language code: BlockchainAddressData[{"BitcoinCash", "Mainnet"} -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m"]//Dataset

获取数据块高度不超过 200,000 的地址数据：

Wolfram Language code: BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumber" -> 200000|>, BlockchainBase -> "BitcoinCash"]//Dataset

按区块过滤特定地址的交易列表：

Wolfram Language code: BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumberInterval" -> {200000, 270000}|>, "TransactionList", BlockchainBase -> "BitcoinCash"]//Dataset

按时间筛选特定地址的交易列表：

Wolfram Language code: BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "TimeInterval" -> {DateObject[{2014, 2, 1, 0, 0, 0}, "Instant", "Gregorian", -5.], DateObject[{2014, 3, 3, 0, 0, 0}, "Instant", "Gregorian", -5.]}|>, BlockchainBase -> "BitcoinCash"]//Dataset

从比特币现金地址获取财产数据：

Wolfram Language code: BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "ValueInUSDollars", BlockchainBase -> "BitcoinCash"]

从一个比特币现金地址获取多个属性：

Wolfram Language code: BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", {"Balance", "TotalTransactions"}, BlockchainBase -> "BitcoinCash"]

范围  (7)

地址  (1)

获取与所提供地址匹配的地址：

Wolfram Language code: addresses = {"Alice" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "Bob" -> "bitcoincash:qqzksq26n7kvelgf6ux5pxm0cxj4gm8vcclns8ed2w" };
Wolfram Language code: BlockchainAddressData["Alice" /. addresses, "Address", BlockchainBase -> "BitcoinCash"]

余额  (1)

获取比特币现金地址的当前余额：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "Balance", BlockchainBase -> "BitcoinCash"]

交易总额  (1)

获取与比特币现金地址相关的交易总额：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "TotalTransactions", BlockchainBase -> "BitcoinCash"]

总 UTXO  (1)

获取比特币现金地址的 UTXO 总量：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "TotalUTXO", BlockchainBase -> {"BitcoinCash", "Mainnet"}]

交易列表  (1)

获取与比特币地址相关的交易列表：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "TransactionList", BlockchainBase -> "BitcoinCash", MaxItems -> 5]//Dataset

UTXO 列表  (1)

获取比特币现金地址的 UTXO 列表：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "UTXOList", BlockchainBase -> {"BitcoinCash", "Mainnet"}]//Dataset

美元价值  (1)

获取比特币现金地址余额的当前美元价值：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "ValueInUSDollars", BlockchainBase -> "BitcoinCash"]

选项  (3)

BlockchainBase  (2)

Mainnet  (1)

从比特币现金主网地址获取信息：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", BlockchainBase -> {"BitcoinCash", "Mainnet"}]//Dataset

Testnet  (1)

从比特币现金测试网络地址获取信息：

Wolfram Language code: BlockchainAddressData["bchtest:qp3dzgxwn2mfn0l7xepv9p066wl7whsq2vv7nqgjpz", BlockchainBase -> {"BitcoinCash", "Testnet"}]//Dataset

MaxItems  (1)

列出比特币现金地址最近的五笔交易：

Wolfram Language code: BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "TransactionList", BlockchainBase -> "BitcoinCash", MaxItems -> 5]//Dataset

应用  (1)

获取特定比特币现金地址的 "ValueInUSDollars" 属性：

Wolfram Language code: value = BlockchainAddressData["bitcoincash:qzvkramkrmwycsws4pqxwhlqv5mvvwg8cqcaem6xkm", "ValueInUSDollars", BlockchainBase -> "BitcoinCash"]

将金额转换为另一种货币：

Wolfram Language code: CurrencyConvert[value, "PeruvianSoles"]

属性和关系  (4)

比特币现金地址可以以三种不同的形式指定：

Wolfram Language code: a1 = BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", BlockchainBase -> "BitcoinCash"];
Wolfram Language code: a2 = BlockchainAddressData["BitcoinCash" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m"];
Wolfram Language code: a3 = BlockchainAddressData[{"BitcoinCash", "Mainnet"} -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m"];

都是等价的：

Wolfram Language code: a1 === a2 === a3

由属性 "Address" 返回的值与所提供的地址相同：

Wolfram Language code: address = "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m";
Wolfram Language code: BlockchainAddressData[address, "Address", BlockchainBase -> "BitcoinCash"] === address

当按照 "BlockNumber"、"BlockNumberInterval" 或 "TimeInterval" 筛选地址时，输出结果不会包含所有可用属性，而只会包含其中的一个子集：

Wolfram Language code: availableProperties = Keys[BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", BlockchainBase -> "BitcoinCash", MaxItems -> 10]]
Wolfram Language code: filteredProperties = Keys[BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumber" -> 200000|>, BlockchainBase -> "BitcoinCash", MaxItems -> 10]]
Wolfram Language code: Complement[availableProperties, filteredProperties]//Column

使用 "BlockNumber" 来筛选一个地址以指定区块，相当于使用 "BlockNumberInterval" 并将区块范围设定为从区块 0 到指定的区块：

Wolfram Language code: res1 = BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumber" -> 170000|>, BlockchainBase -> "BitcoinCash"];
Wolfram Language code: res2 = BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumberInterval" -> {0, 170000}|>, BlockchainBase -> "BitcoinCash"];
Wolfram Language code: res1 === res2

可能存在的问题  (3)

不存在的地址  (2)

在一个网络中使用来自另一个网络的地址将返回一个 Missing 输出：

Wolfram Language code: BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", BlockchainBase -> "BitcoinCash"]//Dataset
Wolfram Language code: BlockchainAddressData["bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", BlockchainBase -> {"BitcoinCash", "Testnet"}]

当按区块高度或时间过滤某个在区块链中尚不存在的地址时，将返回一个 Missing 输出：

Wolfram Language code: BlockchainAddressData[<|"Address" -> "bitcoincash:qpsnhsmjkkq5j69v9na89mz9yugljnp9rvzljykg7m", "BlockNumber" -> 1500|>, BlockchainBase -> "BitcoinCash"]

不正确的地址  (1)

提供无效的地址、公钥或用户名将返回一个 $Failed 输出：

Wolfram Language code: BlockchainAddressData["x!=#%", BlockchainBase -> "BitcoinCash"]
Wolfram Research (2024)，BlockchainAddressData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html.

文本

Wolfram Research (2024)，BlockchainAddressData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html.

CMS

Wolfram 语言. 2024. "BlockchainAddressData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html.

APA

Wolfram 语言. (2024). BlockchainAddressData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html 年

BibTeX

@misc{reference.wolfram_2026_blockchainaddressdata, author="Wolfram Research", title="{BlockchainAddressData}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blockchainaddressdata, organization={Wolfram Research}, title={BlockchainAddressData}, year={2024}, url={https://reference.wolfram.com/language/ref/blockchain/BlockchainAddressData-BitcoinCash.html}, note=[Accessed: 09-August-2026]}