WOLFRAM

Wolfram 语言与系统参考资料中心

ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}]

由矩阵 mi j 组成的矩阵，创建一个单一的展平矩阵.

ArrayFlatten[a,r]

在数组 a 中，展平 r 对层次.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArrayFlatten

ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}]

由矩阵 mi j 组成的矩阵，创建一个单一的展平矩阵.

ArrayFlatten[a,r]

在数组 a 中，展平 r 对层次.

更多信息

  • ArrayFlatten 要求它展平的块具有相适应的维数.
  • ArrayFlatten 可用于由数组块形成块矩阵.
  • 针对矩阵组的一个矩阵而言，ArrayFlatten[a] 所生成矩阵的元素次序和 MatrixForm[a] 相同.
  • ArrayFlatten[a] 通常等价于 Flatten[a,{{1,3},{2,4}}]. »
  • ArrayFlatten[a,r] 通常等价于 Flatten[a,{{1,r+1},{2,r+2},…,{r,2r}}].
  • 对于一个秩为 2r 的张量而言，ArrayFlatten[a,r] 给出一个秩为 r 的张量.
  • 在 ArrayFlatten[{{m11,m12,…},{m21,m22,…},…}] 中，同一行的所有矩阵 mi j 必须具有相同的第一维，同一列中的矩阵 mi j 必须具有相同的第二维.
  • 通常在 ArrayFlatten[a,r] 中，对于 ik 的每一可能值，所有 a[[i1,i2,…,i_r]] 的第 k 维数必须相等.
  • 数组深度小于 r 的第 r 层次元素的作为标量处理，并且被复制用于填入一个相应维数的秩为 r 的数组.
  • ArrayFlatten 对 SparseArray 对象起作用. »

范例

打开所有单元 关闭所有单元

基本范例  (2)

通过展平矩阵组的矩阵，生成的块矩阵.

Wolfram Language code: m = {{1, 2}, {3, 4}};
Wolfram Language code: ArrayFlatten[{{m, m, m}, {m, m, m}}]

利用 0 表示零矩阵组：

Wolfram Language code: m = {{1, 2}, {3, 4}};
Wolfram Language code: ArrayFlatten[{{0, 0, m}, {m, m, 0}}]

范围  (4)

把一个4秩数组展平为2秩：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4}]]//Dimensions

只展平一个6秩数组的前4层：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4, 5, 6}]]//Dimensions

把一个6秩数组展平为3秩：

Wolfram Language code: ArrayFlatten[Array[a, {1, 2, 3, 4, 5, 6}], 3]//Dimensions

ArrayFlatten 对 SparseArray 对象起作用：

Wolfram Language code: s = SparseArray[{i_, i_, j_, k_} -> i / (j + k - 1), {3, 3, 2, 2}]
Wolfram Language code: m = ArrayFlatten[s]
Wolfram Language code: MatrixForm[m]

从一个 SparseArray 对象的块矩阵生成一个稀疏矩阵：

Wolfram Language code: s1 = SparseArray[{i_, i_} -> i, {2, 2}]; s2 = SparseArray[{i_, j_} /; Abs[i - j] == 1 -> i - j, {3, 3}]
Wolfram Language code: m = ArrayFlatten[{{0, s1}, {-s2, 0}}]
Wolfram Language code: MatrixForm[m]

应用  (5)

把一块“花砖”的多个复件放在一起：

Wolfram Language code: ArrayPlot[ArrayFlatten[Table[{{2, 0, 0, 1}, {1, 0, 2, 1}, {0, 1, 2, 2}}, {10}, {10}]]]

对一个2维置换系统进行迭代：

