WOLFRAM

Wolfram 语言与系统参考资料中心

AffineTransform[m]

给出 TransformationFunction，表示将 r 映射到 m.r 的仿射变换.

AffineTransform[{m,v}]

给出将 r 映射到 m.r+v 的仿射变换.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
迭代函数系统  
图像转换  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

AffineTransform

AffineTransform[m]

给出 TransformationFunction，表示将 r 映射到 m.r 的仿射变换.

AffineTransform[{m,v}]

给出将 r 映射到 m.r+v 的仿射变换.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

一般的仿射变换：

Wolfram Language code: t = AffineTransform[{{{Subscript[a, 1, 1], Subscript[a, 1, 2]}, {Subscript[a, 2, 1], Subscript[a, 2, 2]}}, {Subscript[b, 1], Subscript[b, 2]}}]

变换点：

Wolfram Language code: t[{x, y}]

纯旋转：

Wolfram Language code: tr = AffineTransform[RotationMatrix[θ]]
Wolfram Language code: tr[{x, y}]

纯平移：

Wolfram Language code: tt = AffineTransform[{IdentityMatrix[2], {Subscript[b, 1], Subscript[b, 2]}}]
Wolfram Language code: tt[{x, y}]

范围  (3)

四维仿射变换：

Wolfram Language code: t = AffineTransform[{DiagonalMatrix[{1, 1, 1, 2}], {x0, y0, z0, w0}}]
Wolfram Language code: t[{x, y, z, w}]

逆变换：

Wolfram Language code: InverseFunction[t]
Wolfram Language code: InverseFunction[t][{x, y, z, w}]

应用于二维形状的变换：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, AffineTransform[{{.8, .5}, {0, .8}}]]}]

应用于三维形状的变换：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, AffineTransform[{{.8, .5, .5}, {0, .8, .5}, {0, 0, .8}}]]}, Boxed -> False]

应用  (5)

迭代函数系统  (3)

定义一个迭代函数系统（IFS），通过计算每一个迭代的 ，将其在点集上迭代：

Wolfram Language code: IFS[{T__TransformationFunction}][pl_List] := Join@@Comap[{T}, pl]
Wolfram Language code: IFSPlot[f_IFS, pts_, n_Integer] := Graphics[{PointSize[Tiny], Point[Nest[f, pts, n]]}]

谢尔宾斯基三角：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: IFSPlot[N@SierpinskiGasket, RandomReal[1, {100, 2}], 4]

谢尔宾斯基地毯：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: IFSPlot[N@SierpinskiCarpet, RandomReal[1, {100, 2}], 4]

Heighway 龙形曲线：

Wolfram Language code: HeighwayDragon = IFS[{AffineTransform[{{{1 / 2, -1 / 2}, {1 / 2, 1 / 2}}}], AffineTransform[{{{-1 / 2, -1 / 2}, {1 / 2, -1 / 2}}, {1, 0}}]}];
Wolfram Language code: IFSPlot[N@HeighwayDragon, RandomReal[1, {100, 2}], 12]

通过随机挑选点集的子部，有效地计算一个迭代函数系统（IFS）的固定点：

Wolfram Language code: RandomIFS[IFS[{T__TransformationFunction}], m_][pl_List] := Apply[Join, Comap[{T}, RandomChoice[pl, m]]]
Wolfram Language code: IFSPlot[f_RandomIFS, pts_, n_Integer] := Graphics[{PointSize[Tiny], Point[Nest[f, pts, n]]}]

谢尔宾斯基三角：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: IFSPlot[RandomIFS[N@SierpinskiGasket, 10^3], RandomReal[1, {10 ^ 3, 2}], 12]

谢尔宾斯基地毯：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: IFSPlot[RandomIFS[N@SierpinskiCarpet, 10 ^ 3], RandomReal[1, {1000, 2}], 20]

Heighway 龙形曲线：

Wolfram Language code: HeighwayDragon = IFS[{AffineTransform[{{{1 / 2, -1 / 2}, {1 / 2, 1 / 2}}}], AffineTransform[{{{-1 / 2, -1 / 2}, {1 / 2, -1 / 2}}, {1, 0}}]}];
Wolfram Language code: IFSPlot[RandomIFS[N@HeighwayDragon, 10 ^ 4], RandomReal[1, {10 ^ 4, 2}], 12]

刺猬：

Wolfram Language code: Hedgehog = With[{a = (1 + 1 / 3) / 2, b = (1 - 1 / 3) / 2}, IFS[{ScalingTransform[{1, 1, 1} / 3], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}]}]];
Wolfram Language code: Graphics3D[ {PointSize[Tiny], Point[Nest[RandomIFS[N@Hedgehog, 10 ^ 4], RandomReal[1, {100, 3}], 3]]}]

