WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
"AlgebraicValue" (比較法)

"AlgebraicValue" (比較法)

代数操作を含まない計算は行いながら，代数解を求める問題に適した方法で数式を比較する．

詳細

  • 代数解の比較法は，Solve，SolveValues，Fit，Reduce等の求解操作を行うことなく2つの式が等価であるなら両者が同等であるとみなす．
  • 解答集と解答の値は，与えられたものと厳密に等しい値を保持するために，どちらもホールドされた式Hold[expr]として指定できる．値がホールドされている場合でも，代数関数（Solve並びにこれと同等の関数）以外の評価は，評価中に行われる．常に答をホールドすることが推奨される．
  • "AlgebraicValue"の評価は，問題の中の変数を指定するための設定"OptionalResultName"を許容する：AssessmentFunction[key,<|"ComparisonMethod""AlgebraicValue","OptionalResultName"setting|>]
  • 次は，setting のサポートされる値である．
  • var送信された結果の変数 var を受け入れる
    False（デフォルト） ans として提供された答だけをマッチする
    Truekey から var を推測しようとする
  • "OptionalResultName"var を使うときは，以下の任意の形式が答 ans の正しい形として受け入れられる．
  • ans
    Hold[var=ans]
    Hold[var==ans]
    varans
  • 等式と不等式は解答集でサポートされている．同等である式はどれも正解であるとみなされる．
  • 以下の表は，典型的な解答集について，"AlgebraicValue"とその他の比較法を比較したものである．

例題

すべて開く すべて閉じる

例  (1)

代数問題のAssessmentFunctionを作成する：

Wolfram Language code: solvetest = AssessmentFunction[{(-b - Sqrt[b^2 - 4 a c]/2 a), (-b + Sqrt[b^2 - 4 a c]/2 a)}, "AlgebraicValue"]

これを使って同等の形の答を評価する：

Wolfram Language code: solvetest[-(b/2 a) - (Sqrt[b^2 - 4 a c]/2 a)]

スコープ  (5)

直線が円と交わる場所を求める評価関数を作成する：

Wolfram Language code: geometryassess = AssessmentFunction[SolveValues[{x, y}∈InfiniteLine[{{0, 0}, {2, 1}}] && {x, y}∈Circle[], {x, y}], "AlgebraicValue"]

正しい答にチェックを付ける：

Wolfram Language code: geometryassess[{(2/Sqrt[5]), (1/Sqrt[5])}]

解を求めるコードを定義する：

Wolfram Language code: heldSolutionCode = Hold[First@SolveValues[Norm[{x, y}] == 1 && y == x / 2, {x, y}]];

このコードは代数解を求めるコードを含んでいるので正解にはならない：

Wolfram Language code: geometryassess[heldSolutionCode]

正解か否かの評価の前にコードが評価されて正解が出ている場合は，正解となる：

Wolfram Language code: geometryassess[ReleaseHold@heldSolutionCode]

方程式の解を求める：

Wolfram Language code: solution = SolveValues[x + 3 a == 5, x]

結果の名前として変数 x を含む答の別の形を許容する評価を作成する：

Wolfram Language code: solvetest = AssessmentFunction[solution, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> x|>]

通常の答は，求める変数名を含んでいる必要はない：

Wolfram Language code: solvetest[Hold[-3a + 5]]

以下は，代替形式として許容されるものである：

Wolfram Language code: solvetest[Hold[x = 5 - 3a]]
Wolfram Language code: solvetest[Hold[x -> 5 - 3a]]
Wolfram Language code: solvetest[Hold[x == 5 - 3a]]

これ以外の変数名を使用すると，不正解と評価される：

Wolfram Language code: solvetest[Hold[z == 5 - 3a]]

許可されている代替形式が使用されている場合は，変数名が解答集から推測されることがある：

Wolfram Language code: infered = AssessmentFunction[Hold[x = 5 - 3a], <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> True|>]
Wolfram Language code: infered[Hold[x -> 5 - 3a]]

変数名が答に含まれている必要はない：

Wolfram Language code: AssessmentFunction[Hold[x = 5 - 3a], <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> True|>][Hold[5 - 3a]]

方程式簡約問題の解を計算する：

Wolfram Language code: answerkey = Eliminate[{x == 2 + y, y == z}, y]

評価関数を定義する：

Wolfram Language code: equationtest = AssessmentFunction[answerkey, "AlgebraicValue"]

正解と等価である式はすべて受け入れられる：

Wolfram Language code: equationtest[Hold[2 + z == x]]
Wolfram Language code: equationtest[Hold[2 + z - x == 0]]

もとの問題は答としては受け入れられない：

Wolfram Language code: equationtest[Hold[Eliminate[{x == 2 + y, y == z}, y]]]

不等式についての評価関数を作成する：

Wolfram Language code: af = AssessmentFunction[Hold[y - x > 8], "AlgebraicValue"]

同等な不等式は正解とされる：

Wolfram Language code: af[Hold[x + 5 < y - 3]]

"AlgebraicForm"を使って，受容される答をより厳しく制限する：

