WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArithmeticGeometricMean[a,b]

a と b の算術幾何平均を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
微分  
級数展開  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArithmeticGeometricMean

ArithmeticGeometricMean[a,b]

a と b の算術幾何平均を与える．

詳細

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: ArithmeticGeometricMean[1.8, 1.2]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArithmeticGeometricMean[1, x], {x, 0, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArithmeticGeometricMean[1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[ArithmeticGeometricMean[1, x], {x, 0, 2}, Assumptions -> x > 0]

スコープ  (25)

数値評価  (5)

数値的に評価する：

Wolfram Language code: ArithmeticGeometricMean[1.2, 5]
Wolfram Language code: ArithmeticGeometricMean[-2., -5]

高精度で評価する：

Wolfram Language code: N[ArithmeticGeometricMean[52, 5], 30]

出力精度は入力精度に従う：

Wolfram Language code: ArithmeticGeometricMean[2, 3.0000000000000000000000]

複素数入力：

Wolfram Language code: N[ArithmeticGeometricMean[1 + I, 3 + I]]

高精度で効率的に評価する：

Wolfram Language code: ArithmeticGeometricMean[32, 5`100]//Timing
Wolfram Language code: ArithmeticGeometricMean[32, 5`100];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArithmeticGeometricMean[2, Interval[{.8, 1.2}]]
Wolfram Language code: ArithmeticGeometricMean[2, CenteredInterval[8, .2]]
Wolfram Language code: ArithmeticGeometricMean[CenteredInterval[8, .2], 1]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArithmeticGeometricMean[ 1, Around[2, 0.01]]

特定の値  (4)

固定点における値：

Wolfram Language code: Table[ArithmeticGeometricMean[x, y], {x, {16, 8}}, {y, {4, 10}}]//N

ゼロにおける値：

Wolfram Language code: ArithmeticGeometricMean[0, 0]

記号的に評価する：

Wolfram Language code: ArithmeticGeometricMean[a, a]

ArithmeticGeometricMean[3,x]=1.5となるような x の値を求める：

Wolfram Language code: xval = x /. FindRoot[ArithmeticGeometricMean[3, x] == 1.5, {x, 0.5}]
Wolfram Language code: Plot[ArithmeticGeometricMean[3, x], {x, 0, 2}, Epilog -> Style[Point[{xval, ArithmeticGeometricMean[3, xval]}], PointSize[Large], Red]]

可視化  (2)

ArithmeticGeometricMean関数をさまざまな次数についてプロットする：

Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], ArithmeticGeometricMean[2, x], ArithmeticGeometricMean[3, x], ArithmeticGeometricMean[4, x]}, {x, 0, 2}]

TemplateBox[{2, z}, ArithmeticGeometricMean]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

TemplateBox[{2, z}, ArithmeticGeometricMean]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

関数の特性  (10)

ArithmeticGeometricMeanの実領域：

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[x, y], {x, y}]

複素領域：

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[w, z], {w, z}, Complexes]

ArithmeticGeometricMeanはすべての実数値に達する：

Wolfram Language code: FunctionRange[ArithmeticGeometricMean[x, z], {x, z}, y]//Quiet

ArithmeticGeometricMeanは要素単位でリストに縫い込まれる：

Wolfram Language code: ArithmeticGeometricMean[{1.0, 2.0, 3.0}, 5]

ArithmeticGeometricMeanは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArithmeticGeometricMean[x, 1], x]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArithmeticGeometricMean[x, y], {x, y}]
Wolfram Language code: FunctionDiscontinuities[ArithmeticGeometricMean[x, y], {x, y}]

TemplateBox[{1, x}, ArithmeticGeometricMean]はその実領域上で非減少である：

Wolfram Language code: FunctionMonotonicity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean]は単射である：

Wolfram Language code: FunctionInjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], 1}, {x, 0, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean]は全射ではない：

Wolfram Language code: FunctionSurjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], -2}, {x, -2, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean]はその実領域上で非負である：

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{{-, 1}, x}, ArithmeticGeometricMean]はその実領域上で非正である：

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[-1, x], x <= 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean]はその実領域上で凹である：

Wolfram Language code: FunctionConvexity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TraditionalFormによる表示：

Wolfram Language code: ArithmeticGeometricMean[a, b]//TraditionalForm

微分  (2)

b についての一次導関数：

Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]

b についての高次導関数：

Wolfram Language code: Table[D[ArithmeticGeometricMean[a, b], {b, k}], {k, 1, 3}]//FullSimplify

a=3のとき，b についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. a -> 3], {b, 0, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

級数展開  (2)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, 0, 2}]//Normal//FullSimplify

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArithmeticGeometricMean[2, x], {x, 0, m}], {m, 1, 3}]; Plot[{ArithmeticGeometricMean[2, x], terms}, {x, 0, 10}]

生成点におけるテイラー展開：

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, x0, 2}]//Normal// FullSimplify

アプリケーション  (4)

算術幾何平均を返す明示的な形の反復：

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = 1.;b[0] = 2.;
Wolfram Language code: Table[{a[n], b[n]}, {n, 5}]

ArithmeticGeometricMeanと比較する：

Wolfram Language code: ArithmeticGeometricMean[1., 2.]

先程の反復手続きの関数的な実装：

Wolfram Language code: agmIterations[a_ ? InexactNumberQ, b_ ? InexactNumberQ] := FixedPointList[{(#[[1]] + #[[2]]) / 2, Sqrt[#[[1]]#[[2]]]}&, {a, b}]
Wolfram Language code: agmIterations[1., 2.]

ArithmeticGeometricMeanで表現した算術幾何平均の計算のための反復ステップの閉じた形：

Wolfram Language code: ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - (b / a)^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]
Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 1., 2.], {n, 0, 4}]

任意精度演算を使って収束速度を示す：

Wolfram Language code: With[{a = N[1, 2000], b = N[2, 2000]}, Table[ArithmeticGeometricMeanIteration[n, a, b], {n, 0, 10}] - ArithmeticGeometricMean[a, b]]//SetPrecision[#, 3]&

を1000桁計算する：

Wolfram Language code: With[{a = 1``1010, b = 1 / Sqrt[2], o = 9}, 2ArithmeticGeometricMeanIteration[o + 1, a, b][[1]] ^ 2 / (1 - Sum[2 ^ n ({1, -1}.(ArithmeticGeometricMeanIteration[n, a, b] ^ 2)), {n, 0, o}])]
Wolfram Language code: % - Pi

ガウス定数を計算する：

Wolfram Language code: N[1 / ArithmeticGeometricMean[1, Sqrt[2]], 50]

ベータ関数を使ってその式と比較する：

Wolfram Language code: % == (1/2π)Beta[(1/4), (1/2)]

パラメータ平面で絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[ArithmeticGeometricMean[a, b]], {a, -2, 2}, {b, -2, 2}]//Quiet

特性と関係  (3)

ArithmeticGeometricMeanの導関数：

Wolfram Language code: D[ArithmeticGeometricMean[a, b], a]//Simplify
Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]//Simplify

FunctionExpandを使ってtArithmeticGeometricMeanを他の関数に展開する：

Wolfram Language code: FunctionExpand[ArithmeticGeometricMean[a, b], a > 0 && b > 0]

ArithmeticGeometricMeanが超幾何学的微分方程式に従うことを示す：

Wolfram Language code: w[a_] := ArithmeticGeometricMean[a, b]
Wolfram Language code: FullSimplify[2 a (b ^ 2 - a ^ 2) w'[a] ^ 2 + w[a] ((3 a ^ 2 - b ^ 2) w'[a] + a (a ^ 2 - b ^ 2) w''[a]) - a w[a] ^ 2 == 0, a > 0 && b > 0]

反復が算術平均と幾何平均の間であることを証明する：

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = a0;b[0] = b0;
Wolfram Language code: Reduce[ForAll[{a0, b0}, {a0, b0}∈ Reals && a0 > 0 && b0 > 0, (a0 + b0) / 2 >= a[3] >= b[3] >= Sqrt[a0 b0]]]
Wolfram Research (1988), ArithmeticGeometricMean, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html （2022年に更新）.

テキスト

Wolfram Research (1988), ArithmeticGeometricMean, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html （2022年に更新）.

CMS

Wolfram Language. 1988. "ArithmeticGeometricMean." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html.

APA

Wolfram Language. (1988). ArithmeticGeometricMean. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html

BibTeX

@misc{reference.wolfram_2026_arithmeticgeometricmean, author="Wolfram Research", title="{ArithmeticGeometricMean}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arithmeticgeometricmean, organization={Wolfram Research}, title={ArithmeticGeometricMean}, year={2022}, url={https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}, note=[Accessed: 13-September-2026]}