WOLFRAM

Wolfram 语言与系统参考资料中心

AASTriangle[α,β,a]

返回实心三角形，其中角为 α 和 β，边长为 a，且 a 仅与一个角相邻.

更多信息和选项
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式化  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

AASTriangle

AASTriangle[α,β,a]

返回实心三角形，其中角为 α 和 β，边长为 a，且 a 仅与一个角相邻.

更多信息和选项

  • AASTriangle 也被称为角角边三角形.
  • AASTriangle 可用作二维图形的基元和二维几何区域.
  • AASTriangle 的已知（蓝色）和计算得到的（红色）参数：
  • AASTriangle 返回 Triangle，其中 在原点， 在正 轴， 在半平面 .
  • AASTriangle 允许长度 a 为任意正数，角 α 和 β 为任意满足 α+β<π 的正数.

背景

  • AASTriangle 构建角角边三角形. 特别地，AASTriangle[α,β,a] 返回位于 TemplateBox[{}, Reals]^2 的 Triangle，其中顶点 、 和 分别位于原点、 正半轴和上半平面，且有 α∠BAC， β∠ABC 和 a 为顶点 的对边长度. 根据 AAS 定理，这样指定的三角形是唯一的（达到几何一致性）. AASTriangle 允许长度 a 为任意正数，角 α 和 β 为任意满足 α+β<π 的正数. AASTriangle 的参数可以是精确或近似的数值表达式.
  • 由 AASTriangle 返回的 Triangle 对象可以用作二维图形基元或几何区域.
  • AASTriangle 与若干其它符号相关. ASATriangle、SASTriangle 和 SSSTriangle 返回使用不同角和/或边规范构建的二维三角形. 最后，AASTriangle 是 Triangle 的一种特殊情况，原因在于AASTriangle[α,β,a] 等价于Triangle[{{0,0},{a Csc[α] Sin[α+β],0},{a Cot[α] Sin[β],a Sin[β]}}].

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个三角形，其中 ， 且 ：

Wolfram Language code: AASTriangle[Pi / 6, Pi / 3, 1]

一个 AASTriangle：

Wolfram Language code: Graphics[AASTriangle[Pi / 6, Pi / 3, 1]]

应用于 AASTriangle 的不同样式：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面积和形心：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Area[ℛ]

形心：

Wolfram Language code: RegionCentroid[ℛ]

范围  (14)

图形  (4)

规范  (2)

AASTriangle 运算为 Triangle，其中一个点在原点，一条边在 轴：

Wolfram Language code: t = AASTriangle[Pi / 4, Pi / 3, 1]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

具有符号式角的三角形：

Wolfram Language code: t = AASTriangle[Pi / 4, β, 1]

绘制这些三角形：

Wolfram Language code: Table[Graphics[t, ImageSize -> Tiny, PlotLabel -> β], {β, 2π / 8, 5π / 8, π / 8}]

样式化  (2)

颜色指令指定表面颜色：

Wolfram Language code: Table[Graphics[{c, AASTriangle[Pi / 6, Pi / 3, 1]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], AASTriangle[Pi / 6, Pi / 3, 1]}]

区域  (10)

嵌入维度是三角形所在空间的维度：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是三角形本身的维度：

Wolfram Language code: RegionDimension[ℛ]

成员检验：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {RegionMember[ℛ, {1, 1 / 2}], RegionMember[ℛ, {1, 1}]}

成员条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

面积：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

形心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

从一个点到 AASTriangle 的距离：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]

可视化该距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的符号距离：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]
Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

最近点：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionNearest[ℛ, {1, 1}]

可视化：

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三角形是有界的：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

在 AASTriangle 上进行 Integrate 计算：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

对其进行最优化：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Minimize[{(x - 1)^2(3y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

在 AASTriangle 上求解方程：

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

应用  (2)

有两个角相等的三角形为等腰三角形：

Wolfram Language code: IsoscelesTriangle[α_, s_] := AASTriangle[α, α, s]
Wolfram Language code: t = IsoscelesTriangle[3π / 8, 1]

可视化：

Wolfram Language code: Region[t]

求面积：

Wolfram Language code: Area@IsoscelesTriangle[α, s]

AASTriangle 的外接圆可以使用 Circumsphere 得到：

Wolfram Language code: tri = AASTriangle[Pi / 4, Pi / 3, 1.]

外接圆通过三个顶点：

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

求三角形每条边的中点：

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

中垂线是从外接圆圆心到中点的直线：

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Point[center], Point[midpts]}, {Red, Dashed, bisectors}}]

属性和关系  (2)

AASTriangle 是 Triangle 的特例：

Wolfram Language code: AASTriangle[α, β, a]

AASTriangle 可用 Polygon 表示：

Wolfram Language code: Subscript[ℛ, 1] = AASTriangle[Pi / 6, Pi / 3, 1]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {2, 0}, {3 / 2, Sqrt[3] / 2}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

改变角度：

Wolfram Language code: Graphics[{Opacity[0.15], Table[{ColorData["Rainbow"][Rescale[β, {0.1, 0.9}]], AASTriangle[1, 1 + β, 1]}, {β, 0.1, 0.9, 0.04}]}]
Wolfram Research (2014)，AASTriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AASTriangle.html.

文本

Wolfram Research (2014)，AASTriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AASTriangle.html.

CMS

Wolfram 语言. 2014. "AASTriangle." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AASTriangle.html.

APA

Wolfram 语言. (2014). AASTriangle. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AASTriangle.html 年

BibTeX

@misc{reference.wolfram_2026_aastriangle, author="Wolfram Research", title="{AASTriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AASTriangle.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_aastriangle, organization={Wolfram Research}, title={AASTriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/AASTriangle.html}, note=[Accessed: 12-August-2026]}