WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}]

行列 mi jの行列から単一の平坦化された行列を作成する．

ArrayFlatten[a,r]

配列 a 中の r 組のペアになったレベルを平坦化する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArrayFlatten

ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}]

行列 mi jの行列から単一の平坦化された行列を作成する．

ArrayFlatten[a,r]

配列 a 中の r 組のペアになったレベルを平坦化する．

詳細

  • ArrayFlattenが平坦化するブロックは整合性がなければならない．
  • ArrayFlattenは，ブロックの配列からブロック行列を形成するのに使うことができる．
  • 行列の行列の場合，ArrayFlatten[a]は要素の並び順がMatrixForm[a]と同じ行列を返す．
  • ArrayFlatten[a]は一般にFlatten[a,{{1,3},{2,4}}]と等しい． »
  • ArrayFlatten[a,r]は一般にFlatten[a,{{1,r+1},{2,r+2},…,{r,2r}}]と等しい．
  • 階数2r のテンソルの場合，ArrayFlatten[a,r]は階数 r のテンソルを返す．
  • ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}]では，同じ行内のすべての行列 mi jが同一の最初の次元でなければならず，同じ列内の行列 mi jは同一の2番目の次元でなければならない．
  • 一般に，ArrayFlatten[a,r]において，a[[i1,i2,…,i_r]]のすべての k 番目の次元は ik のそれぞれの可能な値について等しくなければならない．
  • 配列の深さが r より小さいレベル r の要素はスカラーとして扱われ，適切な次元の階数 r の配列を埋めるのに繰り返される．
  • ArrayFlattenはSparseArrayオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (2)

行列の行列を平坦化してブロック行列を作る：

Wolfram Language code: m = {{1, 2}, {3, 4}};
Wolfram Language code: ArrayFlatten[{{m, m, m}, {m, m, m}}]

0を使って零行列を表す：

Wolfram Language code: m = {{1, 2}, {3, 4}};
Wolfram Language code: ArrayFlatten[{{0, 0, m}, {m, m, 0}}]

スコープ  (4)

階数4の配列を階数2に平坦化する：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4}]]//Dimensions

階数6の配列の最初の4レベルのみを平坦化する：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4, 5, 6}]]//Dimensions

階数6の配列を階数3に平坦化する：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4, 5, 6}], 3]//Dimensions

ArrayFlattenはSparseArrayオブジェクトに使うことができる：

Wolfram Language code: s = SparseArray[{i_, i_, j_, k_} -> i / (j + k - 1), {3, 3, 2, 2}]
Wolfram Language code: m = ArrayFlatten[s]
Wolfram Language code: MatrixForm[m]

SparseArrayオブジェクトのブロック行列から疎行列を作る：

Wolfram Language code: s1 = SparseArray[{i_, i_} -> i, {2, 2}]; s2 = SparseArray[{i_, j_} /; Abs[i - j] == 1 -> i - j, {3, 3}]
Wolfram Language code: m = ArrayFlatten[{{0, s1}, {-s2, 0}}]
Wolfram Language code: MatrixForm[m]

アプリケーション  (5)

「タイル」の多数のコピーを組み合せる：

Wolfram Language code: ArrayPlot[ArrayFlatten[Table[{{2, 0, 0, 1}, {1, 0, 2, 1}, {0, 1, 2, 2}}, {10}, {10}]]]

2Dの置換系を反復させる：

Wolfram Language code: NestList[ArrayFlatten[# /. 1 -> {{1, 0}, {1, 1}}]&, {{1}}, 3]
Wolfram Language code: ArrayPlot[#, ImageSize -> Tiny]& /@ %

3Dの置換系を反復させる：

Wolfram Language code: NestList[ArrayFlatten[# /. 1 -> {{{1, 0}, {0, 0}}, {{1, 0}, {1, 1}}}, 3]&, {{{1}}}, 3];
Wolfram Language code: Graphics3D[Cuboid /@ Position[#, 1], ImageSize -> Tiny]& /@ %

となるような，行列の逆行列 を形成する：

Wolfram Language code: involutoryMatrix[A_ ? MatrixQ, B_] := Block[{n, k}, {n, k} = Dimensions[A];ArrayFlatten[| | | | ----------------------- | ----------------------- | | IdentityMatrix[k] - B.A | B | | 2 A - A.B.A | A.B - IdentityMatrix[n] |] /; Dimensions[B] == {k, n}]
Wolfram Language code: L = involutoryMatrix[RandomInteger[{-5, 5}, {3, 2}], RandomInteger[{-5, 5}, {2, 3}]]

結果の行列が逆行列であることを確かめる：

Wolfram Language code: L.L//MatrixForm

n 個の空間点を持った波動方程式 のブロック行列の半離散化を行う：

Wolfram Language code: n = 100;h = 1. / n;

周期境界条件を持つ の二次近似の微分行列：

Wolfram Language code: dm = SparseArray[{{i_, i_} -> -2 / h ^ 2, {i_, j_} /; Abs[i - j] == 1 -> 1 / h ^ 2, {n, 1} -> 1 / h ^ 2, {1, n} -> 1 / h ^ 2}, {n, n}, 0.]

サイズ n の単位行列：

Wolfram Language code: im = IdentityMatrix[n, SparseArray, WorkingPrecision -> MachinePrecision]

である系 のブロック行列 a を形成する：

Wolfram Language code: a = ArrayFlatten[{{0., im}, {dm, 0.}}]

サイズ 2 n の単位行列：

Wolfram Language code: im2 = IdentityMatrix[2 n, SparseArray, WorkingPrecision -> MachinePrecision]

についてのベクトルの初期条件を設定する：

Wolfram Language code: ic = Join[Table[Exp[-100(i h - .5) ^ 2], {i, n}], ConstantArray[0., n]];

時間ステップ k の後退オイラー法を使って における解を近似する：

Wolfram Language code: k = h / 100;lsf = LinearSolve[im2 - k a];solt = ic;Do[solt = lsf[solt], {Round[0.25 / k]}];

における と を示す：

Wolfram Language code: ListPlot[{Take[solt, n], Take[solt, -n]}, DataRange -> {0, 1}, PlotRange -> All]

特性と関係  (3)

MatrixFormは行列の行列をArrayFlattenと同じ順序で表示する：

Wolfram Language code: m = {{1, 2}, {3, 4}}; b = {{m, m, m}, {m, m, m}};
Wolfram Language code: MatrixForm[b]
Wolfram Language code: MatrixForm[ArrayFlatten[b]]

ArrayFlattenはFlattenの特殊ケースである：

Wolfram Language code: m = {{1, 2}, {3, 4}}; b = {{m, 2m}, {3m, 4m}};
Wolfram Language code: MatrixForm[b]
Wolfram Language code: Flatten[b, {{1, 3}, {2, 4}}] == ArrayFlatten[b]

KroneckerProductはOuter積のArrayFlattenとして定義される：

Wolfram Language code: m1 = Array[a, {2, 2}]; m2 = Array[b, {2, 2}];
Wolfram Language code: KroneckerProduct[m1, m2] == ArrayFlatten[Outer[Times, m1, m2]]
Wolfram Research (2007), ArrayFlatten, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayFlatten.html.

テキスト

Wolfram Research (2007), ArrayFlatten, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayFlatten.html.

CMS

Wolfram Language. 2007. "ArrayFlatten." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayFlatten.html.

APA

Wolfram Language. (2007). ArrayFlatten. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayFlatten.html

BibTeX

@misc{reference.wolfram_2026_arrayflatten, author="Wolfram Research", title="{ArrayFlatten}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayFlatten.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayflatten, organization={Wolfram Research}, title={ArrayFlatten}, year={2007}, url={https://reference.wolfram.com/language/ref/ArrayFlatten.html}, note=[Accessed: 14-August-2026]}