WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiscretizePDE[cdata,mdata,sd,dep]

メソッドデータ mdata と解データ sd に基づく偏微分方程式の係数データ cdata の依存性 dep の一部を離散化して，DiscretizedPDEDataオブジェクトを生成する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
"SaveFiniteElements"  
"AssembleSystemMatrices"  
"PartialSystemMatricesAssembly"  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

DiscretizePDE

DiscretizePDE[cdata,mdata,sd,dep]

メソッドデータ mdata と解データ sd に基づく偏微分方程式の係数データ cdata の依存性 dep の一部を離散化して，DiscretizedPDEDataオブジェクトを生成する．

詳細とオプション

  • DiscretizePDEは，DiscretizedPDEDataオブジェクトを返す．
  • 係数データ cdata は，InitializePDECoefficientsによって生成されるPDECoefficientDataオブジェクトである．
  • メソッドデータ mdata は，InitializePDEMethodDataを通して生成される，FEMMethodData等の偏微分方程式のメソッドデータオブジェクトである．
  • 依存性 dep は，次のいずれかでよい．
  • "Discrete"離散変数に依存する線形係数
    "IndexedDiscrete"指標付きの離散変数に依存する線形係数
    "Nonlinear"非線形係数
    "Parametric"パラメータには依存するが，時間には依存しない線形係数
    "Stationary"独立空間変数には依存するが，時間やパラメータには依存しない線形係数
    "Transient"
  • 時間に依存する線形係数
  • DiscretizePDE[cdata,mdata,sd]は，DiscretizePDE[cdata,mdata,sd,"Stationary"]に等しい．
  • vd および sd の"Space"成分は，それぞれNumericalRegionオブジェクトとして表わされる空間変数および空間メッシュに設定されなければならない．
  • vd の"DependentVariables"成分は，引数を持たない未知の関数名のリストに設定されなければならない．
  • 時間依存問題については，vd および sd の"Time"成分は，それぞれ時間変数および現行の積分時間に設定されなければならない．
  • 時間積分の際に，離散時間においてのみ変化する離散変数あるいは指標付き離散変数に関する時間依存問題については，vd および sd の"Discrete"および／または"IndexedDiscrete"の成分は，それぞれ離散変数と初期離散値に設定されるべきである．
  • 解の過程で変化しないパラメータの問題については，vd および sd の"Parameters"成分は，それぞれパラメトリック変数と初期パラメトリック変数に設定されるべきである．
  • 次のオプションを与えることができる．
  • "AssembleSystemMatrices" Automatic系の行列をアセンブルするかどうか
    "PartialSystemMatricesAssembly" Automatic系の行列のどの部分をアセンブルするか
    "SaveFiniteElements" False計算された要素を保存するかどうか

例題

すべて開く すべて閉じる

例  (1)

有限要素法パッケージをロードする：

Wolfram Language code: Needs["NDSolve`FEM`"]

NumericalRegionを設定する：

Wolfram Language code: nr = ToNumericalRegion[Rectangle[{0, 0}, {1, 1 / 2}]]

変数データと解データを設定する：

Wolfram Language code: vd = NDSolve`VariableData[{"DependentVariables", "Space"} -> {{u}, {x, y}}]; sd = NDSolve`SolutionData[{"Space"} -> {nr}];

係数を初期化する：

Wolfram Language code: cdata = InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}];

初期化された偏微分方程式の係数を，メソッドデータと解データに基づいて離散化する：

Wolfram Language code: mdata = InitializePDEMethodData[vd, sd]; DiscretizePDE[cdata, mdata, sd]

スコープ  (2)

デフォルトでは，定常成分を離散化する：

Wolfram Language code: DiscretizePDE[cdata, mdata, sd] === DiscretizePDE[cdata, mdata, sd, "Stationary"]

対の偏微分方程式の変数データおよび偏微分方程式係数を設定する：

