WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AffineHalfSpace[{p1,…,pk+1},w]

方向 w に延長されたAffineSpace[{p1,…,pk+1}]を表す．

AffineHalfSpace[p,{v1,…,vk},w]

方向 w に延長されたAffineSpace[p,{v1,…,vk}]を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AffineHalfSpace

AffineHalfSpace[{p1,…,pk+1},w]

方向 w に延長されたAffineSpace[{p1,…,pk+1}]を表す．

AffineHalfSpace[p,{v1,…,vk},w]

方向 w に延長されたAffineSpace[p,{v1,…,vk}]を表す．

詳細

  • AffineHalfSpaceは，幾何学領域およびグラフィックスプリミティブとして使うことができる．
  • AffineHalfSpaceは，領域あるいはを表す．piがアフィン独立または viが線形独立である場合，次元は である．
  • AffineHalfSpaceは，GraphicsおよびGraphics3Dで使うことができる．
  • AffineHalfSpaceは，描画の際はPlotRangeで切り取られる．
  • グラフィックスの描画は，Opacity等のグラフィックス指示子および色の影響を受ける．
  • Thickness,Dashing一次元()
    FaceForm二次元()
  • 二次元のAffineSpaceについては，FaceForm[front,back]を使って front と back に別々のスタイルを指定することができる．ただし，front は，どちらの入力形式が使われているかによって，正規Cross[v1,v2]あるいはCross[p2-p1,p3-p1]の向きで定義される．

例題

すべて開く すべて閉じる

例  (3)

二次元AffineHalfSpace：

Wolfram Language code: Graphics[AffineHalfSpace[{0, 0}, {{1, -1}}, {1, 1}]]

三次元のもの：

Wolfram Language code: Graphics3D[AffineHalfSpace[{0, 0, 0}, {{-1, 0, 1}, {1, 1, 0}}, {-1, 1, -1}]]

アフィン半空間領域にさまざまなスタイルを適用する：

Wolfram Language code: ℛ = AffineHalfSpace[{0, 0, 0}, {{-1, 0, 1}, {1, 1, 0}}, {-1, 1, -1}];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], Pink, ℛ}], Graphics3D[{EdgeForm[Dashed], Pink, ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

点が指定されたアフィン半空間領域に含まれるかどうかをみる：

Wolfram Language code: ℛ = AffineHalfSpace[{0, 0, 0}, {{-1, 0, 1}, {1, 1, 0}}, {-1, 1, -1}];
Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {-1, 0, 0}]}

スコープ  (18)

グラフィックス  (8)

指定  (3)

2つの点と方向ベクトルを使って3Dアフィン半空間を定義する：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 0, 0}, {0, 0, 1}}], Thick, Arrowheads[Medium], Arrow[Tube[{{1, 0, 0}, {1, 1, 1}}]]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[AffineHalfSpace[{{1, 0, 0}, {0, 0, 1}}, {0, 1, 1}]]]

点，接ベクトル，方向ベクトルを使って同じアフィン半空間を定義する：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 0, 0}}], Thick, Arrowheads[Medium], Arrow[Tube[{{{1, 0, 0}, {1, 1, 1}}, {{1, 0, 0}, {0, 0, 1}}}]]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[AffineHalfSpace[{1, 0, 0}, {{-1, 0, 1}}, {0, 1, 1}]]]

単一の点と方向ベクトルで定義された3Dアフィン半空間：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 0, 0}}], Arrowheads[Medium], Thick, Arrow[Tube[{{0, 0, 0}, {0, 1, 1}}]]}, PlotRange -> 2, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[AffineHalfSpace[{{0, 0, 0}}, {0, 1, 1}]]]

接ベクトルで証明されたアフィン半空間：

Wolfram Language code: Table[Graphics3D[AffineHalfSpace[{0, 0, 0}, {{1, Cos[θ], Sin[θ]}}, {1, 1, 1}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

方向ベクトルで証明されたアフィン半空間：

Wolfram Language code: Table[Graphics3D[AffineHalfSpace[{0, 0, 0}, {{1, 0, 0}}, {1, Cos[θ], Sin[θ]}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

スタイリング  (2)

色指示子でアフィン半空間を指定する：

Wolfram Language code: Table[Graphics3D[{c, AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}, {0, 1, 0}]}], {c, {Red, Green, Yellow, Blue}}]

FaceFormとEdgeFormを使って面と辺のスタイルを指定する：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}, {0, 1, 0}]}]

座標  (3)

座標をプロット範囲との割合で指定する：

Wolfram Language code: Graphics3D[AffineHalfSpace[{Scaled[{0.5, 0, 0}], Scaled[{0, 0.5, 0}], Scaled[{0.5, 0.5, 0.5}]}, {1, 0, 0}], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

通常の座標からのスケールされたオフセットを指定する：

Wolfram Language code: Graphics3D[AffineHalfSpace[{Scaled[{0.3, 0.2, 0.5}, {.1, 0, 0}], Scaled[{0, 0, 0.5}, {1, 1, 1}]}, {1, 0, 0}], PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

点およびベクトルはDynamicでよい：

Wolfram Language code: DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, Pi}], Graphics3D[AffineHalfSpace[{0, 0, 0}, {Dynamic[{1, Cos[θ], Sin[θ]}]}, {0, 1, 1}]]}]

領域  (10)

埋込み次元は座標の次元である：

Wolfram Language code: RegionEmbeddingDimension[AffineHalfSpace[{{0, 0}, {1, 0}}, {0, 1}]]
Wolfram Language code: RegionEmbeddingDimension[AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}]]

幾何学時点は領域それ自体の次元である：

Wolfram Language code: RegionDimension[AffineHalfSpace[{{0, 0}, {1, 0}}, {0, 1}]]
Wolfram Language code: RegionDimension[AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}]]

点の帰属判定：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}];
Wolfram Language code: {RegionMember[ℛ, {2, 2, 0}], RegionMember[ℛ, {0, 0, 1}]}

帰属のための座標を得る：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

アフィン半空間は無限測度と未定義の重心を持つ：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

点からの距離：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}, {1, 0, 0}}, {0, 0, 1}];
Wolfram Language code: RegionDistance[ℛ, {0, 0, -3}]

点からの符号付き距離：

Wolfram Language code: SignedRegionDistance[ℛ, {0, 0, -3}]

領域内の最近点：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}, {1, 0, 0}}, {0, 0, 1}];
Wolfram Language code: RegionNearest[ℛ, {-1, -2, -3}]

最近点：

Wolfram Language code: pts = Flatten[Table[{Cos[k 2 π / 8]Cos[j π / 8], Sin[k 2 π / 8]Cos[j π / 8], Sin[j π / 8]}, {k, 0, 7}, {j, -3, 3}], 1]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics3D[{{Opacity[0.5], ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}, Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

アフィン半空間は非有界である：

Wolfram Language code: ℛ = AffineHalfSpace[{{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, {Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, {Subscript[v, x], Subscript[v, y], Subscript[v, z]}];
Wolfram Language code: BoundedRegionQ[ℛ]

領域範囲を求める：

Wolfram Language code: RegionBounds[ℛ]

アフィン半空間上で積分する：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}];
Wolfram Language code: Integrate[Exp[-(z ^ 2 + y ^ 2)], {x, y, z}∈ℛ]

アフィン半空間上で最適化する：

Wolfram Language code: ℛ = AffineHalfSpace[{{1, 1, 1}, {0, 1, 0}}, {0, 0, 1}];
Wolfram Language code: Minimize[{x^2 + y^2 + z^2 + 1, {x, y, z}∈ℛ}, {x, y, z}]

アフィン半空間上で方程式を解く：

Wolfram Language code: ℛ = AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}}, {0, 0, 1}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション  (2)

上半平面を可視化する：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0}, {1, 0}}, {0, 1}], Frame -> True]

下半平面を可視化する：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0}, {1, 0}}, {0, -1}], Frame -> True]

左半平面：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0}, {0, 1}}, {-1, 0}], Frame -> True]

右半平面：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0}, {0, 1}}, {1, 0}], Frame -> True]

上半空間を可視化する：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}, {0, 0, 1}], Boxed -> True]

下半空間：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}, {0, 0, -1}], Boxed -> True]

左半空間：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {-1, 0, 0}], Boxed -> True]

右半空間：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {1, 0, 0}], Boxed -> True]

前半空間：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 0, 1}}, {0, -1, 0}], Boxed -> True]

後ろ半空間：

Wolfram Language code: Region[AffineHalfSpace[{{0, 0, 0}, {1, 0, 0}, {0, 0, 1}}, {0, 1, 0}], Boxed -> True]

特性と関係  (6)

HalfLineはAffineHalfSpaceの特殊ケースである：

Wolfram Language code: Subscript[ℛ, 1] = AffineHalfSpace[{0, 0, 0}, {}, {1, 2, 3}]; Subscript[ℛ, 2] = HalfLine[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfPlaneはAffineHalfSpaceの特殊ケースである：

Wolfram Language code: Subscript[ℛ, 1] = AffineHalfSpace[{0, 0, 0}, {{1, 2, 3}}, {1, 1, 1}]; Subscript[ℛ, 2] = HalfPlane[{0, 0, 0}, {1, 2, 3}, {1, 1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfSpaceはAffineHalfSpaceの特殊ケースである：

Wolfram Language code: p = {1, 1, 1};n = {1, 2, 3}; {v1, v2} = NullSpace[{n}]; w = -n;
Wolfram Language code: Subscript[ℛ, 1] = AffineHalfSpace[p, {v1, v2}, w]; Subscript[ℛ, 2] = HalfSpace[n, p];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

AffineHalfSpaceはConicHullRegionの特殊ケースである：

Wolfram Language code: p = {1, 1, 1, 1}; {v1, v2} = {{-3, 0, 1, 1}, {-2, 1, 0, 4}}; w = {-1, -2, -3, 1};
Wolfram Language code: Subscript[ℛ, 1] = AffineHalfSpace[p, {v1, v2}, w]; Subscript[ℛ, 2] = ConicHullRegion[p, {v1, v2}, {w}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegionは，における任意のAffineHalfSpaceを表すことができる：

Wolfram Language code: p = {1, 0};v = {1, 2};w = {1, 1};
Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[p + a v + b w, {a, {b, 0, Infinity}}]; Subscript[ℛ, 2] = AffineHalfSpace[p, {v}, w];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

における：

Wolfram Language code: p = {0, 0, 0, 5, 1};{v1, v2, v3} = {{1, 2, 3, 0, 0}, {1, 1, 1, 5, 1}, {1, 1, 1, 1, 1}};w = {0, 1, 0, 1, 0};
Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[p + a v1 + b v2 + c v3 + d w, {a, b, c, {d, 0, Infinity}}]; Subscript[ℛ, 2] = AffineHalfSpace[p, {v1, v2, v3}, w];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは，における任意のAffineHalfSpaceを表すことができる：

Wolfram Language code: p = {1, 2};v = {1, 1};w = {1, 0};
Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[-1 - x + y ≤ 0, {x, y}];Subscript[ℛ, 2] = AffineHalfSpace[p, {v}, w];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

における：

Wolfram Language code: p = {1, 2, 1, 1, 1};{v1, v2} = {{2, 2, 1, 1, 1}, {0, 0, 1, 2, 3}};w = {1, 1, 1, 1, 1};
Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[1 + x1 - 3 x3 + x5 ≤ 0 && x3 - 2 x4 + x5 == 0 && 1 + x1 - x2 == 0, {x1, x2, x3, x4, x5}];
Wolfram Language code: Subscript[ℛ, 2] = AffineHalfSpace[p, {v1, v2}, w];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

おもしろい例題  (1)

におけるランダムな半空間の集合：

Wolfram Language code: Table[Graphics[{EdgeForm[Black], {RandomColor[], AffineHalfSpace[RandomReal[{-1, 1}, {2, 2}], RandomReal[{-1, 1}, 2]]}}, ImageSize -> 30, Frame -> True, FrameTicks -> False], {30}]

における：

Wolfram Language code: Table[Graphics3D[{EdgeForm[Black], {RandomColor[], AffineHalfSpace[RandomReal[{-1, 1}, {3, 3}], RandomReal[{-1, 1}, 3]]}}, ImageSize -> 30, Boxed -> True, Ticks -> False, PlotRange -> 1], {20}]
Wolfram Research (2015), AffineHalfSpace, Wolfram言語関数， https://reference.wolfram.com/language/ref/AffineHalfSpace.html.

テキスト

Wolfram Research (2015), AffineHalfSpace, Wolfram言語関数， https://reference.wolfram.com/language/ref/AffineHalfSpace.html.

CMS

Wolfram Language. 2015. "AffineHalfSpace." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AffineHalfSpace.html.

APA

Wolfram Language. (2015). AffineHalfSpace. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AffineHalfSpace.html

BibTeX

@misc{reference.wolfram_2026_affinehalfspace, author="Wolfram Research", title="{AffineHalfSpace}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/AffineHalfSpace.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_affinehalfspace, organization={Wolfram Research}, title={AffineHalfSpace}, year={2015}, url={https://reference.wolfram.com/language/ref/AffineHalfSpace.html}, note=[Accessed: 13-August-2026]}