WOLFRAM

Wolfram 语言与系统参考资料中心

AppellF2[a,b1,b2,c1,c2,x,y]

是两个变量的阿佩尔超几何函数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特定值  
可视化  
求导  
级数展开  
应用  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

AppellF2

AppellF2[a,b1,b2,c1,c2,x,y]

是两个变量的阿佩尔超几何函数 .

更多信息

  • AppellF2 属于阿佩尔函数族，用于推广超几何级数并求解具有多项式系数的 Horn 偏微分方程组.
  • 数学函数，适用于符号和数值操作.
  • 通过超几何级数 有一个基本定义，在区域 TemplateBox[{x}, Abs]+TemplateBox[{y}, Abs]<1 内收敛.
  • 对于实数参数值，Appell F2 级数的收敛区域如下：
  • 一般而言， 满足以下 Horn 偏微分方程组 »：
  • 当 或 时， 简化为 .
  • 对于某些特殊参数，AppellF2 会自动计算出精确值.
  • AppellF2 可以运算为任意数值精度.

范例

打开所有单元 关闭所有单元

基本范例  (7)

数值运算：

Wolfram Language code: AppellF2[2, 1, 3, 4, 5, 0.6, 0.3]

定义总和：

Wolfram Language code: Sum[x^m y^n( Pochhammer[a, m + n]Pochhammer[b1, m] Pochhammer[b2, n]/Pochhammer[c1, m]Pochhammer[c2, n] m! n!), {m, 0, Infinity}, {n, 0, Infinity}]

绘制实数的一个子集：

Wolfram Language code: Plot[AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 3, y], {y, -3 / 4, 1 / 4}]

绘制复数的一个子集：

Wolfram Language code: Plot[Abs[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, 1 / 7, z I]], {z, -3 / 4, 3 / 4}]

绘制 AppellF2 函数族：

Wolfram Language code: Plot[Table[Abs[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, n / 10 I, z I]], {n, -5, 5, 1}]//Evaluate, {z, -3 / 4, 3 / 4}]

在原点处的级数展开：

Wolfram Language code: Series[AppellF2[1, 1, 1, 1, 3, 4, x], {x, 0, 3}]

TraditionalForm 格式：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y]//TraditionalForm

范围  (17)

数值运算  (6)

数值运算：

Wolfram Language code: AppellF2[3, 2, 1, 2, 3, 1 / 3, 0.2]
Wolfram Language code: AppellF2[-2, -1, -2, 5, 2 / 3 + I, 0.4, 0.3]

高精度运算：

Wolfram Language code: N[AppellF2[3, 2, 1, 2, 3, 1 / 3, 2 / 5], 10]

输出的精度与输入的精度一致：

Wolfram Language code: AppellF2[3, 2, 1, 2, 3, 1 / 3, 0.400000000000000000001]

复数输入：

Wolfram Language code: AppellF2[I, 1, 1 + I, 3.2, 1 / 2, 0.5, 0.2 + 0.5 I]

以高精度高效地运算 AppellF2：

Wolfram Language code: AppellF2[3, 2, 1, 2, 1 / 3, 1 / 7, 1 / 5`100]//Timing
Wolfram Language code: AppellF2[3, 2, 1, 2, 7, 1 / 3, -1 / 5`100 + I];//Timing

用 Around 计算一般情况下的统计区间：

Wolfram Language code: AppellF2[ 1 / 2, 1, 5 / 2, 3, 1, 0, Around[2.1, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AppellF2[1 / 2, 1, 1 / 2, 1 / 2, 1, 0, {{1 / 2, 2}, {2, 1 / 2}}]

或用 MatrixFunction 计算矩阵形式的 AppellF2 函数：

Wolfram Language code: MatrixFunction[AppellF2[1 / 2, 1, 1 / 2, 1 / 2, 1, 0, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

特定值  (3)

固定点的值：

Wolfram Language code: AppellF2[1 / 2, 0, 1 / 2, 1, 1 / 2, 0, 2]
Wolfram Language code: AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 2, 0, 2]

简化为 Hypergeometric2F1 函数：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, 0]
Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], 0, y]