计算应用于图形基元的迭代函数系统：

Wolfram Language code: TransformIFS[g_, IFS[l_List]] := Module[{prim = First[g], h = Head[g]}, t = Table[GeometricTransformation[prim, l[[i]]], {i, Length[l]}];h[t]];
Wolfram Language code: TransformIFS[g_, ifs_IFS, 0] := g; TransformIFS[g_, ifs_IFS, 1] := TransformIFS[g, ifs]; TransformIFS[g_, ifs_IFS, n_Integer ? Positive] := TransformIFS[TransformIFS[g, ifs], ifs, n - 1];

谢尔宾斯基三角：

Wolfram Language code: SierpinskiGasket = With[{𝒟 = DiagonalMatrix[{1, 1} / 2]}, IFS[{AffineTransform[{𝒟}], AffineTransform[{𝒟, {1 / 2, 0}}], AffineTransform[{𝒟, {0.25, 0.433}}]}]];
Wolfram Language code: Table[TransformIFS[Graphics[Rectangle[]], SierpinskiGasket, n], {n, 0, 5}]

谢尔宾斯基地毯：

Wolfram Language code: SierpinskiCarpet = With[{𝒟 = DiagonalMatrix[{1, 1} / 3]}, IFS[{AffineTransform[{𝒟} ], AffineTransform[{𝒟, {0, 1 / 3}}], AffineTransform[{𝒟, {0, 2 / 3}}], AffineTransform[{𝒟, {1 / 3, 0}}], AffineTransform[{𝒟, {1 / 3, 2 / 3}}], AffineTransform[{𝒟, {2 / 3, 0}}], AffineTransform[{𝒟, {2 / 3, 1 / 3}}], AffineTransform[{𝒟, {2 / 3, 2 / 3}}]}]];
Wolfram Language code: Table[TransformIFS[Graphics[Rectangle[]], SierpinskiCarpet, n], {n, 0, 3}]

刺猬：

Wolfram Language code: Hedgehog = With[{a = (1 + 1 / 3) / 2, b = (1 - 1 / 3) / 2}, IFS[{ScalingTransform[{1, 1, 1} / 3], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}], ScalingTransform[{b, b, b}].TranslationTransform[{-a, -a, -a}]}]];
Wolfram Language code: Table[TransformIFS[Graphics3D[Cuboid[]], Hedgehog, n], {n, 0, 3}]

图像转换  (2)

用 AffineTransform 旋转图像：

Wolfram Language code: ImageTransformation[[image], AffineTransform[(⁠| | | | ----------- | ---------- | | Cos[π / 8] | Sin[π / 8] | | -Sin[π / 8] | Cos[π / 8] |⁠)]]

三维图像的仿射变换，不进行平移：

Wolfram Language code: ImageTransformation[[image], AffineTransform[(| | | | | - | --- | - | | 1 | 0.5 | 0 | | 0 | 1 | 0 | | 0 | 0 | 1 |⁠)]]

属性和关系  (3)

许多其他的几何变换是仿射变换的一个特例：

Wolfram Language code: Composition[TranslationTransform[{x0, y0}], RotationTransform[a]] == AffineTransform[{{{Cos[a], -Sin[a]}, {Sin[a], Cos[a]}}, {x0, y0}}]

而仿射变换是线性分式变换的一个特例：

Wolfram Language code: {m, v} = {Array[a, {3, 3}], {x, y, z}};
Wolfram Language code: AffineTransform[{m, v}] == LinearFractionalTransform[{m, v, {0, 0, 0}, 1}]

仿射变换的组合是仿射变换：

Wolfram Language code: {m1, v1} = {Array[a1, {2, 2}], {x[1], y[1]}};
Wolfram Language code: {m2, v2} = {Array[a2, {2, 2}], {x[2], y[2]}};
Wolfram Language code: Composition[AffineTransform[{m1, v1}], AffineTransform[{m2, v2}]] == AffineTransform[{m1.m2, m1.v2 + v1}]

巧妙范例  (1)

圆的嵌套变换：

Wolfram Language code: Graphics[NestList[GeometricTransformation[#, AffineTransform[{{.184, -.6}, {1.16, .6}}]]&, Circle[{2, 2}], 25]]
Wolfram Research (2007)，AffineTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AffineTransform.html.

文本

Wolfram Research (2007)，AffineTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AffineTransform.html.

CMS

Wolfram 语言. 2007. "AffineTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AffineTransform.html.

APA

Wolfram 语言. (2007). AffineTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AffineTransform.html 年

BibTeX

@misc{reference.wolfram_2026_affinetransform, author="Wolfram Research", title="{AffineTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AffineTransform.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_affinetransform, organization={Wolfram Research}, title={AffineTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/AffineTransform.html}, note=[Accessed: 18-August-2026]}