WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AffineTransform[m]

r を m.r にマップするアフィン変換を表すTransformationFunctionを返す．

AffineTransform[{m,v}]

r を m.r+v にマップするアフィン変換を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
反復関数系  
画像変換  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AffineTransform

AffineTransform[m]

r を m.r にマップするアフィン変換を表すTransformationFunctionを返す．

AffineTransform[{m,v}]

r を m.r+v にマップするアフィン変換を返す．

詳細

例題

すべて開く すべて閉じる

例  (2)

一般的なアフィン変換：

Wolfram Language code: t = AffineTransform[{{{Subscript[a, 1, 1], Subscript[a, 1, 2]}, {Subscript[a, 2, 1], Subscript[a, 2, 2]}}, {Subscript[b, 1], Subscript[b, 2]}}]

変換点：

Wolfram Language code: t[{x, y}]

純回転：

Wolfram Language code: tr = AffineTransform[RotationMatrix[θ]]
Wolfram Language code: tr[{x, y}]

純粋な平行移動：

Wolfram Language code: tt = AffineTransform[{IdentityMatrix[2], {Subscript[b, 1], Subscript[b, 2]}}]
Wolfram Language code: tt[{x, y}]

スコープ  (3)

四次元におけるアフィン変換：

Wolfram Language code: t = AffineTransform[{DiagonalMatrix[{1, 1, 1, 2}], {x0, y0, z0, w0}}]
Wolfram Language code: t[{x, y, z, w}]

逆変換：

Wolfram Language code: InverseFunction[t]
Wolfram Language code: InverseFunction[t][{x, y, z, w}]

2Dの形に適用した変換：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, AffineTransform[{{.8, .5}, {0, .8}}]]}]

3Dの形に適用した変換：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, AffineTransform[{{.8, .5, .5}, {0, .8, .5}, {0, 0, .8}}]]}, Boxed -> False]

アプリケーション  (5)

反復関数系  (3)

反復関数系(IFS)を定義し，反復ごとに を計算することで，点集合においてこれを反復させる：

Wolfram Language code: IFS[{T__TransformationFunction}][pl_List] := Join@@Comap[{T}, pl]
Wolfram Language code: IFSPlot[f_IFS, pts_, n_Integer] := Graphics[{PointSize[Tiny], Point[Nest[f, pts, n]]}]

シェルピンスキー(Sierpiński)のギャスケット：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: IFSPlot[N@SierpinskiGasket, RandomReal[1, {100, 2}], 4]

シェルピンスキーのカーペット：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: IFSPlot[N@SierpinskiCarpet, RandomReal[1, {100, 2}], 4]

Heighwayのドラゴン：

Wolfram Language code: HeighwayDragon = IFS[{AffineTransform[{{{1 / 2, -1 / 2}, {1 / 2, 1 / 2}}}], AffineTransform[{{{-1 / 2, -1 / 2}, {1 / 2, -1 / 2}}, {1, 0}}]}];
Wolfram Language code: IFSPlot[N@HeighwayDragon, RandomReal[1, {100, 2}], 12]

点集合の下位区分をランダムに選択することで，反復関数系の固定点を効率よく計算する：

Wolfram Language code: RandomIFS[IFS[{T__TransformationFunction}], m_][pl_List] := Apply[Join, Comap[{T}, RandomChoice[pl, m]]]
Wolfram Language code: IFSPlot[f_RandomIFS, pts_, n_Integer] := Graphics[{PointSize[Tiny], Point[Nest[f, pts, n]]}]

シェルピンスキーのギャスケット：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: IFSPlot[RandomIFS[N@SierpinskiGasket, 10^3], RandomReal[1, {10 ^ 3, 2}], 12]

シェルピンスキーのカーペット：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: IFSPlot[RandomIFS[N@SierpinskiCarpet, 10 ^ 3], RandomReal[1, {1000, 2}], 20]

Heighwayのドラゴン：

Wolfram Language code: HeighwayDragon = IFS[{AffineTransform[{{{1 / 2, -1 / 2}, {1 / 2, 1 / 2}}}], AffineTransform[{{{-1 / 2, -1 / 2}, {1 / 2, -1 / 2}}, {1, 0}}]}];
Wolfram Language code: IFSPlot[RandomIFS[N@HeighwayDragon, 10 ^ 4], RandomReal[1, {10 ^ 4, 2}], 12]