Wolfram Language code: AssessmentFunction[Hold[y - x > 8], "AlgebraicForm"][Hold[x + 5 < y - 3]]

アプリケーション  (3)

複数の正解がある代数問題についてのQuestionObject を作成する：

Wolfram Language code: QuestionObject["Find a root of a x^2==b+1", AssessmentFunction[ {(-Sqrt[1 + b]/Sqrt[a]), (Sqrt[1 + b]/Sqrt[a])}, "AlgebraicValue" ]]

幾何の問題のQuestionObjectを作成する：

Wolfram Language code: QuestionObject[Column[{ StringForm["Find a point of intersection {x,y} for a circle at the origin of radius one and the line ``", y == (1 / a) x], Graphics[{Red, InfiniteLine[{0, 0}, {2, 1}], Blue, Circle[]}, Rule[...]] }], AssessmentFunction[SolveValues[{x, y}∈InfiniteLine[{{0, 0}, {a, 1}}] && {x, y}∈Circle[], {x, y}, Rule[...]], "AlgebraicValue"]]

値を見付けるのに役立つプロットを含む多項式解法問題を作成する．"OptionalResultName" を設定すると，受け入れられる解答形式に柔軟性が生まれる：

Wolfram Language code: QuestionObject[Column[{StringForm["Find all the roots of the polynomial p(x) = ``", pol = Expand[(x - 1) (x - 2) (x - 3) (x - 4)]], OpenerView[{Style["Helper:", Blue, Smaller], Plot[...]}]}], AssessmentFunction[{{1, 2, 3, 4}}, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> HoldPattern@x, "ListAssessment" -> "AllElementsOrderless"|>]]

特性と関係  (3)

代数とはみなされない操作の評価は，答がホールドされていても実行される：

Wolfram Language code: AssessmentFunction[Hold[10x], "AlgebraicValue"][Hold[Echo[5x + 5x]]]

"値がホールドされているときは，大域定義が評価中に無視される：

Wolfram Language code: x = 0; AssessmentFunction[Hold[10x], "AlgebraicValue"][Hold[0]]

変数がホールドされていないと，大域的定義が"OptionalResultName"に対して指定された名前と衝突することもある：

Wolfram Language code: z = 0;
Wolfram Language code: AssessmentFunction[10, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> z|>][Hold[z = 10]]

HoldまたはHoldPatternで変数を包み込んで大域的定義を無視する：

Wolfram Language code: AssessmentFunction[10, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> HoldPattern@z|>][Hold[z = 10]]
Wolfram Language code: AssessmentFunction[10, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> Hold@z|>][Hold[z = 10]]

"AlgebraicValue"法では，Plusのように代数問題は解かない関数の評価が許容される：

Wolfram Language code: AssessmentFunction[-1, "AlgebraicValue"][Hold[-3 + 2]]

代数問題を解く関数は評価されず，不正解とされる：

Wolfram Language code: AssessmentFunction[-1, "AlgebraicValue"][Hold[SolveValues[x + 1 == 0, {x}][[1, 1]]]]

"CalculusResult"は，代数を解く関数の評価を許容する：

Wolfram Language code: AssessmentFunction[-1, "CalculusResult"][Hold[SolveValues[x + 1 == 0, {x}][[1, 1]]]]

考えられる問題  (1)

複数の変数について，Solveを使って解答集を作成する：

Wolfram Language code: sol = Solve[{x, y}∈InfiniteLine[{{0, 0}, {2, 1}}] && {x, y}∈Circle[], {x, y}]

デフォルトの"ListAssessment"設定でAssessmentFunctionを作成すると，解答集の中の各リストが単一の答として扱われる：

Wolfram Language code: wholelistassessment = AssessmentFunction[sol, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> True|>]

解答集と同一の答だけが正しいとみなされる：

Wolfram Language code: wholelistassessment[{x -> -(2/Sqrt[5]), y -> -(1/Sqrt[5])}]

"OptionalResultName"Trueと設定しても，変数名がない値は不正解になる：

Wolfram Language code: wholelistassessment[{-(2/Sqrt[5]), -(1/Sqrt[5])}]

代りに，"AllElementsOrderless"または"AllElementsOrdered"を"ListAssessment"設定として使って各部分値を個別に評価する：

Wolfram Language code: elementassessment = AssessmentFunction[sol, <|"ComparisonMethod" -> "AlgebraicValue", "OptionalResultName" -> True, "ListAssessment" -> "AllElementsOrdered"|>]

解答集の個別の要素と答が別々にマッチされ，"OptionalResultName"設定は予想通りに動作する：

Wolfram Language code: elementassessment[{x -> -(2/Sqrt[5]), y == -(1/Sqrt[5])}]

算術面でのみ異なる数学的に等価な結果は受け入れられる：

Wolfram Language code: elementassessment[{Hold[-2Sqrt[5] / 5], -Hold[Sqrt[5] / 5]}]

等号を含む解答を与える場合は，Holdを使って値の設定を防ぐ：

Wolfram Language code: elementassessment[{Hold[x = -2Sqrt[5] / 5], Hold[y = -Sqrt[5] / 5]}]