WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SPARQLQuery[query]

RDFStoreに適用可能なクエリ演算子である．

SPARQLQuery["query"]

SPARQLのクエリ文字列を使う．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
関連項目
関連するガイド
引用書式
GraphStore`
GraphStore`

SPARQLQuery

SPARQLQuery[query]

RDFStoreに適用可能なクエリ演算子である．

SPARQLQuery["query"]

SPARQLのクエリ文字列を使う．

詳細とオプション

  • SPARQLExecuteでSPARQLQueryを使ってSPARQL Endpointのクエリが行える．
  • query は，SPARQLSelect，SPARQLAsk，SPARQLConstructの演算子でよい．
  • 集約はSPARQLQuery[SPARQLSelect[…]/*SPARQLAggregate[…]]として指定できる．
  • 次は，使用可能なオプションである．
  • "Base"Automatic相対IRIを解決するために使われる基底IRI
    "From"Automaticクエリするデフォルトグラフ
    "FromNamed"Automaticクエリする名前付きグラフのリスト
  • "From"{iri1,iri2,…}の設定のとき，irii で識別されたグラフのRDFマージがデフォルトグラフとして使われる．
  • SPARQLQuery[File[...]]とSPARQLQuery[URL[...]]もサポートされている．

例題

すべて開く すべて閉じる

例  (1)

Wolfram Language code: Needs["GraphStore`"]

RDFグラフの例を指定する：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: g = RDFStore[{ RDFTriple[ex["e1"], ex["a"], 1], RDFTriple[ex["e2"], ex["a"], 2], RDFTriple[ex["e3"], ex["a"], 3], RDFTriple[ex["e4"], ex["a"], 4], RDFTriple[ex["e1"], ex["b"], "x"], RDFTriple[ex["e2"], ex["b"], "y"], RDFTriple[ex["e3"], ex["b"], "z"], RDFTriple[ex["e4"], ex["b"], "x"] }];

指定された主語に関連付けられたすべてのデータについて尋ねる：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[RDFTriple[ex["e2"], SPARQLVariable["p"], SPARQLVariable["o"]]] ]

指定された述語に関連付けられたすべてのデータについて尋ねる：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[RDFTriple[SPARQLVariable["s"], ex["b"], SPARQLVariable["o"]]] ]

指定された述語について特定の値があるすべての主語を求める：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[RDFTriple[SPARQLVariable["s"], ex["b"], "x"]] ]

述語"b"について特定の値を持つ主語について，述語"a"の値を求める：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[{ RDFTriple[SPARQLVariable["s"], ex["a"], SPARQLVariable["a"]], RDFTriple[SPARQLVariable["s"], ex["b"], "x"] } -> "a"] ]

解を集約する：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[RDFTriple[SPARQLVariable["s"], ex["a"], SPARQLVariable["a"]]] /* SPARQLAggregate["total" -> SPARQLEvaluation["sum"][SPARQLVariable["a"]]] ]

解をグループ化して集約する：

Wolfram Language code: g//SPARQLQuery[ SPARQLSelect[{ RDFTriple[SPARQLVariable["s"], ex["a"], SPARQLVariable["a"]], RDFTriple[SPARQLVariable["s"], ex["b"], SPARQLVariable["b"]] }] /* SPARQLAggregate[{"b", "total" -> SPARQLEvaluation["sum"][SPARQLVariable["a"]]}, SPARQLVariable["b"]] ]

スコープ  (2)

Wolfram Language code: Needs["GraphStore`"]
Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: g = RDFStore[{ RDFTriple[ex["strawberry"], ex["color"], "red"] }];

SPARQLクエリ文字列を使ってクエリを指定する：

Wolfram Language code: g//SPARQLQuery[" prefix ex: <http://example.org/> select * where {ex:strawberry ex:color ?color .} "]
Wolfram Language code: Needs["GraphStore`"]

SPARQLクエリをエキスポートする：

Wolfram Language code: rdf[s_] := URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#" <> s]; schema[s_] := URL["http://schema.org/" <> s]; ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: ExportString[ SPARQLQuery[ SPARQLSelect[{ RDFTriple[SPARQLVariable["movie"], rdf["type"], schema["Movie"]], RDFTriple[SPARQLVariable["movie"], ex["durationHours"], SPARQLVariable["duration"]] } /; SPARQLVariable["duration"] > 5] ], "SPARQLQuery", "Prefixes" -> <| "schema" -> "http://schema.org/", "ex" -> "http://example.org/" |> ]

同じクエリをインポートする：

Wolfram Language code: ImportString[%, "SPARQLQuery"]
Wolfram Research (2019), SPARQLQuery, Wolfram言語関数， https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html.

テキスト

Wolfram Research (2019), SPARQLQuery, Wolfram言語関数， https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html.

CMS

Wolfram Language. 2019. "SPARQLQuery." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html.

APA

Wolfram Language. (2019). SPARQLQuery. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html

BibTeX

@misc{reference.wolfram_2026_sparqlquery, author="Wolfram Research", title="{SPARQLQuery}", year="2019", howpublished="\url{https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_sparqlquery, organization={Wolfram Research}, title={SPARQLQuery}, year={2019}, url={https://reference.wolfram.com/language/GraphStore/ref/SPARQLQuery.html}, note=[Accessed: 18-August-2026]}