ハリネズミ：

Wolfram Language code: Hedgehog = With[{a = (1 + 1 / 3) / 2, b = (1 - 1 / 3) / 2}, IFS[{ScalingTransform[{1, 1, 1} / 3], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}]}]];
Wolfram Language code: Graphics3D[ {PointSize[Tiny], Point[Nest[RandomIFS[N@Hedgehog, 10 ^ 4], RandomReal[1, {100, 3}], 3]]}]

グラフィックスプリミティブに適用された反復関数系を計算する：

Wolfram Language code: TransformIFS[g_, IFS[l_List]] := Module[{prim = First[g], h = Head[g]}, t = Table[GeometricTransformation[prim, l[[i]]], {i, Length[l]}];h[t]];
Wolfram Language code: TransformIFS[g_, ifs_IFS, 0] := g; TransformIFS[g_, ifs_IFS, 1] := TransformIFS[g, ifs]; TransformIFS[g_, ifs_IFS, n_Integer ? Positive] := TransformIFS[TransformIFS[g, ifs], ifs, n - 1];

シェルピンスキーのギャスケット：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: Table[TransformIFS[Graphics[Rectangle[]], SierpinskiGasket, n], {n, 0, 5}]

シェルピンスキーのカーペット：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: Table[TransformIFS[Graphics[Rectangle[]], SierpinskiCarpet, n], {n, 0, 3}]

ハリネズミ：

Wolfram Language code: Hedgehog = With[{a = (1 + 1 / 3) / 2, b = (1 - 1 / 3) / 2}, IFS[{ScalingTransform[{1, 1, 1} / 3], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}]}]];
Wolfram Language code: Table[TransformIFS[Graphics3D[Cuboid[]], Hedgehog, n], {n, 0, 3}]

画像変換  (2)

AffineTransformを使って画像を回転させる：

Wolfram Language code: ImageTransformation[[image], AffineTransform[(⁠| | | | ----------- | ---------- | | Cos[π / 8] | Sin[π / 8] | | -Sin[π / 8] | Cos[π / 8] |⁠)]]

3D画像の平行移動を伴わないアフィン変換：

Wolfram Language code: ImageTransformation[[image], AffineTransform[(| | | | | - | --- | - | | 1 | 0.5 | 0 | | 0 | 1 | 0 | | 0 | 0 | 1 |⁠)]]

特性と関係  (3)

他の多くの幾何学変換はアフィン変換の特殊ケースである：

Wolfram Language code: Composition[TranslationTransform[{x0, y0}], RotationTransform[a]] == AffineTransform[{{{Cos[a], -Sin[a]}, {Sin[a], Cos[a]}}, {x0, y0}}]

同様に，アフィン変換は一次分数変換の特殊ケースである：

Wolfram Language code: {m, v} = {Array[a, {3, 3}], {x, y, z}};
Wolfram Language code: AffineTransform[{m, v}] == LinearFractionalTransform[{m, v, {0, 0, 0}, 1}]

アフィン変換の構成要素はアフィン変換である：

Wolfram Language code: {m1, v1} = {Array[a1, {2, 2}], {x[1], y[1]}};
Wolfram Language code: {m2, v2} = {Array[a2, {2, 2}], {x[2], y[2]}};
Wolfram Language code: Composition[AffineTransform[{m1, v1}], AffineTransform[{m2, v2}]] == AffineTransform[{m1.m2, m1.v2 + v1}]

おもしろい例題  (1)

円のネストした変換：

Wolfram Language code: Graphics[NestList[GeometricTransformation[#, AffineTransform[{{.184, -.6}, {1.16, .6}}]]&, Circle[{2, 2}], 25]]
Wolfram Research (2007), AffineTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/AffineTransform.html.

テキスト

Wolfram Research (2007), AffineTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/AffineTransform.html.

CMS

Wolfram Language. 2007. "AffineTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AffineTransform.html.

APA

Wolfram Language. (2007). AffineTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AffineTransform.html

BibTeX

@misc{reference.wolfram_2026_affinetransform, author="Wolfram Research", title="{AffineTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AffineTransform.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_affinetransform, organization={Wolfram Research}, title={AffineTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/AffineTransform.html}, note=[Accessed: 15-September-2026]}