WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AASTriangle[α,β,a]

角度が α および β で，辺の長さが a の塗り潰された三角形を返す．ただし，a は片方の角にのみ接している．

詳細とオプション
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AASTriangle

AASTriangle[α,β,a]

角度が α および β で，辺の長さが a の塗り潰された三角形を返す．ただし，a は片方の角にのみ接している．

詳細とオプション

  • AASTriangleは，2つの角とその片方の角に接した辺が決まっている三角形である．
  • AASTriangleは，2Dグラフィックスではプリミティブとして，また2Dの幾何学領域として使うことができる．
  • AASTriangleの指定されたパラメータ（青）と計算されたパラメータ（赤）．
  • AASTriangleは，原点に，正の 軸上に，の半平面上にがあるTriangleを返す．
  • AASTriangleでは，長さ a は任意の正の数でよく，角度 α および β は α+β<π となるような正の数でよい．

予備知識

  • AASTriangleは，2つの角とその片方の角に接した辺が決まっている三角形を構築する．具体的に言うと，AASTriangle[α,β,a]は，頂点，，が，順にTemplateBox[{}, Reals]^2上の，原点，正の 軸上，上半平面に位置するTriangleを表す．α∠BAC，β∠ABCで，a はの対辺の長さである．AAS定理により，このように指定された三角形は（幾何学的合同という点で）一意的である．AASTriangleの a の長さは任意の正の数でよく，角 α および角 β は α+β<π を満足する正の数でよい．AASTriangleの引数は厳密または近似の数式でよい．
  • AASTriangleが返すTriangleオブジェクトは，2Dのグラフィックスプリミティブあるいは幾何領域として使うことができる．
  • AASTriangleは数多くの他のシンボルと関連がある．ASATriangle，SASTriangle，SSSTriangleは，異なる角および／または辺の指定を使って構築された二次元の三角形を返す．最後に，AASTriangleは，AASTriangle[α,β,a]がTriangle[{{0,0},{a Csc[α] Sin[α+β],0},{a Cot[α] Sin[β],a Sin[β]}}]と等しいと言う意味で，Triangleの特殊ケースである．

例題

すべて開く すべて閉じる

例  (4)

，，の三角形：

Wolfram Language code: AASTriangle[Pi / 6, Pi / 3, 1]

AASTriangle：

Wolfram Language code: Graphics[AASTriangle[Pi / 6, Pi / 3, 1]]

異なるスタイルが適用されたAASTriangle：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面積と重心：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Area[ℛ]

重心：

Wolfram Language code: RegionCentroid[ℛ]

スコープ  (14)

グラフィックス  (4)

指定  (2)

AASTriangleを評価すると，原点に点の1つがあり，1辺が 軸上にあるTriangleになる：

Wolfram Language code: t = AASTriangle[Pi / 4, Pi / 3, 1]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

記号による角度のある三角形：

Wolfram Language code: t = AASTriangle[Pi / 4, β, 1]

プロットする：

Wolfram Language code: Table[Graphics[t, ImageSize -> Tiny, PlotLabel -> β], {β, 2π / 8, 5π / 8, π / 8}]

スタイリング  (2)

面の色を色指示子で指定する：

Wolfram Language code: Table[Graphics[{c, AASTriangle[Pi / 6, Pi / 3, 1]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormおよびEdgeFormを使って内側と境界のスタイルを指定することができる：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], AASTriangle[Pi / 6, Pi / 3, 1]}]

領域  (10)

埋込み次元は三角形がある空間の次元である：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

幾何次元は三角形自体の次元である：

Wolfram Language code: RegionDimension[ℛ]

帰属判定：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {RegionMember[ℛ, {1, 1 / 2}], RegionMember[ℛ, {1, 1}]}

帰属条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

面積：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

ある点からAASTriangleまでの距離：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]

これを可視化する：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付きの距離：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]
Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

最近点：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionNearest[ℛ, {1, 1}]

これを可視化する：

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三角形は有界である：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

その範囲を求める：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

AASTriangle上で積分(Integrate)する：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

この上で最適化する：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Minimize[{(x - 1)^2(3y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

AASTriangle上で方程式を解く：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

アプリケーション  (2)

2角が等しい三角形は，二等辺三角形である：

Wolfram Language code: IsoscelesTriangle[α_, s_] := AASTriangle[α, α, s]
Wolfram Language code: t = IsoscelesTriangle[3π / 8, 1]

可視化する：

Wolfram Language code: Region[t]

面積を求める：

Wolfram Language code: Area@IsoscelesTriangle[α, s]

AASTriangleの外接円は，Circumsphereを使って求めることができる：

Wolfram Language code: tri = AASTriangle[Pi / 4, Pi / 3, 1.]

外接円は3つの端点を通る：

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

三角形の各辺の中点を求める：

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

垂直二等分線は，外心から中点までの直線である：

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Point[center], Point[midpts]}, {Red, Dashed, bisectors}}]

特性と関係  (2)

AASTriangleはTriangleの特殊ケースである：

Wolfram Language code: AASTriangle[α, β, a]

AASTriangleはPolygonで表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = AASTriangle[Pi / 6, Pi / 3, 1]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {2, 0}, {3 / 2, Sqrt[3] / 2}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

おもしろい例題  (1)

角度を変える：

Wolfram Language code: Graphics[{Opacity[0.15], Table[{ColorData["Rainbow"][Rescale[β, {0.1, 0.9}]], AASTriangle[1, 1 + β, 1]}, {β, 0.1, 0.9, 0.04}]}]
Wolfram Research (2014), AASTriangle, Wolfram言語関数， https://reference.wolfram.com/language/ref/AASTriangle.html.

テキスト

Wolfram Research (2014), AASTriangle, Wolfram言語関数， https://reference.wolfram.com/language/ref/AASTriangle.html.

CMS

Wolfram Language. 2014. "AASTriangle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AASTriangle.html.

APA

Wolfram Language. (2014). AASTriangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AASTriangle.html

BibTeX

@misc{reference.wolfram_2026_aastriangle, author="Wolfram Research", title="{AASTriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AASTriangle.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_aastriangle, organization={Wolfram Research}, title={AASTriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/AASTriangle.html}, note=[Accessed: 09-August-2026]}