WOLFRAM

Wolfram 语言与系统参考资料中心

AppendTo[x,elem]

将 elem 追加到 x 的值，并在结果中重新设置 x.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AppendTo

AppendTo[x,elem]

将 elem 追加到 x 的值，并在结果中重新设置 x.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

指定 l 为一个列表：

Wolfram Language code: l = {1, 2, 4, 9}

在列表末端包含一个新值：

Wolfram Language code: AppendTo[l, 16]

赋给 l 的值已经改变：

Wolfram Language code: l

范围  (5)

使用任意标头：

Wolfram Language code: e = f[a, b, c]; AppendTo[e, x + y]

追加至 Association：

Wolfram Language code: x = <|1 -> a, 2 -> b|>
Wolfram Language code: AppendTo[x, 3 -> c]
Wolfram Language code: PrependTo[x, 4 -> d]

赋给 s 一个稀疏矩阵：

Wolfram Language code: s = SparseArray[{{i_, i_} -> i}, 3]

往矩阵中添加一行数据：

Wolfram Language code: AppendTo[s, {1, 2, 3}]

如果添加的元素的维度与已有元素的维度不一致，则需将其转换为列表：

Wolfram Language code: AppendTo[s, {4, 5}]

AppendTo 的第一个参数不必是符号：

Wolfram Language code: list = {{1}, {2}, {3}}
Wolfram Language code: AppendTo[list[[2]], a]
Wolfram Language code: list

并行追加到共享列表：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelEvaluate[AppendTo[sl, $KernelID]];
Wolfram Language code: sl

应用  (1)

指定 m 为2×2矩阵：

Wolfram Language code: m = {{a, b}, {c, d}};

添加一行至 m：

Wolfram Language code: AppendTo[m, {e, f}]

添加一列至 m：

Wolfram Language code: col = {x, y, z}; Table[AppendTo[m[[i]], col[[i]]], {i, 3}]

m 目前为3×3矩阵：

Wolfram Language code: m

可能存在的问题  (5)

第一参数必须是个变量：

Wolfram Language code: AppendTo[k, 2]

第一个参数必须被赋给能被追加值的量：

Wolfram Language code: k = 1;AppendTo[k, 2]

如果 AtomQ 为 True，则不能为其追加值：

Wolfram Language code: AtomQ[k]

将 AppendTo 用于矩阵的一列将替换列的值：

Wolfram Language code: m = {{11, 12, 13}, {21, 22, 23}};
Wolfram Language code: AppendTo[m[[All, 1]], 4]; m

追加至矩阵列：

Wolfram Language code: m = {{11, 12, 13}, {21, 22, 23}}; val = Append[m[[All, 1]], 4]

用新值重置列的值：

Wolfram Language code: m[[All, 1]] = val; m

利用 AppendTo 在大的循环中累积数值可能较慢：

Wolfram Language code: BlockRandom[Timing[a = {};sum = 0;While[sum < 10 ^ 5, r = RandomInteger[9];sum += r;AppendTo[a, r]]; Length[a]]]

存在许多替代方法，例如使用 Reap 和Sow：

Wolfram Language code: BlockRandom[Timing[sum = 0;{r, {a}} = Reap[While[sum < 10 ^ 5, r = RandomInteger[9]; sum += r; Sow[r]]];Length[a]]]

在并行处理共享列表时，AppendTo 具备原子性：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[AppendTo[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl

而看起来与之相当的使用 Append 的表达式则不具备原子性：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[sl = Append[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl
Wolfram Research (1988)，AppendTo，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppendTo.html （更新于 2014 年）.

文本

Wolfram Research (1988)，AppendTo，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppendTo.html （更新于 2014 年）.

CMS

Wolfram 语言. 1988. "AppendTo." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/AppendTo.html.

APA

Wolfram 语言. (1988). AppendTo. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AppendTo.html 年

BibTeX

@misc{reference.wolfram_2026_appendto, author="Wolfram Research", title="{AppendTo}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AppendTo.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appendto, organization={Wolfram Research}, title={AppendTo}, year={2014}, url={https://reference.wolfram.com/language/ref/AppendTo.html}, note=[Accessed: 10-August-2026]}