WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Accumulate[list]

list 中の要素の連続累計のリストを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Accumulate

Accumulate[list]

list 中の要素の連続累計のリストを与える．

詳細とオプション

  • Accumulate[list]は list と同じ長さである．
  • Accumulate[list]は，実質的にFoldList[Plus,list]と等価である．
  • Accumulate[list,Method"CompensatedSummation"]は補正加算を使って結果の数値誤差を小さくする．

例題

すべて開く すべて閉じる

例  (2)

累積和：

Wolfram Language code: Accumulate[{a, b, c, d}]

列内での累積：

Wolfram Language code: Accumulate[{{a, b}, {c, d}, {e, f}}]

スコープ  (3)

定期的にサンプルされたTimeSeriesを累積する：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; ts = TimeSeries[v, Automatic]

作成されたタイムスタンプは間隔が一定している：

Wolfram Language code: RegularlySampledQ[ts]

累積する：

Wolfram Language code: res = Accumulate[ts]

経路：

Wolfram Language code: res["Path"]

累積された値と比較する：

Wolfram Language code: Accumulate[v]

不規則にサンプルを取られた時系列を累積する：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; t = {1, 3, 5, 6, 7, 10}; ts = TimeSeries[v, {t}];
Wolfram Language code: RegularlySampledQ[ts]

値を累積する：

Wolfram Language code: res1 = Accumulate[ts["Values"]]

新たな時系列を定義し，TemporalRegularityをTrueに設定することもできる：

Wolfram Language code: ts2 = TimeSeries[ts, TemporalRegularity -> True];

経路は変わらない：

Wolfram Language code: ts["Path"] == ts2["Path"]

これで，Accumulateの結果がTimeSeriesで与えられるようになった：

Wolfram Language code: res2 = Accumulate[ts2]
Wolfram Language code: res2["Values"] == res1

数量を含むデータを累積する：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: Accumulate[data]

一般化と拡張  (1)

頭部がListである必要はない：

Wolfram Language code: Accumulate[f[a, b, c, d]]

アプリケーション  (4)

三角数：

Wolfram Language code: Accumulate[Range[10]]

ランダムウォーク：

Wolfram Language code: ListLinePlot[Accumulate[RandomReal[{-1, 1}, 100]]]

理想化されたランダムな山腹：

Wolfram Language code: ListPlot3D[Accumulate[RandomReal[{-.1, 1}, {30, 30}]]]

級数中の項の累積和：

Wolfram Language code: List@@Normal[Series[Sin[x], {x, 0, 10}]]
Wolfram Language code: Plot[Evaluate[Accumulate[%]], {x, 0, 2Pi}]

特性と関係  (3)

DifferencesはAccumulateのほぼ正反対である：

Wolfram Language code: Accumulate[Range[10]]
Wolfram Language code: Differences[%]

AccumulateはFoldListの特定のケースと等価である：

Wolfram Language code: FoldList[Plus, {a, b, c, d}]
Wolfram Language code: Accumulate[{a, b, c, d}]

Sumを使って数列を記号的に累積する：

Wolfram Language code: s = Sum[i ^ 2, {i, 1, n}]
Wolfram Language code: Table[s, {n, 1, 10}]
Wolfram Language code: Accumulate[Table[i ^ 2, {i, 1, 10}]]

考えられる問題  (1)

不規則にサンプルを取られた時系列を直接累積したものは，その値を累積したものとは異なることがある：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; t = {1, 3, 5, 6, 7, 10}; ts = TimeSeries[v, {t}]

経路：

Wolfram Language code: ts["Path"]

定期的にサンプルされているかどうかチェックする：

Wolfram Language code: RegularlySampledQ[ts]

時系列を累積する：

Wolfram Language code: res = Accumulate[ts]
Wolfram Language code: res["Path"]

これは累積された値と同じではない：

Wolfram Language code: av = Accumulate[v]

時系列は，まずMinimumTimeIncrementに従ってアップサンプルされ，次にダウンサンプルされている：

Wolfram Language code: ts1 = TimeSeriesResample[ts]; aux = Accumulate[ts1]; res1 = TimeSeriesResample[aux, {t}]
Wolfram Language code: res1["Path"] == res["Path"]

一時的な規則性を仮定し，単純に値を累積する：

Wolfram Language code: ts2 = TimeSeries[ts, TemporalRegularity -> True]
Wolfram Language code: ts["Path"] == ts2["Path"]
Wolfram Language code: res2 = Accumulate[ts2]
Wolfram Language code: res2["Path"]
Wolfram Language code: res2["Values"] == av

おもしろい例題  (1)

パスカルの三角形の対角線：

Wolfram Language code: Transpose[NestList[Accumulate, Range[5], 5]]
Wolfram Research (2007), Accumulate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Accumulate.html （2008年に更新）.

テキスト

Wolfram Research (2007), Accumulate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Accumulate.html （2008年に更新）.

CMS

Wolfram Language. 2007. "Accumulate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Accumulate.html.

APA

Wolfram Language. (2007). Accumulate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Accumulate.html

BibTeX

@misc{reference.wolfram_2026_accumulate, author="Wolfram Research", title="{Accumulate}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Accumulate.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_accumulate, organization={Wolfram Research}, title={Accumulate}, year={2008}, url={https://reference.wolfram.com/language/ref/Accumulate.html}, note=[Accessed: 09-August-2026]}