Wolfram 语言与系统参考资料中心

ArcSin

ArcSin[z]

给出复数的反正弦函数 .

背景

ArcSin 是反正弦函数. 对实数，ArcSin[x] 表示满足的弧度值且 .
ArcSin 自动逐项作用于列表. 对某些特定变量值，ArcSin 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcSin 可以算出任意精度的数值结果. 对包含 ArcSin 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcSin 的定义为 $sin^(-1)(z)=-ⅈ log(sqrt(TemplateBox[{{1, -, {z, ^, 2}}}, Abs]) ⅇ^(1/2 ⅈ arg(1-z^2))+ⅈ z)$ . ArcSin[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Sin、ArcCos、InverseHaversine 和 ArcSinh.

范例

打开所有单元关闭所有单元

基本范例 (6)

结果以弧度表示：

Wolfram Language code: ArcSin[1]

除以 Degree 已得到以度为单位的结果：

Wolfram Language code: ArcSin[1] / Degree//FullSimplify

在实数域子集上绘图：

Wolfram Language code: Plot[ArcSin[x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcSin[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

在 0 处的渐近展开：

Wolfram Language code: Series[ArcSin[x], {x, 0, 10}]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcSin[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcSin[x], {x, -1, 5}]

范围 (42)

数值计算 (6)

数值计算：

Wolfram Language code: ArcSin[0.4]

Wolfram Language code: ArcSin[1.5]

高精度求值：

Wolfram Language code: N[ArcSin[1 / 3], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcSin[0.33333333333333333333333333333333333333333333]

ArcSin 接受复数输入：

Wolfram Language code: ArcSin[2.5 + I]

在高精度条件下高效计算 ArcSin：

Wolfram Language code: ArcSin[0.4`500]//Timing

Wolfram Language code: ArcSin[0.4`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: ArcSin[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcSin 函数：

Wolfram Language code: MatrixFunction[ArcSin[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcSin[Interval[{-1 / 3, 1 / 2}]]

Wolfram Language code: ArcSin[CenteredInterval[1 / 2, 1 / 100]]

Wolfram Language code: ArcSin[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcSin[Around[.9, 0.1]]

特殊值 (4)

ArcSin 在固定点上的值：

Wolfram Language code: Table[ArcSin[(n /2)], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcSin[Infinity]

Wolfram Language code: ArcSin[ComplexInfinity]

ArcSin 的零点：

Wolfram Language code: ArcSin[0]

求满足方程的的值：

Wolfram Language code: f[x_] := ArcSin[x] - (π/3);

Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (3)

绘制 ArcSin 函数：

Wolfram Language code: Plot[ArcSin[x], {x, -1, 1}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcSin[z]], {z, -3π - 3I, 3π + 3I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcSin[z]], {z, -π - 3I, π + 3I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcSin[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

函数属性 (11)

ArcSin 是针对区间内的所有实数定义的：

Wolfram Language code: FunctionDomain[ArcSin[x], x]

复定义域是整个平面：

Wolfram Language code: FunctionDomain[ArcSin[z], z, Complexes]

ArcSin 获取区间上的所有实数值；

Wolfram Language code: FunctionRange[ArcSin[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcSin[z], z, y, Complexes]

ArcSin 是一个奇函数：

Wolfram Language code: ArcSin[-x]

ArcSin 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcSin[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcSin[x], x]

ArcSin 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ArcSin[x], x]

在其实定义域上是单调的：

Wolfram Language code: FunctionMonotonicity[{ArcSin[x], -1 ≤ x ≤ 1}, x]

ArcSin 是单射函数：

Wolfram Language code: FunctionInjective[ArcSin[x], x]

Wolfram Language code: Plot[{ArcSin[x], 1 / 2}, {x, -2π, 2π}]

ArcSin 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcSin[x], x]

Wolfram Language code: Plot[{ArcSin[x], 2}, {x, -2π, 2π}]

ArcSin 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcSin[x], x]

ArcSin 函数在 (-∞,-1] 和 [1,∞) 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcSin[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcSin[x], x]

ArcSin 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcSin[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcSin[z]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcSin[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcSin[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcSin[x], {x, n}]

积分 (3)

ArcSin 的不定积分：

Wolfram Language code: Integrate[ArcSin[x], x]

在以原点为中心的区间上，ArcSin 的定积分为0：

Wolfram Language code: Integrate[ArcSin[x], {x, -1, 1}]

更多积分：

Wolfram Language code: Integrate[ArcCos[x] ArcSin[x], x]

Wolfram Language code: Integrate[ArcSin[z]^a, z]

级数展开式 (4)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcSin[x], {x, 0, 7}]

绘制 ArcSin 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcSin[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcSin[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcSin 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcSin[x], {x, 0, n}]

求分支点和分支切割的级数展开式：

Wolfram Language code: Series[ArcSin[x], {x, 1, 1}]

Wolfram Language code: Series[ArcSin[x], {x, -2, 1}]

ArcSin 可被应用于幂级数：

Wolfram Language code: ArcSin[x + (x^2/2) + (x^3/3) + O[x]^4]

函数恒等式和化简 (3)

化简含有 ArcSin 的表达式：

Wolfram Language code: FullSimplify[ArcSin[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

用 TrigToExp 通过对数和平方根来表示：

Wolfram Language code: TrigToExp@ArcSin[z]

Wolfram Language code: ExpToTrig[%]

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcSin[x + I y]]

函数表示 (5)

使用 ArcCsc 表示：

Wolfram Language code: ArcCsc[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: (π/2) - InverseJacobiCN[z, 0]//FullSimplify

Wolfram Language code: InverseJacobiDS[(1/z), 0]//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: (π/2) - z HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, z^2]//FullSimplify

用 MeijerG 表示：

Wolfram Language code: MeijerGReduce[ArcSin[x], x]

Wolfram Language code: Activate[%]

ArcSin 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ArcSin[x], x]

应用 (6)

绘出 ArcSin 的实部和虚部：

Wolfram Language code: Plot[{Re[ArcSin[x]], Im[ArcSin[x]]}, {x, -2, 2}, PlotStyle -> Thick]

绘出 ArcSin 的黎曼曲面：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Sin[u + I v]], Im[Sin[u + I v]], u}], {u, 0, 4π}, {v, -2, 2}]

求出两个三维向量之间的角：

Wolfram Language code: With[{v = Normalize[{1, 1, -2}], u = Normalize[{1, 1, 1}]}, ArcSin[Norm[Cross[v, u]]]]

为列维第二反正弦定律建模：

Wolfram Language code:

{With[{n = 1000}, ListPlot[MapIndexed[{#1, #2[[1]] / n}&, Sort[Table[Position[FoldList[Plus, 0, RandomChoice[{-1, 1}, n]], 0][[-1, 1]] / n, {n}]]]]], Plot[2 / Pi ArcSin[Sqrt[x]], {x, 0, 1}]}

解 ArcSin 微分方程：

Wolfram Language code: DSolve[Sqrt[1 - z^2]w'[z] == 1, w[z], z]

从椭圆到单位圆盘的共形图：

Wolfram Language code:

w[z_, {a_, b_}] := With[{q = (a - b) ^ 2 / (a + b) ^ 2, e = Sqrt[a ^ 2 - b ^ 2]}, EllipticTheta[1, ArcSin[z / e], q] / EllipticTheta[4, ArcSin[z / e], q]]

将图可视化：

Wolfram Language code:

ParametricPlot[{Re[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], Im[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]]}, {ρ, 0, 1}, {φ, 0, 2Pi}, Mesh -> 15]

属性和关系 (9)

与反函数合成：

Wolfram Language code: {Sin[ArcSin[z]], ArcSin[Sin[z]]}

利用 PowerExpand 去掉 ArcSin 的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假设条件下计算：

Wolfram Language code: Refine[ArcSin[Sin[z]], 0 < z < Pi / 2]

利用 TrigToExp 通过对数和平方根表示：

Wolfram Language code: ArcSin[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

它显示 ArcSin 函数的分支线：

Wolfram Language code: Plot3D[Im[ArcSin[x + I y]], {x, -2, 2}, {y, -2, 2}]

ArcSin 给出以弧度为单位的角，ArcSinDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcSin[1]

Wolfram Language code: ArcSinDegrees[1]

假设实数变量扩展：

Wolfram Language code: ComplexExpand[ArcSin[x + I y]]

求解反三角函数方程：

Wolfram Language code: Reduce[ArcSin[z]^2 + 3 ArcSin[z] == 2, z]

Wolfram Language code: Reduce[ArcSin[Sin[z]] == w, z]

求解零：

Wolfram Language code: Reduce[ArcSin[α x + β] == 0, x]

拉普拉斯变换：

Wolfram Language code: LaplaceTransform[ArcSin[t], t, s]

ArcSin 是多种数学函数的一个特例：

Wolfram Language code:

{(π/2) - InverseJacobiCD[z, 0], InverseJacobiCS[(I/z), 1], -(Sqrt[π]/2) MeijerG[{{1, 1, 1}, {}}, {{1}, {0, (1/2)}}, I z, (1/2)]}//FullSimplify

可能存在的问题 (4)

一般地，：

Wolfram Language code: ArcSin[Sin[30.]]

Wolfram Language code: Sin[ArcSin[30.]]

在分支线上，机器精度输入可能给出错误数值答案：

Wolfram Language code: ArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N

Wolfram Language code: ArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&

输出精度可能远远低于输入精度：

Wolfram Language code: ArcSin[0.99999999999999999999999999999999999999999999]

在传统形式中，自变量需要圆括号：

Wolfram Language code: sin^-1x

Wolfram Language code: sin^-1(x)

巧妙范例 (3)

嵌套积分：

Wolfram Language code: NestList[Integrate[#, x]&, ArcSin[x], 4]

利用迭代法计算数值：

Wolfram Language code: arcSin[x_ ? (InexactNumberQ[#] && 0 < # < 1&)] := FixedPoint[Function[ξ, ξ + 1 / Cos[ξ](x - Sin[ξ])], x]

Wolfram Language code: {arcSin[N[7 / 11, 20]], ArcSin[N[7 / 11, 20]]}

在整数点绘制 ArcSin：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcSin[x y]]], {x, -20, 20}, {y, -20, 20}]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcSin

更多信息

背景

范例

基本范例 (6)

范围 (42)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (11)

微分 (3)

积分 (3)

级数展开式 (4)

函数恒等式和化简 (3)

函数表示 (5)

应用 (6)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (3)

文本

CMS

APA

BibTeX

BibLaTeX

ArcSin

更多信息

背景

范例

基本范例 (6)

范围 (42)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (11)

微分 (3)

积分 (3)

级数展开式 (4)

函数恒等式和化简 (3)

函数表示 (5)

应用 (6)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (3)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX