WOLFRAM

Wolfram 语言与系统参考资料中心

ASATriangle[α,c,β]

返回实心三角形，其中角为 α 和 β，边长为 c，且 c 与这两个角都相邻.

更多信息和选项
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式化  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ASATriangle

ASATriangle[α,c,β]

返回实心三角形，其中角为 α 和 β，边长为 c，且 c 与这两个角都相邻.

更多信息和选项

  • ASATriangle 也被称为角边角三角形.
  • ASATriangle 可用作二维图形的基元和二维几何区域.
  • ASATriangle 的已知（蓝色）和计算得到的（红色）参数：
  • ASATriangle 返回 Triangle，其中 在原点， 在正 轴， 在半平面 .
  • ASATriangle 允许长度 c 为任意正数，角 α 和 β 为任意满足 α+β<π 的正数.

背景

  • ASATriangle 构建角边角三角形. 特别地，ASATriangle[α,c,β] 表示位于TemplateBox[{}, Reals]^2 的 Triangle，其中顶点 、 和 分别位于原点、 正半轴和上半平面，且有 α∠BAC，β∠ABC 和 c 为顶点 的对边长度. 根据 ASA 定理，这样指定的三角形是唯一的（达到几何一致性）. ASATriangle 允许长度 c 为任意正数，角 α 和 β 为任意满足 α+β<π 的正数. ASATriangle 的参数可以是精确或近似的数值表达式.
  • 由 ASATriangle 返回的 Triangle 对象可以用作二维图形基元或几何区域.
  • ASATriangle 与若干其它符号相关. AASTriangle、SASTriangle 和 SSSTriangle 返回使用不同角和/或边规范构建的二维三角形. ASATriangle 是 Triangle 的一种特殊情况，原因在于 ASATriangle[α,c,β] 等价于 Triangle[{{0,0},{c,0},{c x,c y}}] ，其中 xCos[α] Csc[α+β] Sin[β] 且 yCsc[α+β] Sin[α] Sin[β].

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个三角形，其中 ，，且 ：

Wolfram Language code: ASATriangle[Pi / 6, 1, Pi / 3]

ASATriangle：

Wolfram Language code: Graphics[ASATriangle[Pi / 6, 1, Pi / 3]]

应用于 ASATriangle 的不同样式：

Wolfram Language code: ℛ = ASATriangle[Pi / 6, 1, Pi / 3]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面积和形心：

Wolfram Language code: ℛ = ASATriangle[Pi / 6, 1, Pi / 3];
Wolfram Language code: Area[ℛ]

形心：

Wolfram Language code: RegionCentroid[ℛ]

范围  (14)

图形  (4)

规范  (2)

ASATriangle 运算得到 Triangle，其中一个点在原点，一条边在 轴：

Wolfram Language code: t = ASATriangle[Pi / 4, 1, Pi / 4]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

具有符号式角的三角形：

Wolfram Language code: t = ASATriangle[Pi / 4, 1, β]

绘制这些三角形：

Wolfram Language code: Table[Graphics[t, ImageSize -> Tiny, PlotLabel -> β], {β, π / 4, 5π / 8, π / 8}]

样式化  (2)

颜色指令指定表面颜色：

Wolfram Language code: Table[Graphics[{c, ASATriangle[Pi / 6, 1, Pi / 3]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], ASATriangle[Pi / 6, 1, Pi / 3]}]

区域  (10)

嵌入维度是三角形所在空间的维度：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是三角形本身的维度：

Wolfram Language code: RegionDimension[ℛ]

成员检验：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {2, 1}]}

得到成员条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

面积：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

形心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

从一个点到 ASATriangle 的距离：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionDistance[ℛ, {2, 1}]
Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的带符号距离：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]

现在对其绘图：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

最近点：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionNearest[ℛ, {2, 1}]

可视化：

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三角形是有界的：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

在 ASATriangle 上进行 Integrate 计算：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

对其进行最优化：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Minimize[{(x - 1)^2(y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

在 ASATriangle 上求解方程：

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

应用  (2)

有两个角相等的三角形为等腰三角形：

Wolfram Language code: IsoscelesTriangle[α_, s_] := ASATriangle[α, s, α]
Wolfram Language code: t = IsoscelesTriangle[3π / 8, 1]

可视化：

Wolfram Language code: Region[t]

求它的面积：

Wolfram Language code: Area@IsoscelesTriangle[α, s]

ASATriangle 的外接圆可以使用 Circumsphere 得到：

Wolfram Language code: tri = ASATriangle[Pi / 3, 1., Pi / 3]

外接圆通过三个顶点：

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

求三角形每条边的中点：

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

垂直平分线是从外接圆圆心到中点的直线：

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Red, Point[center]}, {Red, Point[midpts]}, {Red, Dashed, bisectors}}]

属性和关系  (2)

ASATriangle 是 Triangle 的特例：

Wolfram Language code: ASATriangle[α, c, β]

ASATriangle 可用 Polygon 表示：

Wolfram Language code: Subscript[ℛ, 1] = ASATriangle[Pi / 4, Sqrt[2], Pi / 2]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {Sqrt[2], 0}, {Sqrt[2], Sqrt[2]}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

同时改变两个角：

Wolfram Language code: Graphics[{Opacity[0.2], Table[{ColorData["Rainbow"][Rescale[β, {0.1, 0.9}]], ASATriangle[1 - β, 1, 1 + β]}, {β, 0.1, 0.9, 0.04}]}]
Wolfram Research (2014)，ASATriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ASATriangle.html.

文本

Wolfram Research (2014)，ASATriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ASATriangle.html.

CMS

Wolfram 语言. 2014. "ASATriangle." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ASATriangle.html.

APA

Wolfram 语言. (2014). ASATriangle. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ASATriangle.html 年

BibTeX

@misc{reference.wolfram_2026_asatriangle, author="Wolfram Research", title="{ASATriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ASATriangle.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_asatriangle, organization={Wolfram Research}, title={ASATriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/ASATriangle.html}, note=[Accessed: 10-August-2026]}