Wolfram Language code: vd2 = vd; NDSolve`SetSolutionDataComponent[vd2, "DependentVariables", {u, v}]; methodData2 = InitializePDEMethodData[vd2, sd]; initPDECoeff2 = InitializePDECoefficients[vd2, sd, "DiffusionCoefficients" -> -{{{{(100000/91), 0}, {0, (5000/13)}}, {{0, (30000/91)}, {(5000/13), 0}}}, {{{0, (5000/13)}, {(30000/91), 0}}, {{(5000/13), 0}, {0, (100000/91)}}}}];

メソッドデータと解データに基づいて，偏微分方程式係数の初期化された系を離散化する：

Wolfram Language code: DiscretizePDE[initPDECoeff2, methodData2, sd]

オプション  (3)

"SaveFiniteElements"  (1)

有限要素を保存して，変微分方程式を離散化する：

Wolfram Language code: finiteElements = DiscretizePDE[cdata, mdata, sd, "SaveFiniteElements" -> True]

生の剛性行列の有限要素を抽出する：

Wolfram Language code: finiteElements["StiffnessElements"]//Short

生の負荷ベクトルの有限要素を抽出する：

Wolfram Language code: finiteElements["LoadElements"]

偏微分方程式の寄与係数が指定されていない場合には，要素は何も計算されない．

生の減衰行列の有限要素を抽出する：

Wolfram Language code: finiteElements["DampingElements"]

生の質量行列の有限要素を抽出する：

Wolfram Language code: finiteElements["MassElements"]

系の行列はアセンブルされていない：

Wolfram Language code: finiteElements["StiffnessMatrix"]

"AssembleSystemMatrices"  (1)

有限要素を保存し系の行列をアセンブルした，偏微分方程式を離散化する：

Wolfram Language code: finiteElements = DiscretizePDE[cdata, mdata, sd, "SaveFiniteElements" -> True, "AssembleSystemMatrices" -> True]

生の剛性行列の有限要素を抽出する：

Wolfram Language code: finiteElements["StiffnessElements"]//Short

アセンブルされた剛性行列を抽出する：

Wolfram Language code: finiteElements["StiffnessMatrix"]

"PartialSystemMatricesAssembly"  (1)

偏微分方程式を部分的に離散化するためには，メッシュ要素をアセンブルされるブロックに分割しなければならない：

Wolfram Language code: mdata2 = InitializePDEMethodData[vd, sd, Method -> {"FiniteElement", "MeshOptions" -> {"MeshElementBlocks" -> 5}}];

メッシュ内のメッシュ要素ブロックを調べる：

Wolfram Language code: mdata2["ElementMesh"]

ブロック番号1，2，5で偏微分方程式を部分的に離散化する：

Wolfram Language code: dpde1 = DiscretizePDE[cdata, mdata2, sd, "PartialSystemMatricesAssembly" -> {1, 2, 5}]

アセンブルされた剛性行列を抽出そして可視化する：

Wolfram Language code: MatrixPlot[dpde1["StiffnessMatrix"]]

ブロック番号3と4で偏微分方程式を部分的に離散化する：

Wolfram Language code: dpde2 = DiscretizePDE[cdata, mdata2, sd, "PartialSystemMatricesAssembly" -> {3, 4}]

アセンブルされた剛性行列を抽出そして可視化する：

Wolfram Language code: MatrixPlot[dpde2["StiffnessMatrix"]]

すべてのメッシュ要素について偏微分方程式を離散化する：

Wolfram Language code: dpde = DiscretizePDE[cdata, mdata2, sd]

部分的にアセンブルされた系の行列の総和が，全体としてアセンブルされた系の行列に等しいことを確かめる：

Wolfram Language code: dpde["StiffnessMatrix"] == dpde1["StiffnessMatrix"] + dpde2["StiffnessMatrix"]

考えられる問題  (1)

DiscretizePDEが有限要素を保存する場合のために，系の行列は作成されない：

Wolfram Language code: dPDE = DiscretizePDE[cdata, mdata, sd, "SaveFiniteElements" -> True]

剛性行列は，何も項目を含んでいないことに注意する：

Wolfram Language code: dPDE["StiffnessMatrix"]

剛性行列を作成し，その要素を保存するためには，以下を使う：

Wolfram Language code: dPDE = DiscretizePDE[cdata, mdata, sd, "SaveFiniteElements" -> True, "AssembleSystemMatrices" -> True]
Wolfram Language code: dPDE["StiffnessMatrix"]
Wolfram Language code: dPDE["StiffnessElements"]//Short
Wolfram Research (2014), DiscretizePDE, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html.

テキスト

Wolfram Research (2014), DiscretizePDE, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html.

CMS

Wolfram Language. 2014. "DiscretizePDE." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html.

APA

Wolfram Language. (2014). DiscretizePDE. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html

BibTeX

@misc{reference.wolfram_2026_discretizepde, author="Wolfram Research", title="{DiscretizePDE}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretizepde, organization={Wolfram Research}, title={DiscretizePDE}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/DiscretizePDE.html}, note=[Accessed: 19-August-2026]}