WOLFRAM

Wolfram 语言与系统参考资料中心

Accumulate[list]

给出 list 中元素的逐次累积总值列表.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Accumulate

Accumulate[list]

给出 list 中元素的逐次累积总值列表.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

累积和：

Wolfram Language code: Accumulate[{a, b, c, d}]

在列内累积：

Wolfram Language code: Accumulate[{{a, b}, {c, d}, {e, f}}]

范围  (3)

累积一个规则采样的 TimeSeries：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; ts = TimeSeries[v, Automatic]

所创建的时间标记的间距是规则的：

Wolfram Language code: RegularlySampledQ[ts]

累积：

Wolfram Language code: res = Accumulate[ts]

路径：

Wolfram Language code: res["Path"]

与累积值比较：

Wolfram Language code: Accumulate[v]

累积一个不规则采样的时间序列：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; t = {1, 3, 5, 6, 7, 10}; ts = TimeSeries[v, {t}];
Wolfram Language code: RegularlySampledQ[ts]

累积值：

Wolfram Language code: res1 = Accumulate[ts["Values"]]

或者定义一个新的时间序列，并设置 TemporalRegularity 为 True：

Wolfram Language code: ts2 = TimeSeries[ts, TemporalRegularity -> True];

路径没有变化：

Wolfram Language code: ts["Path"] == ts2["Path"]

现在，Accumulate 的结果作为 TimeSeries 给出：

Wolfram Language code: res2 = Accumulate[ts2]
Wolfram Language code: res2["Values"] == res1

累积带有单位的数据：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: Accumulate[data]

推广和延伸  (1)

头部不一定是 List：

Wolfram Language code: Accumulate[f[a, b, c, d]]

应用  (4)

三角形数：

Wolfram Language code: Accumulate[Range[10]]

随机行走：

Wolfram Language code: ListLinePlot[Accumulate[RandomReal[{-1, 1}, 100]]]

理想化的随机山坡：

Wolfram Language code: ListPlot3D[Accumulate[RandomReal[{-.1, 1}, {30, 30}]]]

一个级数中各项的累积和：

Wolfram Language code: List@@Normal[Series[Sin[x], {x, 0, 10}]]
Wolfram Language code: Plot[Evaluate[Accumulate[%]], {x, 0, 2Pi}]

属性和关系  (3)

Differences 几乎与 Accumulate 逆反：

Wolfram Language code: Accumulate[Range[10]]
Wolfram Language code: Differences[%]

Accumulate 等价于特定的 FoldList：

Wolfram Language code: FoldList[Plus, {a, b, c, d}]
Wolfram Language code: Accumulate[{a, b, c, d}]

Sum 用于符号累积序列：

Wolfram Language code: s = Sum[i ^ 2, {i, 1, n}]
Wolfram Language code: Table[s, {n, 1, 10}]
Wolfram Language code: Accumulate[Table[i ^ 2, {i, 1, 10}]]

可能存在的问题  (1)

直接累积不规则采样的时间序列可能不同于累积值：

Wolfram Language code: v = {3, 8, 4, 11, 9, 2}; t = {1, 3, 5, 6, 7, 10}; ts = TimeSeries[v, {t}]

路径：

Wolfram Language code: ts["Path"]

检查是否为规则采用：

Wolfram Language code: RegularlySampledQ[ts]

累积时间序列：

Wolfram Language code: res = Accumulate[ts]
Wolfram Language code: res["Path"]

这不同于累积值：

Wolfram Language code: av = Accumulate[v]

时间序列首先根据 MinimumTimeIncrement 上采样，然后下采样：

Wolfram Language code: ts1 = TimeSeriesResample[ts]; aux = Accumulate[ts1]; res1 = TimeSeriesResample[aux, {t}]
Wolfram Language code: res1["Path"] == res["Path"]

假设时间规律性，简单地累积值：

Wolfram Language code: ts2 = TimeSeries[ts, TemporalRegularity -> True]
Wolfram Language code: ts["Path"] == ts2["Path"]
Wolfram Language code: res2 = Accumulate[ts2]
Wolfram Language code: res2["Path"]
Wolfram Language code: res2["Values"] == av

巧妙范例  (1)

帕斯卡三角对角线：

Wolfram Language code: Transpose[NestList[Accumulate, Range[5], 5]]
Wolfram Research (2007)，Accumulate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Accumulate.html （更新于 2008 年）.

文本

Wolfram Research (2007)，Accumulate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Accumulate.html （更新于 2008 年）.

CMS

Wolfram 语言. 2007. "Accumulate." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/Accumulate.html.

APA

Wolfram 语言. (2007). Accumulate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Accumulate.html 年

BibTeX

@misc{reference.wolfram_2026_accumulate, author="Wolfram Research", title="{Accumulate}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Accumulate.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_accumulate, organization={Wolfram Research}, title={Accumulate}, year={2008}, url={https://reference.wolfram.com/language/ref/Accumulate.html}, note=[Accessed: 15-September-2026]}