Wolfram 语言与系统参考资料中心

ArcCsch

ArcCsch[z]

给出复数的反双曲余割 .

背景

ArcCsch 是反双曲余割函数. 对实数，ArcCsch[x] 表示满足的双曲角度且 .
ArcCsch 自动逐项作用于列表. 对某些特定变量值，ArcCsch 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcCsch 可以算出任意精度的数值结果. 对包含 ArcCsch 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcCsch 的定义为 . ArcCsch[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Csch、ArcSech 和 ArcCsc.

范例

打开所有单元关闭所有单元

基本范例 (6)

数值计算：

Wolfram Language code: ArcCsch[4.5]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCsch[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCsch[z], {z, -3 - 4I, 3 + 4I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[ArcCsch[x], {x, 0, 10}, Assumptions -> x > 0]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcCsch[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCsch[x], {x, I, 3}, Assumptions -> x > 0]

范围 (43)

数值计算 (6)

数值计算：

Wolfram Language code: ArcCsch[5.0]

高精度求值：

Wolfram Language code: N[ArcCsch[5], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCsch[5.000000000000000000000000000000000000000000]

计算复变量：

Wolfram Language code: ArcCsch[1.5 + I]

在高精度条件下高效计算 ArcCsch：

Wolfram Language code: ArcCsch[5`500]//Timing

Wolfram Language code: ArcCsch[5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCsch[Interval[{-4, Csch[2]}]]

Wolfram Language code: ArcCsch[CenteredInterval[3, 1 / 100]]

Wolfram Language code: ArcCsch[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCsch[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCsch[{{2I, 0}, {I, -2I}}]

或用 MatrixFunction 以矩阵形式计算 ArcCsch 函数：

Wolfram Language code: MatrixFunction[ArcCsch[#]&, {{2I, 0}, {I, -2I}}]

特殊值 (4)

ArcCsch 在固定点上的值：

Wolfram Language code: Table[ArcCsch[I n], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcCsch[Infinity]

Wolfram Language code: ArcCsch[ComplexInfinity]

ArcCsch 的奇点：

Wolfram Language code: ArcCsch[0]

求满足方程的值：

Wolfram Language code: f[x_] := ArcCsch[x] - Log[2];

Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (3)

绘制 ArcCsch 函数：

Wolfram Language code: Plot[ArcCsch[x], {x, -1, 1}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCsch[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCsch[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcCsch[k ϕ], {ϕ, -3π, 3π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-6, 6}, {-0.3, 0.8}}, AspectRatio -> 0.8]], {k, 1, 4}]

函数属性 (11)

ArcCsch 是针对除 0 以外的所有实数定义的：

Wolfram Language code: FunctionDomain[ArcCsch[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcCsch[z], z, Complexes]

ArcCsch 获得除0以外的所有实数值：

Wolfram Language code: FunctionRange[ArcCsch[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcCsch[z], z, y, Complexes]

ArcCsch 是一个奇函数：

Wolfram Language code: ArcCsch[-x]

ArcCsch 具有镜像属性 $csch^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{csch, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]$ ：

Wolfram Language code: FullSimplify[ArcCsch[Conjugate[z]] == Conjugate[ArcCsch[z]]]

ArcCsch 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCsch[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCsch[x], x]

ArcCsch 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ArcCsch[x], x]

ArcCsch 是单射函数：

Wolfram Language code: FunctionInjective[ArcCsch[x], x]

Wolfram Language code: Plot[{ArcCsch[x], 1}, {x, -3, 3}]

不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCsch[x], x]

Wolfram Language code: Limit[ArcCsch[x], x -> ∞]

Wolfram Language code: Plot[{ArcCsch[x], 0}, {x, -1, 1}]

ArcCsch 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcCsch[x], x]

在零处有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCsch[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcCsch[x], x]

ArcCsch 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcCsch[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcCsch[x]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcCsch[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCsch[x], {x, n}], {n, 1, 4}]//FullSimplify

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCsch[x], {x, n}]

积分 (3)

ArcCsch 的不定积分：

Wolfram Language code: Integrate[ArcCsch[x], x]

在以原点为中心的区间上，ArcCsch 的定积分为0：

Wolfram Language code: Integrate[ArcCsch[x], {x, -1, 1}, PrincipalValue -> True]

更多积分：

Wolfram Language code: Integrate[x ArcCsch[x], x]

Wolfram Language code: Integrate[x ^ k ArcCsch[x], x]

级数展开式 (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCsch[x], {x, 1, 4}]

绘制 ArcCsch 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcCsch[x], {x, 1, m}], {m, 1, 3}];
Plot[{ArcCsch[x], terms}, {x, 0, 2}, PlotRange -> {{0, 2}, {0, 5}}]

在分支点和分支切口处求级数展开式：

Wolfram Language code: Series[ArcCsch[x], {x, 0, 1}]

Wolfram Language code: Series[ArcCsch[x], {x, (I/2), 1}]

将 ArcCsch 应用于幂级数：

Wolfram Language code: ArcCsch[Exp[x] + O[x] ^ 6]

积分变换 (2)

用 MellinTransform 计算 Mellin 变换：

Wolfram Language code: MellinTransform[ArcCsch[x], x, s ]

HankelTransform:

Wolfram Language code: HankelTransform[ArcCsch[r], r, s]

函数恒等式和化简 (3)

化简 ArcCsch：

Wolfram Language code:

x^4 y^4 - 2 x^2 y^2 (2 + x^2 + y^2) Csch[ArcCsch[x] + ArcCsch[y]]^2 + (x^2 - y^2)^2 Csch[ArcCsch[x] + ArcCsch[y]]^4//FullSimplify

通过 TrigToExp 用对数来表示：

Wolfram Language code: ArcCsch[z]//TrigToExp

转换回来：

Wolfram Language code: ExpToTrig[%]//FullSimplify

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcCsch[x + I y]]

函数表示 (5)

使用 ArcSinh 表示：

Wolfram Language code: ArcSinh[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCS[z, 1]

Wolfram Language code: InverseJacobiDS[z, 1]

使用 Hypergeometric2F1 表示：

Wolfram Language code: (HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, -(1/z^2)]/z)//FullSimplify

可用 MeijerG 来表示 ArcCsch：

Wolfram Language code: MeijerGReduce[ArcCsch[x], x]

Wolfram Language code: Activate[%]//FullSimplify

也可用 DifferentialRoot 来表示 ArcCsch：

Wolfram Language code: DifferentialRootReduce[ArcCsch[x], x]

应用 (3)

ArcCsch 沿虚轴延伸的分支线结构：

Wolfram Language code: Plot3D[Re[ArcCsch[x - I y]], {y, -2, 2}, {x, -2, 2}]

解微分方程：

Wolfram Language code: DSolve[x y'[x] - y[x] - ArcCsch[x] == 0, y[x], x]

Sinh-Gordon 方程的解：

Wolfram Language code: u[x_, t_] := 2ArcCsch[JacobiSC[x - t, m]]

检查该解：

Wolfram Language code: FullSimplify[D[u[x, t], x, t] + Sinh[u[x, t]]]

绘制该解：

Wolfram Language code: Plot3D[Evaluate[u[x, t] /. m -> 4 / 3], {x, -3, 2}, {t, 0, 5 / 2}, MaxRecursion -> 1]

属性和关系 (2)

与反函数复合：

Wolfram Language code: {ArcCsch[Csch[z]], Csch[ArcCsch[z]]}

利用 PowerExpand 去掉 ArcCsch的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假设条件下计算：

Wolfram Language code: Refine[ArcCsch[Csch[z]], z∈Reals]

利用 TrigToExp 通过对数表示：

Wolfram Language code: ArcCsch[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcCsch

更多信息

背景

范例

基本范例 (6)

范围 (43)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (11)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (5)

应用 (3)

属性和关系 (2)

文本

CMS

APA

BibTeX

BibLaTeX

ArcCsch

更多信息

背景

范例

基本范例 (6)

范围 (43)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (11)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (5)

应用 (3)

属性和关系 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX