WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
"Color" (比較法)

"Color" (比較法)

色の距離に基づいて2つの色を比較する．

詳細

  • "Color"比較法は，2つの色の違いが指定の許容範囲を超えないとき，この2色が等しいとみなす．
  • 許容範囲は，AssessmentFunctionのToleranceオプションを使って設定される．
  • デフォルトで，解答集の各値と提出された答の間の距離はColorDistanceを使って計算される．DistanceFunctionオプションを使ってColorDistanceがサポートする任意の設定を指定することができる．
  • 解答集の複数の値が答の許容範囲にあるときは，最も近い値が選択される．

例題

すべて開く すべて閉じる

例  (2)

色の問題についてのAssessmentFunctionを作成する：

Wolfram Language code: lightblue = AssessmentFunction[{LightBlue}, "Color", Tolerance -> 0.3]

これを使って答を評価する：

Wolfram Language code: lightblue[Blue]
Wolfram Language code: lightblue[Lighter[Blue, .8]]

複数の正解がある色の評価を作成する．"Color"比較法が自動的に選択される点に注意のこと：

Wolfram Language code: redwhiteblue = AssessmentFunction[{Red -> 1, White -> 2, Blue -> 3}, Tolerance -> 0.2]

RGBColorを使って答を指定する：

Wolfram Language code: answer = RGBColor[0, 0.1, 0.9]

これを評価する：

Wolfram Language code: result = redwhiteblue[answer]

点数を取り出す：

Wolfram Language code: result["Score"]

スコープ  (2)

デフォルトの許容範囲を0として評価を作成する：

Wolfram Language code: black = AssessmentFunction[Black, "Color"]

正解と判断されるためには，答は厳密に等しくなければならない：

Wolfram Language code: black[GrayLevel[0.0001]]
Wolfram Language code: black[GrayLevel[0.]]

解答集あるいは提出する答には，任意の有効な色指示子を使うことができる：

Wolfram Language code: rgbtest = AssessmentFunction[RGBColor[1, 0, 1], Tolerance -> 0.2]
Wolfram Language code: rgbtest /@ {CMYKColor[0., 1., 0., 0.], LABColor[0.60, 0.939, -0.60], XYZColor[0.57, 0.28, 0.72], LCHColor[0.60, 1.11, 0.90], Hue[0.83, 1., 1.], LUVColor[0.60, 0.94, -0.97]}

オプション  (1)

DistanceFunction  (1)

輝度に基づいて比較するようにDistanceFunctionを設定する：

Wolfram Language code: answerkeycolor = LABColor[0.52, -0.05, -0.18]
Wolfram Language code: luminancecompare = AssessmentFunction[answerkeycolor, Tolerance -> 0.2, DistanceFunction -> "DeltaL"]

輝度が等しい色は正解となる：

Wolfram Language code: luminancecompare[LABColor[0.58, .2, .6]]
Wolfram Language code: luminancecompare[RGBColor[0.91, 0.3, 0.01]]

その他は不正解となる：

Wolfram Language code: luminancecompare[RGBColor[0.39, 0.11, 0.01]]

アプリケーション  (3)

色の選択のためのQuestionObjectを作成する：

Wolfram Language code: QuestionObject[QuestionInterface["SelectColor", <|"Prompt" -> "What color is a pickle?"|>], AssessmentFunction[Green, Tolerance -> 0.2]]

ランダムなポケモンクイズを作成する：

Wolfram Language code: With[{p = RandomEntity["Pokemon"]}, QuestionObject[QuestionInterface["SelectColor", <|"Prompt" -> Column[{"What color is this pokemon? ", ColorConvert[p["Image"], "Grayscale"]}]|>], AssessmentFunction[DominantColors[p["Image"]], Tolerance -> 0.3]]]

画像からの色選択を評価するQuestionObjectを作成する：

Wolfram Language code: With[{mandrill = Image[ExampleData[{"TestImage", "Mandrill"}], ImageSize -> Medium]}, QuestionObject[QuestionInterface["ClickLocations", <|"Prompt" -> "Choose a red location in the image", "Background" -> mandrill|>], AssessmentFunction[Red, <|"ComparisonMethod" -> "Color"|>, Tolerance -> 0.4][RGBColor[First@PixelValue[mandrill, #]]]&] ]