ArcCsch

ArcCsch[z]

複素数の逆双曲線余割を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
特別な引数の場合，ArcCschは自動的に厳密値を計算する．
ArcCschは任意の数値精度で評価できる．
ArcCschは自動的にリストに関数の並列的な適用を行う．
ArcCsch[z]は，複素平面上，〜の範囲で不連続な分枝切断線を持つ．
ArcCschはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

ArcCschは逆双曲線余割関数である．ArcCsch[x]は，実数について，となるようなの双曲線角度を表す．
ArcCschは自動的にリストに縫い込まれる．特別な引数の場合，ArcCschは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcCschは任意の数値精度に評価できることがある．ArcCschを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
ArcCschは，複素引数について，によって定義される．ArcCsch[z]は複素平面上で不連続な分枝切断線を持つ．
関連する数学関数には，Csch，ArcSech，ArcCscがある．

例題

すべて開くすべて閉じる

例 (6)

数値的に評価する：

Wolfram Language code: ArcCsch[4.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcCsch[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcCsch[z], {z, -3 - 4I, 3 + 4I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[ArcCsch[x], {x, 0, 10}, Assumptions -> x > 0]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcCsch[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcCsch[x], {x, I, 3}, Assumptions -> x > 0]

スコープ (43)

数値評価 (6)

数値的に評価する：

Wolfram Language code: ArcCsch[5.0]

高精度で評価する：

Wolfram Language code: N[ArcCsch[5], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcCsch[5.000000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcCsch[1.5 + I]

ArcCschを高精度で効率よく評価する：

Wolfram Language code: ArcCsch[5`500]//Timing

Wolfram Language code: ArcCsch[5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcCsch[Interval[{-4, Csch[2]}]]

Wolfram Language code: ArcCsch[CenteredInterval[3, 1 / 100]]

Wolfram Language code: ArcCsch[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcCsch[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcCsch[{{2I, 0}, {I, -2I}}]

MatrixFunctionを使って行列のArcCsch関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcCsch[#]&, {{2I, 0}, {I, -2I}}]

特定の値 (4)

固定点におけるArcCschの値：

Wolfram Language code: Table[ArcCsch[I n], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcCsch[Infinity]

Wolfram Language code: ArcCsch[ComplexInfinity]

ArcCschの特異点：

Wolfram Language code: ArcCsch[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := ArcCsch[x] - Log[2];

Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化 (3)

ArcCsch関数をプロットする：

Wolfram Language code: Plot[ArcCsch[x], {x, -1, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcCsch[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcCsch[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の極プロット：

Wolfram Language code:

Table[PolarPlot[ArcCsch[k ϕ], {ϕ, -3π, 3π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-6, 6}, {-0.3, 0.8}}, AspectRatio -> 0.8]], {k, 1, 4}]

関数の特性 (11)

ArcCschは0を除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcCsch[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcCsch[z], z, Complexes]

ArcCschは0を除くすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcCsch[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcCsch[z], z, y, Complexes]

ArcCschは奇関数である：

Wolfram Language code: ArcCsch[-x]

ArcCschは鏡映性 $csch^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{csch, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]$ を有する：

Wolfram Language code: FullSimplify[ArcCsch[Conjugate[z]] == Conjugate[ArcCsch[z]]]

ArcCschは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcCsch[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcCsch[x], x]

ArcCschは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ArcCsch[x], x]

ArcCschは単射である：

Wolfram Language code: FunctionInjective[ArcCsch[x], x]

Wolfram Language code: Plot[{ArcCsch[x], 1}, {x, -3, 3}]

全射ではない：

Wolfram Language code: FunctionSurjective[ArcCsch[x], x]

Wolfram Language code: Limit[ArcCsch[x], x -> ∞]

Wolfram Language code: Plot[{ArcCsch[x], 0}, {x, -1, 1}]

ArcCschは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcCsch[x], x]

零点に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcCsch[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcCsch[x], x]

ArcCschは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcCsch[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcCsch[x]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[ArcCsch[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcCsch[x], {x, n}], {n, 1, 4}]//FullSimplify

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcCsch[x], {x, n}]

積分 (3)

ArcCschの不定積分：

Wolfram Language code: Integrate[ArcCsch[x], x]

原点を中心とした区間上でのArcCschの定積分：

Wolfram Language code: Integrate[ArcCsch[x], {x, -1, 1}, PrincipalValue -> True]

その他の積分例：

Wolfram Language code: Integrate[x ArcCsch[x], x]

Wolfram Language code: Integrate[x ^ k ArcCsch[x], x]

級数展開 (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcCsch[x], {x, 1, 4}]

の周りでのArcCschの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[ArcCsch[x], {x, 1, m}], {m, 1, 3}];
Plot[{ArcCsch[x], terms}, {x, 0, 2}, PlotRange -> {{0, 2}, {0, 5}}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcCsch[x], {x, 0, 1}]

Wolfram Language code: Series[ArcCsch[x], {x, (I/2), 1}]

ArcCschをベキ級数に適用する：

Wolfram Language code: ArcCsch[Exp[x] + O[x] ^ 6]

積分変換 (2)

MellinTransformを使ったメリン(Mellin)変換を計算する：

Wolfram Language code: MellinTransform[ArcCsch[x], x, s ]

HankelTransform：

Wolfram Language code: HankelTransform[ArcCsch[r], r, s]

関数の恒等式と簡約 (3)

ArcCschの簡約：

Wolfram Language code:

x^4 y^4 - 2 x^2 y^2 (2 + x^2 + y^2) Csch[ArcCsch[x] + ArcCsch[y]]^2 + (x^2 - y^2)^2 Csch[ArcCsch[x] + ArcCsch[y]]^4//FullSimplify

TrigToExpを使って対数によって表す：

Wolfram Language code: ArcCsch[z]//TrigToExp

変換し直す：

Wolfram Language code: ExpToTrig[%]//FullSimplify

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[ArcCsch[x + I y]]

関数表現 (5)

ArcSinhを使って表現する：

Wolfram Language code: ArcSinh[1 / x]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: InverseJacobiCS[z, 1]

Wolfram Language code: InverseJacobiDS[z, 1]

Hypergeometric2F1を使って表現する：

Wolfram Language code: (HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, -(1/z^2)]/z)//FullSimplify

ArcCschはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ArcCsch[x], x]

Wolfram Language code: Activate[%]//FullSimplify

ArcCschはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcCsch[x], x]

アプリケーション (3)

ArcCschの分枝切断構造は虚軸に沿っている：

Wolfram Language code: Plot3D[Re[ArcCsch[x - I y]], {y, -2, 2}, {x, -2, 2}]

微分方程式を解く：

Wolfram Language code: DSolve[x y'[x] - y[x] - ArcCsch[x] == 0, y[x], x]

sinh‐Gordon方程式の解：

Wolfram Language code: u[x_, t_] := 2ArcCsch[JacobiSC[x - t, m]]

解をチェックする：

Wolfram Language code: FullSimplify[D[u[x, t], x, t] + Sinh[u[x, t]]]

解をプロットする：

Wolfram Language code: Plot3D[Evaluate[u[x, t] /. m -> 4 / 3], {x, -3, 2}, {t, 0, 5 / 2}, MaxRecursion -> 1]

特性と関係 (2)

逆関数で構成する：

Wolfram Language code: {ArcCsch[Csch[z]], Csch[ArcCsch[z]]}

PowerExpandを使ってArcCschの多価性を無視する：

Wolfram Language code: PowerExpand[%]

追加的な仮定をして評価する：

Wolfram Language code: Refine[ArcCsch[Csch[z]], z∈Reals]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcCsch[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcCsch

詳細

予備知識

例題

例 (6)

スコープ (43)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (11)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (3)

特性と関係 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArcCsch

詳細

予備知識

例題

例 (6)

スコープ (43)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (11)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (3)

特性と関係 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX