WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AppendTo[x,elem]

要素 elem を x の値に付加し，その結果に x を再設定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

AppendTo

AppendTo[x,elem]

要素 elem を x の値に付加し，その結果に x を再設定する．

詳細

  • AppendTo[x,elem]は，x=Append[x,elem]と等価である．
  • AppendToは属性HoldFirstを有する．
  • AppendTo[x,elem]の x はシンボルまたは既存の値があるその他の式でよい． »
  • AppendToを繰り返し使用することでリストを構築することができるが，SowやReapを使う方が一般により効率的である． »
  • AppendToをSparseArrayオブジェクトに使うと，必要ならば通常のリストが返される． »
  • AppendToは，Appendと同じように，Associationオブジェクトに使うことができる．

例題

すべて開く すべて閉じる

例  (1)

lにリストを割り当てる：

Wolfram Language code: l = {1, 2, 4, 9}

リストの最後に新しい値を含める：

Wolfram Language code: AppendTo[l, 16]

lに割り当てられた値が変化した：

Wolfram Language code: l

スコープ  (5)

任意の頭部を使う：

Wolfram Language code: e = f[a, b, c]; AppendTo[e, x + y]

Associationに付け加える：

Wolfram Language code: x = <|1 -> a, 2 -> b|>
Wolfram Language code: AppendTo[x, 3 -> c]
Wolfram Language code: PrependTo[x, 4 -> d]

sに疎な行列を割り当てる：

Wolfram Language code: s = SparseArray[{{i_, i_} -> i}, 3]

行列に行を追加する：

Wolfram Language code: AppendTo[s, {1, 2, 3}]

次元が異なる要素を追加するためには通常のリストに変換する必要がある：

Wolfram Language code: AppendTo[s, {4, 5}]

AppendToの第1引数がシンボルである必要はない：

Wolfram Language code: list = {{1}, {2}, {3}}
Wolfram Language code: AppendTo[list[[2]], a]
Wolfram Language code: list

共有リストに並列で付け加える：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelEvaluate[AppendTo[sl, $KernelID]];
Wolfram Language code: sl

アプリケーション  (1)

mが2×2行列になるように割り当てる：

Wolfram Language code: m = {{a, b}, {c, d}};

mに行を加える：

Wolfram Language code: AppendTo[m, {e, f}]

mに列を加える：

Wolfram Language code: col = {x, y, z}; Table[AppendTo[m[[i]], col[[i]]], {i, 3}]

mは3×3行列になった：

Wolfram Language code: m

考えられる問題  (5)

第1引数は値を持っていなければならない：

Wolfram Language code: AppendTo[k, 2]

第1引数は追加できるものに割り当てられていなければならない：

Wolfram Language code: k = 1;AppendTo[k, 2]

AtomQがTrueであるものは一般に追加できない：

Wolfram Language code: AtomQ[k]

行列の列にAppendToを使うと列の値が置換される：

Wolfram Language code: m = {{11, 12, 13}, {21, 22, 23}};
Wolfram Language code: AppendTo[m[[All, 1]], 4]; m

行列の列に加える：

Wolfram Language code: m = {{11, 12, 13}, {21, 22, 23}}; val = Append[m[[All, 1]], 4]

列の値を新たな値に再設定する：

Wolfram Language code: m[[All, 1]] = val; m

AppendToを使って大きいループ中の値を集めるのには時間がかかることがある：

Wolfram Language code: BlockRandom[Timing[a = {};sum = 0;While[sum < 10 ^ 5, r = RandomInteger[9];sum += r;AppendTo[a, r]]; Length[a]]]

ReapとSowを使う等，他に使える方法がたくさんある：

Wolfram Language code: BlockRandom[Timing[sum = 0;{r, {a}} = Reap[While[sum < 10 ^ 5, r = RandomInteger[9]; sum += r; Sow[r]]];Length[a]]]

共有リストに並列で作業するときは，AppendToは原子的である：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[AppendTo[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl

Appendを使った同等に見える式は原子的ではない：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[sl = Append[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl
Wolfram Research (1988), AppendTo, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppendTo.html （2014年に更新）.

テキスト

Wolfram Research (1988), AppendTo, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppendTo.html （2014年に更新）.

CMS

Wolfram Language. 1988. "AppendTo." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/AppendTo.html.

APA

Wolfram Language. (1988). AppendTo. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppendTo.html

BibTeX

@misc{reference.wolfram_2026_appendto, author="Wolfram Research", title="{AppendTo}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AppendTo.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appendto, organization={Wolfram Research}, title={AppendTo}, year={2014}, url={https://reference.wolfram.com/language/ref/AppendTo.html}, note=[Accessed: 19-August-2026]}