WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AppellF2[a,b1,b2,c1,c2,x,y]

二変数のアッペル(Appell)超幾何関数 である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
微分  
級数展開  
アプリケーション  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

AppellF2

AppellF2[a,b1,b2,c1,c2,x,y]

二変数のアッペル(Appell)超幾何関数 である．

詳細

  • AppellF2は，超幾何級数を一般化して多項式係数を持つHorn偏微分方程式系を解くAppell関数族の一員である．
  • 記号操作・数値操作の両方に適した数学関数である．
  • は，領域TemplateBox[{x}, Abs]+TemplateBox[{y}, Abs]<1内で収束する超幾何級数 を介して主定義を得る．引数の実数値についてのAppellF2級数の収束領域は以下の通りである．
  • 引数の実数値についてのアッペルF2級数の収束領域は以下の通りである．
  • 一般に，は の形のHorn偏微分方程式系を満足する． »
  • は または のときに簡約される．
  • 特別な引数の場合，AppellF2は自動的に厳密値を計算する．
  • AppellF2は任意の数値精度で評価できる．

例題

すべて開く すべて閉じる

例  (7)

数値的に評価する：

Wolfram Language code: AppellF2[2, 1, 3, 4, 5, 0.6, 0.3]

総和の定義：

Wolfram Language code: Sum[x^m y^n( Pochhammer[a, m + n]Pochhammer[b1, m] Pochhammer[b2, n]/Pochhammer[c1, m]Pochhammer[c2, n] m! n!), {m, 0, Infinity}, {n, 0, Infinity}]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 3, y], {y, -3 / 4, 1 / 4}]

複素数の部分集合上でプロットする：

Wolfram Language code: Plot[Abs[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, 1 / 7, z I]], {z, -3 / 4, 3 / 4}]

AppellF2関数族をプロットする：

Wolfram Language code: Plot[Table[Abs[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, n / 10 I, z I]], {n, -5, 5, 1}]//Evaluate, {z, -3 / 4, 3 / 4}]

原点における級数展開：

Wolfram Language code: Series[AppellF2[1, 1, 1, 1, 3, 4, x], {x, 0, 3}]

TraditionalFormによる表示：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y]//TraditionalForm

スコープ  (17)

数値評価  (6)

数値的に評価する：

Wolfram Language code: AppellF2[3, 2, 1, 2, 3, 1 / 3, 0.2]
Wolfram Language code: AppellF2[-2, -1, -2, 5, 2 / 3 + I, 0.4, 0.3]

高精度で評価する：

Wolfram Language code: N[AppellF2[3, 2, 1, 2, 3, 1 / 3, 2 / 5], 10]

出力精度は入力精度に従う：

Wolfram Language code: AppellF2[3, 2, 1, 2, 3, 1 / 3, 0.400000000000000000001]

複素数入力：

Wolfram Language code: AppellF2[I, 1, 1 + I, 3.2, 1 / 2, 0.5, 0.2 + 0.5 I]

AppellF2を高精度で効率的に評価する：

Wolfram Language code: AppellF2[3, 2, 1, 2, 1 / 3, 1 / 7, 1 / 5`100]//Timing
Wolfram Language code: AppellF2[3, 2, 1, 2, 7, 1 / 3, -1 / 5`100 + I];//Timing

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: AppellF2[ 1 / 2, 1, 5 / 2, 3, 1, 0, Around[2.1, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: AppellF2[1 / 2, 1, 1 / 2, 1 / 2, 1, 0, {{1 / 2, 2}, {2, 1 / 2}}]

MatrixFunctionを使って行列のAppellF2関数を計算することもできる：

Wolfram Language code: MatrixFunction[AppellF2[1 / 2, 1, 1 / 2, 1 / 2, 1, 0, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

特定の値  (3)

固定点における値：

Wolfram Language code: AppellF2[1 / 2, 0, 1 / 2, 1, 1 / 2, 0, 2]
Wolfram Language code: AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 2, 0, 2]

Hypergeometric2F1関数に簡約する：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, 0]
Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], 0, y]

ゼロにおける値：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], 0, 0]

可視化  (3)

AppellF2関数をさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[{AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 3], AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 4], AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 5]}, {x, -1 / 2, 1 / 2}]

AppellF2をその第2パラメータ の関数としてプロットする：

Wolfram Language code: Plot[{AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 3, y], AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 4, y], AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 5, y]}, {y, -1 / 2, 1 / 2}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[AppellF2[2, 1, 3, 1 / 3, 2, 0, z]], {z, -1 - I, 1 + I}]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[AppellF2[2, 1, 3, 1 / 3, 2, 0, z]], {z, -5 - 5I, 5 + 5I}]

微分  (4)

x についての一次導関数：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], x]

y についての一次導関数：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], y]

y についてのより高次の導関数：

Wolfram Language code: Table[D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {y, k}], {k, 1, 3}]//FullSimplify

a=b1=b2=2，c1=c2=5，x=1/5のときの y についてのより高次の導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. {a -> 2, Subscript[b, 1] -> 2, Subscript[b, 2] -> 2, Subscript[c, 1] -> 5, Subscript[c, 2] -> 5, x -> 1 / 5}], {y, -1 / 2, 1 / 2}, Rule[...]]

y についての 次導関数の式：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {y, n}]

級数展開  (1)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {x, 0, 2}]//Normal//FullSimplify

の周りの最初の3つの近似のプロット：

Wolfram Language code: terms = Normal@Table[Series[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, x, .3], terms}, {x, 0, 1 / 2}]

アプリケーション  (1)

アッペル関数 は多項式係数を持つ以下の偏微分方程式系を解く：

Wolfram Language code: pde = {x (1 - x) f^(2, 0)[x, y] - x y f^(1, 1)[x, y] + (Subscript[c, 1] - (a + Subscript[b, 1] + 1)x)f^(1, 0)[x, y] - Subscript[b, 1] y f^(0, 1)[x, y] - a Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] - x y f^(1, 1)[x, y] + (Subscript[c, 2] - (a + Subscript[b, 2] + 1)y)f^(0, 1)[x, y] - Subscript[b, 2] x f^(1, 0)[x, y] - a Subscript[b, 2] f[x, y] == 0};

が解であることを確かめる：

Wolfram Language code: (pde /. {a -> 2, Subscript[b, 1] -> 1, Subscript[b, 2] -> 1 / 2, Subscript[c, 1] -> 1 / 3, Subscript[c, 2] -> 2}) /. f -> Function[{x, y}, AppellF2[2, 1, 1 / 2, 1 / 3, 2, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-3 / 4, 3 / 4}, {2}, WorkingPrecision -> 20]]

おもしろい例題  (1)

多くの初等関数および特殊関数はAppellF2の特殊ケースである：

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (2023), AppellF2, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppellF2.html.

テキスト

Wolfram Research (2023), AppellF2, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppellF2.html.

CMS

Wolfram Language. 2023. "AppellF2." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AppellF2.html.

APA

Wolfram Language. (2023). AppellF2. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppellF2.html

BibTeX

@misc{reference.wolfram_2026_appellf2, author="Wolfram Research", title="{AppellF2}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF2.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf2, organization={Wolfram Research}, title={AppellF2}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF2.html}, note=[Accessed: 18-August-2026]}