Wolfram Language code: NestList[ArrayFlatten[# /. 1 -> {{1, 0}, {1, 1}}]&, {{1}}, 3]
Wolfram Language code: ArrayPlot[#, ImageSize -> Tiny]& /@ %

对一个三维置换系统进行迭代：

Wolfram Language code: NestList[ArrayFlatten[# /. 1 -> {{{1, 0}, {0, 0}}, {{1, 0}, {1, 1}}}, 3]&, {{{1}}}, 3];
Wolfram Language code: Graphics3D[Cuboid /@ Position[#, 1], ImageSize -> Tiny]& /@ %

形成一个对合矩阵 ，使得 ：

Wolfram Language code: involutoryMatrix[A_ ? MatrixQ, B_] := Block[{n, k}, {n, k} = Dimensions[A];ArrayFlatten[| | | | ----------------------- | ----------------------- | | IdentityMatrix[k] - B.A | B | | 2 A - A.B.A | A.B - IdentityMatrix[n] |] /; Dimensions[B] == {k, n}]
Wolfram Language code: L = involutoryMatrix[RandomInteger[{-5, 5}, {3, 2}], RandomInteger[{-5, 5}, {2, 3}]]

检查得到的矩阵是对合矩阵：

Wolfram Language code: L.L//MatrixForm

使一个具有 n 空间点的波动方程 的块矩阵半离散化：

Wolfram Language code: n = 100;h = 1. / n;

具有周期性边界条件的 的二阶逼近的微分矩阵：

Wolfram Language code: dm = SparseArray[{{i_, i_} -> -2 / h ^ 2, {i_, j_} /; Abs[i - j] == 1 -> 1 / h ^ 2, {n, 1} -> 1 / h ^ 2, {1, n} -> 1 / h ^ 2}, {n, n}, 0.]

尺寸为 n 的单位矩阵：

Wolfram Language code: im = IdentityMatrix[n, SparseArray, WorkingPrecision -> MachinePrecision]

系统 的块矩阵 a，其中 ：

Wolfram Language code: a = ArrayFlatten[{{0., im}, {dm, 0.}}]

尺寸为 2 n 的单位矩阵：

Wolfram Language code: im2 = IdentityMatrix[2 n, SparseArray, WorkingPrecision -> MachinePrecision]

为 建立一个初始条件向量：

Wolfram Language code: ic = Join[Table[Exp[-100(i h - .5) ^ 2], {i, n}], ConstantArray[0., n]];

当 时利用后向欧拉方法以时间步长 k 近似求解：

Wolfram Language code: k = h / 100;lsf = LinearSolve[im2 - k a];solt = ic;Do[solt = lsf[solt], {Round[0.25 / k]}];

给出 时的 和 ：

Wolfram Language code: ListPlot[{Take[solt, n], Take[solt, -n]}, DataRange -> {0, 1}, PlotRange -> All]

属性和关系  (3)

MatrixForm 按照和 ArrayFlatten 相同的次序显示矩阵组的矩阵：

Wolfram Language code: m = {{1, 2}, {3, 4}}; b = {{m, m, m}, {m, m, m}};
Wolfram Language code: MatrixForm[b]
Wolfram Language code: MatrixForm[ArrayFlatten[b]]

ArrayFlatten 是 Flatten 的一个特例：

Wolfram Language code: m = {{1, 2}, {3, 4}}; b = {{m, 2m}, {3m, 4m}};
Wolfram Language code: MatrixForm[b]
Wolfram Language code: Flatten[b, {{1, 3}, {2, 4}}] == ArrayFlatten[b]

KroneckerProduct 定义为一个 Outer 积的 ArrayFlatten：

Wolfram Language code: m1 = Array[a, {2, 2}]; m2 = Array[b, {2, 2}];
Wolfram Language code: KroneckerProduct[m1, m2] == ArrayFlatten[Outer[Times, m1, m2]]
Wolfram Research (2007)，ArrayFlatten，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayFlatten.html.

文本

Wolfram Research (2007)，ArrayFlatten，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayFlatten.html.

CMS

Wolfram 语言. 2007. "ArrayFlatten." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayFlatten.html.

APA

Wolfram 语言. (2007). ArrayFlatten. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArrayFlatten.html 年

BibTeX

@misc{reference.wolfram_2026_arrayflatten, author="Wolfram Research", title="{ArrayFlatten}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayFlatten.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayflatten, organization={Wolfram Research}, title={ArrayFlatten}, year={2007}, url={https://reference.wolfram.com/language/ref/ArrayFlatten.html}, note=[Accessed: 09-August-2026]}