WOLFRAM

Wolfram 语言与系统参考资料中心
"Color" (比较方法)

"Color" (比较方法)

Compare two colors based on color distance.

Details

  • The "Color" comparison method considers two colors to be equivalent if they do not differ beyond a given tolerance.
  • This tolerance is set using the Tolerance option in AssessmentFunction.
  • By default, the distance between each value of the answer key and the submitted answer is computed using ColorDistance. The DistanceFunction option can be used to specify any of the settings supported by ColorDistance.
  • When multiple values in the answer key are within the tolerance range of an answer, the closest value is selected.

范例

打开所有单元 关闭所有单元

基本范例  (2)

Create an AssessmentFunction for a color question:

Wolfram Language code: lightblue = AssessmentFunction[{LightBlue}, "Color", Tolerance -> 0.3]

Use it to assess answers:

Wolfram Language code: lightblue[Blue]
Wolfram Language code: lightblue[Lighter[Blue, .8]]

Create a color assessment with multiple correct answers. Note that the "Color" comparison method is automatically chosen:

Wolfram Language code: redwhiteblue = AssessmentFunction[{Red -> 1, White -> 2, Blue -> 3}, Tolerance -> 0.2]

Specify an answer using RGBColor:

Wolfram Language code: answer = RGBColor[0, 0.1, 0.9]

Assess it:

Wolfram Language code: result = redwhiteblue[answer]

Retrieve the score:

Wolfram Language code: result["Score"]

Scope  (2)

Create an assessment with a default tolerance of zero:

Wolfram Language code: black = AssessmentFunction[Black, "Color"]

The answer must be exactly the same to be considered correct:

Wolfram Language code: black[GrayLevel[0.0001]]
Wolfram Language code: black[GrayLevel[0.]]

Any valid color directive can be used in the answer keys or submitted answer:

Wolfram Language code: rgbtest = AssessmentFunction[RGBColor[1, 0, 1], Tolerance -> 0.2]
Wolfram Language code: rgbtest /@ {CMYKColor[0., 1., 0., 0.], LABColor[0.60, 0.939, -0.60], XYZColor[0.57, 0.28, 0.72], LCHColor[0.60, 1.11, 0.90], Hue[0.83, 1., 1.], LUVColor[0.60, 0.94, -0.97]}

Options  (1)

DistanceFunction  (1)

Set the DistanceFunction to compare based on luminance:

Wolfram Language code: answerkeycolor = LABColor[0.52, -0.05, -0.18]
Wolfram Language code: luminancecompare = AssessmentFunction[answerkeycolor, Tolerance -> 0.2, DistanceFunction -> "DeltaL"]

Colors with similar luminance are marked as correct:

Wolfram Language code: luminancecompare[LABColor[0.58, .2, .6]]
Wolfram Language code: luminancecompare[RGBColor[0.91, 0.3, 0.01]]

Others are incorrect:

Wolfram Language code: luminancecompare[RGBColor[0.39, 0.11, 0.01]]

Applications  (3)

Create a QuestionObject for color selection:

Wolfram Language code: QuestionObject[QuestionInterface["SelectColor", <|"Prompt" -> "What color is a pickle?"|>], AssessmentFunction[Green, Tolerance -> 0.2]]

Create a random Pokémon quiz:

Wolfram Language code: With[{p = RandomEntity["Pokemon"]}, QuestionObject[QuestionInterface["SelectColor", <|"Prompt" -> Column[{"What color is this pokemon? ", ColorConvert[p["Image"], "Grayscale"]}]|>], AssessmentFunction[DominantColors[p["Image"]], Tolerance -> 0.3]]]

Create a QuestionObject for assessing the selection of a color from an image:

Wolfram Language code: With[{mandrill = Image[ExampleData[{"TestImage", "Mandrill"}], ImageSize -> Medium]}, QuestionObject[QuestionInterface["ClickLocations", <|"Prompt" -> "Choose a red location in the image", "Background" -> mandrill|>], AssessmentFunction[Red, <|"ComparisonMethod" -> "Color"|>, Tolerance -> 0.4][RGBColor[First@PixelValue[mandrill, #]]]&] ]