零点的值：

Wolfram Language code: AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], 0, 0]

可视化  (3)

绘制不同参数的 AppellF2 函数图形：

Wolfram Language code: Plot[{AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 3], AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 4], AppellF2[2, 1, 3, 1 / 3, 2, x, 1 / 5]}, {x, -1 / 2, 1 / 2}]

将 AppellF2 作为其第二个参数 的函数，绘制其图形：

Wolfram Language code: Plot[{AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 3, y], AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 4, y], AppellF2[2, 1, 1 / 2, 1 / 3, 2, 1 / 5, y]}, {y, -1 / 2, 1 / 2}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[AppellF2[2, 1, 3, 1 / 3, 2, 0, z]], {z, -1 - I, 1 + I}]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AppellF2[2, 1, 3, 1 / 3, 2, 0, z]], {z, -5 - 5I, 5 + 5I}]

求导  (4)

关于 x 的一阶导数：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], x]

关于 y 的一阶导数：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], y]

关于 y 的高阶导数：

Wolfram Language code: Table[D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {y, k}], {k, 1, 3}]//FullSimplify

当 a=b1=b2=2， c1=c2=5 且 x=1/5 时，绘制关于 y 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. {a -> 2, Subscript[b, 1] -> 2, Subscript[b, 2] -> 2, Subscript[c, 1] -> 5, Subscript[c, 2] -> 5, x -> 1 / 5}], {y, -1 / 2, 1 / 2}, Rule[...]]

关于 y 的 阶导数公式：

Wolfram Language code: D[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {y, n}]

级数展开  (1)

使用 Series 求泰勒展开式：

Wolfram Language code: Series[AppellF2[a, Subscript[b, 1], Subscript[b, 2], Subscript[c, 1], Subscript[c, 2], x, y], {x, 0, 2}]//Normal//FullSimplify

围绕 的前三个近似值的图形：

Wolfram Language code: terms = Normal@Table[Series[AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF2[1 / 2, 1 / 3, 1 / 4, 1 / 5, 1 / 6, x, .3], terms}, {x, 0, 1 / 2}]

应用  (1)

阿佩尔函数 求解以下具有多项式系数的偏微分方程组：

Wolfram Language code: pde = {x (1 - x) f^(2, 0)[x, y] - x y f^(1, 1)[x, y] + (Subscript[c, 1] - (a + Subscript[b, 1] + 1)x)f^(1, 0)[x, y] - Subscript[b, 1] y f^(0, 1)[x, y] - a Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] - x y f^(1, 1)[x, y] + (Subscript[c, 2] - (a + Subscript[b, 2] + 1)y)f^(0, 1)[x, y] - Subscript[b, 2] x f^(1, 0)[x, y] - a Subscript[b, 2] f[x, y] == 0};

检查 是一个解：

Wolfram Language code: (pde /. {a -> 2, Subscript[b, 1] -> 1, Subscript[b, 2] -> 1 / 2, Subscript[c, 1] -> 1 / 3, Subscript[c, 2] -> 2}) /. f -> Function[{x, y}, AppellF2[2, 1, 1 / 2, 1 / 3, 2, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-3 / 4, 3 / 4}, {2}, WorkingPrecision -> 20]]

巧妙范例  (1)

许多初等函数和特殊函数是 AppellF2 的特例：

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (2023)，AppellF2，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppellF2.html.

文本

Wolfram Research (2023)，AppellF2，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppellF2.html.

CMS

Wolfram 语言. 2023. "AppellF2." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AppellF2.html.

APA

Wolfram 语言. (2023). AppellF2. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AppellF2.html 年

BibTeX

@misc{reference.wolfram_2026_appellf2, author="Wolfram Research", title="{AppellF2}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF2.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf2, organization={Wolfram Research}, title={AppellF2}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF2.html}, note=[Accessed: 14-August-2026]}