WOLFRAM

Wolfram 语言与系统参考资料中心

ArcCosh[z]

给出复数 的反双曲余弦 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcCosh

ArcCosh[z]

给出复数 的反双曲余弦 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于某些特殊参数，ArcCosh 自动计算出精确值.
  • ArcCosh 可以算出任意精度的值.
  • ArcCosh 自动逐项作用于列表的各个元素.
  • ArcCosh[z] 在复平面 上有一个分支切割，从 到 .
  • ArcCosh 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值计算：

Wolfram Language code: ArcCosh[2.]
Wolfram Language code: Cosh[%]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCosh[x], {x, 1, 10}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCosh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在 Infinity 处渐近展开：

Wolfram Language code: Series[ArcCosh[x], {x, ∞, 3}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCosh[x], {x, 1, 3}]

范围  (41)

数值计算  (6)

数值计算：

Wolfram Language code: ArcCosh[5.0]

高精度计算：

Wolfram Language code: N[ArcCosh[5], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCosh[5.0000000000000000000000000000000000]

对复变量进行计算：

Wolfram Language code: ArcCosh[1.5 + I]

在高精度条件下高效计算 ArcCosh：

Wolfram Language code: ArcCosh[5`500]//Timing
Wolfram Language code: ArcCosh[5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCosh[Interval[{2, Cosh[3]}]]
Wolfram Language code: ArcCosh[CenteredInterval[4, 1 / 100]]
Wolfram Language code: ArcCosh[CenteredInterval[2 + 3I, (1 + 1) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCosh[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCosh[{{1, 1 / Sqrt[2]}, {0, -1 / Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcCosh 函数：

Wolfram Language code: MatrixFunction[ArcCosh[#]&, {{1, 1 / Sqrt[2]}, {0, -1 / Sqrt[2]}}]

特殊值  (4)

ArcCosh 在固定点上的值：

Wolfram Language code: Table[ArcCosh[(n /2)], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcCosh[Infinity]
Wolfram Language code: ArcCosh[ComplexInfinity]

ArcCosh 的零点：

Wolfram Language code: ArcCosh[1]

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcCosh[x] - Log[2];
Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 1, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ArcCosh 函数：

Wolfram Language code: Plot[ArcCosh[x], {x, 0, 10}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCosh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCosh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcCosh[k ϕ], {ϕ, 0, 8π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

函数的属性  (10)

ArcCosh 对所有大于或等于 1 的实数有定义：

Wolfram Language code: FunctionDomain[ArcCosh[x], x]

复定义域是整个平面：

Wolfram Language code: FunctionDomain[ArcCosh[z], z, Complexes]

ArcCosh 的值域是大于或等于 0 的所有实数：

Wolfram Language code: FunctionRange[ArcCosh[x], x, y]

参数取复定义域内的值时的值域：

Wolfram Language code: FunctionRange[ArcCosh[z], z, y, Complexes]

ArcCosh 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCosh[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCosh[x], x]

ArcCosh 在实定义域上是递增的：

Wolfram Language code: FunctionMonotonicity[{ArcCosh[x], x ≥ 1}, x, StrictInequalities -> True]

ArcCosh 是单射函数：

Wolfram Language code: FunctionInjective[ArcCosh[x], x]
Wolfram Language code: Plot[{ArcCosh[x], 1}, {x, -1, 10}]

ArcCosh 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCosh[x], x]
Wolfram Language code: Plot[{ArcCosh[x], -.5}, {x, -5, 5}]

ArcCosh 在其实定义域上是非负的：

Wolfram Language code: FunctionSign[{ArcCosh[x], x ≥ 1}, x]

函数在 (-∞,1] 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCosh[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCosh[x], x]

ArcCosh 在其实定义域上是凹的：

Wolfram Language code: FunctionConvexity[{ArcCosh[x], x ≥ 1}, x]

TraditionalForm 格式：

Wolfram Language code: ArcCosh[z]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcCosh[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCosh[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, 1, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCosh[x], {x, n}]

积分  (3)

ArcCosh 的不定积分：

Wolfram Language code: Integrate[ArcCosh[x], x]

ArcCosh 在实数域之外的区间上的定积分是虚数：

Wolfram Language code: Integrate[ArcCosh[x], {x, 0, 1}]

更多积分：

Wolfram Language code: Integrate[ArcCosh[z] ^ a, z]
Wolfram Language code: Integrate[ArcCosh[x] ArcCos[x], x]

级数展开式  (4)

用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCosh[x], {x, 2, 4}]

绘制 ArcCosh 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcCosh[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcCosh[x], terms}, {x, 1, 3}]

ArcCosh 在 处的级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcCosh[x], {x, 0, n}]

求分支点和分支切割处的级数展开式：

Wolfram Language code: Series[ArcCosh[x], {x, 1, 4}]
Wolfram Language code: Series[ArcCosh[x], {x, -1, 4}]

ArcCosh 可被应用于幂级数：

Wolfram Language code: ArcCosh[2Exp[x] + O[x] ^ 5]

函数恒等式和化简  (3)

化简含有 ArcCosh 的表达式：

Wolfram Language code: FullSimplify[Cosh[ArcCosh[x] + ArcCosh[y]] ^ 2 - 2x y Cosh[ArcCosh[x] + ArcCosh[y]] + x ^ 2 + y ^ 2]

用 TrigToExp 通过对数和平方根来表示：

Wolfram Language code: TrigToExp@ArcCosh[z]

转换回原来：

Wolfram Language code: ExpToTrig[%]

假定实数变量 和 的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcCosh[x + I y]]

函数表示  (5)

使用 ArcSech 表示：

Wolfram Language code: ArcSech[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCN[(1/z), 1]//FullSimplify
Wolfram Language code: InverseJacobiDN[(1/z), 1]//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: (Sqrt[z - 1] ((π/2) - z HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, z^2])/Sqrt[1 - z])//FullSimplify

可用 MeijerG 表示 ArcCosh：

Wolfram Language code: MeijerGReduce[ArcCosh[x], x]
Wolfram Language code: Activate[%]//FullSimplify

也可用 DifferentialRoot 表示 ArcCosh：

Wolfram Language code: DifferentialRootReduce[ArcCosh[x], x]

应用  (4)

求使一个物体的能量达到到其静能两倍的提升速度：

Wolfram Language code: ArcCosh[2]//N

所需光速的分式：

Wolfram Language code: Tanh[%]

密苏里州圣路斯市拱门倒悬拱基座的宽度，以英尺计：

Wolfram Language code: 2(ArcCosh[(757.7 - y) / 127.7] 127.7) /. y -> 0

绘制 ArcCosh 的实值和虚值部：

Wolfram Language code: Plot[{Re[ArcCosh[x]], Im[ArcCosh[x]]}, {x, -2, 2}, PlotStyle -> Thick]

解微分方程：

Wolfram Language code: DSolve[1 + (2 E^-x y[x] + 3 E^x y[x]) x (y[x] + x y'[x]) == 0, y[x], x]//Quiet

属性和关系  (5)

与反函数的合成可能需要 PowerExpand 将其简化为单位元：

Wolfram Language code: {Cosh[ArcCosh[z]], ArcCosh[Cosh[z]]}
Wolfram Language code: PowerExpand[%]

也可以使用附加假设：

Wolfram Language code: Simplify[%%, z > 0]

这里表示出 ArcCosh 函数的分支线：

Wolfram Language code: Plot3D[Im[ArcCosh[x + I y]], {x, -2, 2}, {y, -2, 2}]

求解一个反三角函数方程：

Wolfram Language code: Reduce[ArcCosh[z]^3 + 3 ArcCosh[z] == 2, z]
Wolfram Language code: Reduce[ArcCosh[Cosh[z]] == w, z]

求解零：

Wolfram Language code: Reduce[ArcCosh[α x + β] == 0, x]

求解满足 ArcCosh 的微分方程：

Wolfram Language code: DSolve[{z y'[z] + (z^2 - 1) y''[z] == 0, y[1] == 0}, y[z], z]

验证它满足 ArcCosh：

Wolfram Language code: z y'[z] + (z^2 - 1) y''[z] /. y -> ArcCosh
Wolfram Language code: Simplify[%]

可能存在的问题  (2)

一般地，：

Wolfram Language code: ArcCosh[Cosh[0.3 + 5 I]]
Wolfram Language code: Cosh[ArcCosh[0.3 + 5 I]]

在分支线上，机器精度输入可能给出错误数值答案：

Wolfram Language code: ArcCosh[-1 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N
Wolfram Language code: ArcCosh[-1 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&

巧妙范例  (1)

下面显示 ArcCosh 幂函数的分支切割：

Wolfram Language code: Plot3D[Im[ArcCosh[(x + I y) ^ 4]], {x, -2, 2}, {y, -2, 2}, ...]
Wolfram Research (1988)，ArcCosh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCosh.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcCosh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCosh.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcCosh." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcCosh.html.

APA

Wolfram 语言. (1988). ArcCosh. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcCosh.html 年

BibTeX

@misc{reference.wolfram_2026_arccosh, author="Wolfram Research", title="{ArcCosh}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCosh.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccosh, organization={Wolfram Research}, title={ArcCosh}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCosh.html}, note=[Accessed: 14-September-2026]}