WOLFRAM

Wolfram 语言与系统参考资料中心

ArithmeticGeometricMean[a,b]

给出 a 和 b 的算术几何平均值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数属性  
微分  
级数展开  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArithmeticGeometricMean

ArithmeticGeometricMean[a,b]

给出 a 和 b 的算术几何平均值.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值计算：

Wolfram Language code: ArithmeticGeometricMean[1.8, 1.2]

在实数的子集上绘图：

Wolfram Language code: Plot[ArithmeticGeometricMean[1, x], {x, 0, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArithmeticGeometricMean[1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[ArithmeticGeometricMean[1, x], {x, 0, 2}, Assumptions -> x > 0]

范围  (25)

数值计算  (5)

数值化计算：

Wolfram Language code: ArithmeticGeometricMean[1.2, 5]
Wolfram Language code: ArithmeticGeometricMean[-2., -5]

高精度计算：

Wolfram Language code: N[ArithmeticGeometricMean[52, 5], 30]

输出的精度与输入的精度一致：

Wolfram Language code: ArithmeticGeometricMean[2, 3.0000000000000000000000]

复数输入：

Wolfram Language code: N[ArithmeticGeometricMean[1 + I, 3 + I]]

高精度的高效计算：

Wolfram Language code: ArithmeticGeometricMean[32, 5`100]//Timing
Wolfram Language code: ArithmeticGeometricMean[32, 5`100];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArithmeticGeometricMean[2, Interval[{.8, 1.2}]]
Wolfram Language code: ArithmeticGeometricMean[2, CenteredInterval[8, .2]]
Wolfram Language code: ArithmeticGeometricMean[CenteredInterval[8, .2], 1]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArithmeticGeometricMean[ 1, Around[2, 0.01]]

特殊值  (4)

在固定点的值：

Wolfram Language code: Table[ArithmeticGeometricMean[x, y], {x, {16, 8}}, {y, {4, 10}}]//N

零处的值：

Wolfram Language code: ArithmeticGeometricMean[0, 0]

符号式计算：

Wolfram Language code: ArithmeticGeometricMean[a, a]

求当 ArithmeticGeometricMean[3,x]=1.5 时， x 的值：

Wolfram Language code: xval = x /. FindRoot[ArithmeticGeometricMean[3, x] == 1.5, {x, 0.5}]
Wolfram Language code: Plot[ArithmeticGeometricMean[3, x], {x, 0, 2}, Epilog -> Style[Point[{xval, ArithmeticGeometricMean[3, xval]}], PointSize[Large], Red]]

可视化  (2)

绘制各阶 ArithmeticGeometricMean 函数：

Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], ArithmeticGeometricMean[2, x], ArithmeticGeometricMean[3, x], ArithmeticGeometricMean[4, x]}, {x, 0, 2}]

绘制 TemplateBox[{2, z}, ArithmeticGeometricMean] 实部：

Wolfram Language code: ComplexContourPlot[Re[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

绘制 TemplateBox[{2, z}, ArithmeticGeometricMean] 虚部：

Wolfram Language code: ComplexContourPlot[Im[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

函数属性  (10)

ArithmeticGeometricMean 的实域：

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[x, y], {x, y}]

复数域：

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[w, z], {w, z}, Complexes]

ArithmeticGeometricMean 可达到所有实数值：

Wolfram Language code: FunctionRange[ArithmeticGeometricMean[x, z], {x, z}, y]//Quiet

ArithmeticGeometricMean 按元素线性作用于列表：

Wolfram Language code: ArithmeticGeometricMean[{1.0, 2.0, 3.0}, 5]

ArithmeticGeometricMean 并非解析函数：

Wolfram Language code: FunctionAnalytic[ArithmeticGeometricMean[x, 1], x]

该函数有奇点和断点：

Wolfram Language code: FunctionSingularities[ArithmeticGeometricMean[x, y], {x, y}]
Wolfram Language code: FunctionDiscontinuities[ArithmeticGeometricMean[x, y], {x, y}]

TemplateBox[{1, x}, ArithmeticGeometricMean] 在其实数域上非递减：

Wolfram Language code: FunctionMonotonicity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean] 为单射函数：

Wolfram Language code: FunctionInjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], 1}, {x, 0, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean] 不是满射：

Wolfram Language code: FunctionSurjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], -2}, {x, -2, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean] 在其实数域上为非负：

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{{-, 1}, x}, ArithmeticGeometricMean] 在其实数域上为非正：

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[-1, x], x <= 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean] 在其实数域上为凹函数：

Wolfram Language code: FunctionConvexity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TraditionalForm 格式化：

Wolfram Language code: ArithmeticGeometricMean[a, b]//TraditionalForm

微分  (2)

关于 b 的一阶导：

Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]

关于 b 的高阶导：

Wolfram Language code: Table[D[ArithmeticGeometricMean[a, b], {b, k}], {k, 1, 3}]//FullSimplify

绘制关于 b 當 a=3 的高阶导：

Wolfram Language code: Plot[Evaluate[% /. a -> 3], {b, 0, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

级数展开  (2)

使用 Series 求泰勒展开：

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, 0, 2}]//Normal//FullSimplify

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[ArithmeticGeometricMean[2, x], {x, 0, m}], {m, 1, 3}]; Plot[{ArithmeticGeometricMean[2, x], terms}, {x, 0, 10}]

普通点的泰勒展开：

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, x0, 2}]//Normal// FullSimplify

应用  (4)

生成算术几何平均值的显式迭代形式：

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = 1.;b[0] = 2.;
Wolfram Language code: Table[{a[n], b[n]}, {n, 5}]

与 ArithmeticGeometricMean 进行比较：

Wolfram Language code: ArithmeticGeometricMean[1., 2.]

上述迭代过程的函数形式实现：

Wolfram Language code: agmIterations[a_ ? InexactNumberQ, b_ ? InexactNumberQ] := FixedPointList[{(#[[1]] + #[[2]]) / 2, Sqrt[#[[1]]#[[2]]]}&, {a, b}]
Wolfram Language code: agmIterations[1., 2.]

用于计算算术几何平均值的迭代步骤的解析式，算术几何平均值用 ArithmeticGeometricMean 表示：

Wolfram Language code: ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - (b / a)^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]
Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 1., 2.], {n, 0, 4}]

利用任意精度算术显示收敛速度：

Wolfram Language code: With[{a = N[1, 2000], b = N[2, 2000]}, Table[ArithmeticGeometricMeanIteration[n, a, b], {n, 0, 10}] - ArithmeticGeometricMean[a, b]]//SetPrecision[#, 3]&

计算一千位数的 ：

Wolfram Language code: With[{a = 1``1010, b = 1 / Sqrt[2], o = 9}, 2ArithmeticGeometricMeanIteration[o + 1, a, b][[1]] ^ 2 / (1 - Sum[2 ^ n ({1, -1}.(ArithmeticGeometricMeanIteration[n, a, b] ^ 2)), {n, 0, o}])]
Wolfram Language code: % - Pi

计算高斯常数：

Wolfram Language code: N[1 / ArithmeticGeometricMean[1, Sqrt[2]], 50]

与贝塔函数形式的表示比较：

Wolfram Language code: % == (1/2π)Beta[(1/4), (1/2)]

在参数平面绘制绝对值：

Wolfram Language code: Plot3D[Abs[ArithmeticGeometricMean[a, b]], {a, -2, 2}, {b, -2, 2}]//Quiet

属性和关系  (3)

ArithmeticGeometricMean 的导数：

Wolfram Language code: D[ArithmeticGeometricMean[a, b], a]//Simplify
Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]//Simplify

利用 FunctionExpand 展开 ArithmeticGeometricMean 成为其它函数：

Wolfram Language code: FunctionExpand[ArithmeticGeometricMean[a, b], a > 0 && b > 0]

证明 ArithmeticGeometricMean 满足一种超几何微分方程：

Wolfram Language code: w[a_] := ArithmeticGeometricMean[a, b]
Wolfram Language code: FullSimplify[2 a (b ^ 2 - a ^ 2) w'[a] ^ 2 + w[a] ((3 a ^ 2 - b ^ 2) w'[a] + a (a ^ 2 - b ^ 2) w''[a]) - a w[a] ^ 2 == 0, a > 0 && b > 0]

证明迭代介于算术和几何平均值之间：

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = a0;b[0] = b0;
Wolfram Language code: Reduce[ForAll[{a0, b0}, {a0, b0}∈ Reals && a0 > 0 && b0 > 0, (a0 + b0) / 2 >= a[3] >= b[3] >= Sqrt[a0 b0]]]
Wolfram Research (1988)，ArithmeticGeometricMean，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ArithmeticGeometricMean，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ArithmeticGeometricMean." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html.

APA

Wolfram 语言. (1988). ArithmeticGeometricMean. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html 年

BibTeX

@misc{reference.wolfram_2026_arithmeticgeometricmean, author="Wolfram Research", title="{ArithmeticGeometricMean}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arithmeticgeometricmean, organization={Wolfram Research}, title={ArithmeticGeometricMean}, year={2022}, url={https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}, note=[Accessed: 18-August-2026]}