WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayMesh[array]

各セルが幾何次元 d を有し，配列の非零の値を表す階数 d の配列から，メッシュ領域を生成する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DataRange  
DataReversed  
MeshCellHighlight  
Show More Show More
MeshCellLabel  
MeshCellMarker  
MeshCellShapeFunction  
MeshCellStyle  
PlotTheme  
アプリケーション  
セルオートマトン  
画像  
パターン  
置換系  
ゲームデザイン  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ArrayMesh

ArrayMesh[array]

各セルが幾何次元 d を有し，配列の非零の値を表す階数 d の配列から，メッシュ領域を生成する．

詳細とオプション

  • ArrayMeshは，セルが区間，正方形，あるいは立方体であり，格子点が一様間隔で置かれた整数点である格子から生成される．
  • ArrayMeshは連続する array の行を下向きに並べ，連続する列を横方向に並べる．
  • ArrayMeshにはMeshRegionと同じオプションに次を加えたものが使える．
  • DataRange Automatic生成するメッシュ座標の範囲
    DataReversed False行の順序を逆にするかどうか
  • ArrayMeshはSparseArrayオブジェクトに使うことができる．

例題

すべて開く すべて閉じる

例  (3)

1Dカントール(Cantor)メッシュ：

Wolfram Language code: ArrayMesh[{1, 0, 1, 1, 0, 1}]

2D配列メッシュ：

Wolfram Language code: ArrayMesh[{{1, 1, 0, 1}, {1, 1, 1, 1}, {0, 1, 0, 1}}]

3D配列メッシュ：

Wolfram Language code: ArrayMesh[{{{1, 1}, {1, 1}, {1, 0}}, {{0, 1}, {1, 1}, {0, 0}}}]

スコープ  (2)

1D配列メッシュを作成する：

Wolfram Language code: ArrayMesh[{1, 1, 0, 0, 1}]

2D配列メッシュ：

Wolfram Language code: ArrayMesh[{{1, 1, 0, 1}, {1, 1, 1, 1}, {0, 1, 0, 1}}]

3D配列メッシュ：

Wolfram Language code: ArrayMesh[{{{1, 1}, {1, 1}, {1, 0}}, {{0, 1}, {1, 1}, {0, 0}}}]

ArrayMeshはSparseArrayに使うことができる：

Wolfram Language code: ArrayMesh[SparseArray[{{x_, y_} /; Abs[x - y] < 2 -> 1}, {3, 3}]]

オプション  (14)

DataRange  (1)

DataRangeを使って生成するメッシュ座標の範囲を指定することができる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}]
Wolfram Language code: MeshCoordinates[%]

別の範囲を指定する：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, DataRange -> {{0, 1}, {0, 2}}]
Wolfram Language code: MeshCoordinates[%]

DataReversed  (1)

DataReversedを使って行の順序を逆にすることができる：

Wolfram Language code: ArrayMesh[{{1, 0, 0}, {1, 1, 0}, {1, 0, 1}, {1, 1, 1}}]

行の順序を逆にする：

Wolfram Language code: ArrayMesh[{{1, 0, 0}, {1, 1, 0}, {1, 0, 1}, {1, 1, 1}}, DataReversed -> True]

MeshCellHighlight  (2)

MeshCellHighlightを使ってArrayMeshの一部のハイライトを指定することができる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellHighlight -> {{1, All} -> Red, {0, All} -> Green}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellHighlight -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Green}}]

セルそれ自体を使ってハイライトすることもできる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellHighlight -> {Line[{4, 6}] -> {Thick, Red}, Line[{5, 6}] -> {Dashed, Green}}]

MeshCellLabel  (2)

MeshCellLabelを使ってArrayMeshの一部にラベルを付けることができる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellLabel -> {0 -> "Index"}]

個々のセルにはセル指標を使ってラベルを付けることができる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellLabel -> {{1, 2} -> "x", {1, 1} -> "y"}]

セルそれ自体を使うこともできる：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, MeshCellLabel -> {Line[{5, 6}] -> "x", Line[{4, 6}] -> "y"}]

MeshCellMarker  (1)

MeshCellMarkerを使ってArrayMeshの一部に値を割り当てることができる：

Wolfram Language code: ArrayMesh[{{1, 0}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}]

MeshCellLabelを使ってマーカーを示す：

Wolfram Language code: ArrayMesh[{{1, 0}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction  (2)

MeshCellShapeFunctionを使ってArrayMeshの一部に値を割り当てることができる：

Wolfram Language code: ArrayMesh[{{{1, 0}}}, MeshCellShapeFunction -> {1 -> (Tube[#1, .1]&)}]

個々のセルはセル指標を使って描くことができる：

Wolfram Language code: ArrayMesh[{{{1, 0}}}, MeshCellShapeFunction -> {{1, 4} -> (Tube[#1, .1]&)}]

セルそれ自身を使うこともできる：

Wolfram Language code: ArrayMesh[{{{1, 0}}}, MeshCellShapeFunction -> {Line[{1, 2}] -> (Tube[#1, .1]&)}]

MeshCellStyle  (3)

MeshCellStyleを使ってArrayMeshの一部のスタイリングを指定することができる：

Wolfram Language code: ArrayMesh[{{1, 0}}, MeshCellStyle -> {{1, All} -> Red, {0, All} -> Green}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: ArrayMesh[{{1, 0}}, MeshCellStyle -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Green}}]

セル自身を使うこともできる：

Wolfram Language code: ArrayMesh[{{1, 0}}, MeshCellStyle -> {Line[{3, 4}] -> {Thick, Red}, Line[{2, 4}] -> {Dashed, Green}}]

明示的な色指示子を与えて個々のセルの色を指定する：

Wolfram Language code: ArrayMesh[{{1, 0, 0, 1}, {1, 1, 0, 1}, {1, 0, 1, 1}}, MeshCellStyle -> {{2, All} -> Black, {2, 1} -> Red, {2, {2, 3}} -> Pink}]

PlotTheme  (2)

格子線と凡例があるテーマを使う：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, PlotTheme -> "Detailed"]

テーマを使ってワイヤーフレームを描画する：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, PlotTheme -> "Lines"]

アプリケーション  (15)

セルオートマトン  (5)

2Dセルオートマトンの進化：

Wolfram Language code: ArrayMesh[CellularAutomaton[30, {{1}, 0}, 50]]

3Dセルオートマトンの進化の一連のステップを示す：

Wolfram Language code: ArrayMesh /@ CellularAutomaton[{14, {2, 1}, {1, 1, 1}}, {{{{1}}}, 0}, 10]

外部総和型2Dセルオートマトンを使って迷路のようなパターンを作る：

Wolfram Language code: ArrayMesh[CellularAutomaton[{746, {2, {{2, 2, 2}, {2, 1, 2}, {2, 2, 2}}}, {1, 1}}, {{Table[1, {7}]}, 0}, {{{150}}}]]

ライフゲームの「グライダー」を示す：

Wolfram Language code: c = CellularAutomaton[{224, {2, {{2, 2, 2}, {2, 1, 2}, {2, 2, 2}}}, {1, 1}}, {{{0, 1, 0}, {0, 0, 1}, {1, 1, 1}}, 0}, 8];
Wolfram Language code: glider = (First /@ Position[Flatten[#], 1])& /@ c;
Wolfram Language code: ArrayMesh[ConstantArray[1, {5, 5}], MeshCellStyle -> {{1, All} -> Black, {2, All} -> White, {2, #} -> Black}]& /@ glider

一連の二次元の9近傍ルールを使って生成されたパターン：

Wolfram Language code: Table[ArrayMesh[CellularAutomaton[{i, {2, 1}, {1, 1}}, {{{1}}, 0}, {{{30}}}]], {i, 2, 20, 4}]

平均のセル値：

Wolfram Language code: Table[ArrayMesh[Mean[CellularAutomaton[{i, {2, 1}, {1, 1}}, {{{1}}, 0}, 10]]], {i, 2, 20, 4}]

画像  (2)

2D画像をMeshRegionに変換する：

Wolfram Language code: img = [image];

セルとスタイル：

Wolfram Language code: cells = ImageData[img];
Wolfram Language code: style = MapIndexed[{2, First[#2]} -> GrayLevel[#1] &, Flatten[cells]];

メッシュ：

Wolfram Language code: ArrayMesh[cells, MeshCellStyle -> style]

3D画像を変換する：

Wolfram Language code: img = Image3D[RandomReal[1, {2, 3, 4}], ColorFunction -> GrayLevel]

セルとスタイル：

Wolfram Language code: cells = Transpose[ImageData[img], {2, 3, 1}];
Wolfram Language code: style = MapIndexed[{3, First[#2]} -> GrayLevel[#1] &, Flatten[cells]];

メッシュ：

Wolfram Language code: ArrayMesh[cells, MeshCellStyle -> style]

パターン  (2)

単純な2Dパターンを生成する：

Wolfram Language code: ArrayMesh[Table[If[Mod[i, 4] == 2 && Mod[j, 4] == 2, 0, 1], {i, 11}, {j, 11}]]

3Dパターン：

Wolfram Language code: ArrayMesh[{{{1, 1, 1}, {1, 0, 1}, {1, 1, 1}}, {{1, 1, 1}, {1, 0, 1}, {1, 1, 1}}, {{1, 1, 1}, {1, 0, 1}, {1, 1, 1}}}]

より複雑なパターン：

Wolfram Language code: ArrayMesh[CellularAutomaton[{14, {2, 1}, {1, 1}}, {{{1}}, 0}, 10]]

Seidelメッシュ，つまり，トンネルが交差せずに全方向に通っているメッシュ領域を作る：

Wolfram Language code: SeidelMesh[{r_, s_, t_}] := ArrayMesh[Table[If[Mod[i, 4] == 2 && Mod[j, 4] == 2 || Mod[i, 4] == 0 && Mod[k, 4] == 0 || Mod[j, 4] == 0 && Mod[k, 4] == 2, 0, 1], {i, 3 + r 4}, {j, 3 + s 4}, {k, 3 + t 4}]]
Wolfram Language code: SeidelMesh[{1, 1, 1}]

境界メッシュを変換しそれにスタイルを付けると理解し易くなる：

Wolfram Language code: HighlightMesh[BoundaryMesh[%], {Style[1, None], Style[2, Opacity[0.5]]}]

置換系  (4)

1Dカントールメッシュ：

Wolfram Language code: ArrayMesh[{1, 0, 1, 0, 0, 0, 1, 0, 1}]

各ステージにおけるカントール集合の長さ：

Wolfram Language code: Table[Rationalize[RegionMeasure[ArrayMesh[n]]], {n, SubstitutionSystem[{1 -> {1, 0, 1}, 0 -> {0, 0, 0}}, {1}, 5]}]

式：

Wolfram Language code: FindSequenceFunction[%, n]

カントール集合の構築ステップ：

Wolfram Language code: ArrayMesh[{#}]& /@ SubstitutionSystem[{1 -> {1, 0, 1}, 0 -> {0, 0, 0}}, {1}, 3]

これに似た2Dのネストしたオブジェクトを作る：

Wolfram Language code: ArrayMesh /@ SubstitutionSystem[{1 -> {{1, 1, 1}, {1, 0, 1}, {1, 1, 1}}, 0 -> ConstantArray[0, {3, 3}]}, {{1}}, 3]

3Dメンガー(Menger)スポンジ：

Wolfram Language code: ArrayMesh /@ SubstitutionSystem[{1 -> 1 - CrossMatrix[{1, 1, 1}], 0 -> ConstantArray[0, {3, 3, 3}]}, {{{1}}}, 3]

ゲームデザイン  (2)

2Dのチェス盤を作る：

Wolfram Language code: m = Join@@ConstantArray[{{0, 1, 0, 1, 0, 1, 0, 1}, {1, 0, 1, 0, 1, 0, 1, 0}}, 4];
Wolfram Language code: p = First /@ Position[Flatten[m], 1];
Wolfram Language code: style = {{1, All} -> {Thick, Black}, {2, All} -> White, {2, #}& /@ p -> Black};
Wolfram Language code: r = ArrayMesh[ConstantArray[1, {8, 8}], MeshCellStyle -> style]

3Dのチェス盤：

Wolfram Language code: m = Join@@ConstantArray[{{{0}, {1}, {0}, {1}, {0}, {1}, {0}, {1}}, {{1}, {0}, {1}, {0}, {1}, {0}, {1}, {0}}}, 4];
Wolfram Language code: p = First /@ Position[Flatten[m], 1];
Wolfram Language code: style = {{1, All} -> {Thick, Black}, {3, All} -> White, {3, #}& /@ p -> Black};
Wolfram Language code: r = ArrayMesh[ConstantArray[1, {8, 8, 1}], MeshCellStyle -> style]

それぞれが4つの正方形からなる形であるテトロミノを生成する：

Wolfram Language code: reg = ArrayMesh /@ {(⁠| | | | | | - | - | - | - | | 1 | 0 | 0 | 0 | | 1 | 0 | 0 | 0 | | 1 | 0 | 0 | 0 | | 1 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 1 | 1 | 0 | 0 | | 0 | 1 | 0 | 0 | | 0 | 1 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 1 | 1 | 0 | 0 | | 1 | 0 | 0 | 0 | | 1 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 0 | 1 | 0 | 0 | | 1 | 1 | 0 | 0 | | 0 | 1 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 1 | 0 | 0 | 0 | | 1 | 1 | 0 | 0 | | 0 | 1 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 1 | 1 | 0 | 0 | | 1 | 1 | 0 | 0 | | 0 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠), (⁠| | | | | | - | - | - | - | | 1 | 1 | 0 | 0 | | 0 | 1 | 1 | 0 | | 0 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 |⁠)}

テトロミノに彩色する：

Wolfram Language code: col = ColorData[97, "ColorList"];
Wolfram Language code: Table[MeshRegion[reg[[i]], MeshCellStyle -> {2 -> col[[i]]}], {i, 7}]

特性と関係  (6)

ArrayMeshの出力は常に全次元のMeshRegionである：

Wolfram Language code: ArrayMesh[RandomInteger[1, {3, 4}]]
Wolfram Language code: {MeshRegionQ[%], RegionDimension[%]}

ArrayMeshは1Dの区間からなる：

Wolfram Language code: ArrayMesh[{1, 1, 0, 0, 1}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

2Dの長方形：

Wolfram Language code: ArrayMesh[{{0, 0, 1, 1}, {0, 1, 1, 0}, {1, 0, 0, 0}}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

3Dの六面体：

Wolfram Language code: ArrayMesh[{{{1, 0}, {0, 1}}}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

ArrayPlotを使ってプロットを生成することができる：

Wolfram Language code: arr = {{0, 1, 1, 0}, {1, 0, 1, 0}, {1, 1, 0, 1}};
Wolfram Language code: ArrayMesh[arr]

プロットを示す：

Wolfram Language code: ArrayPlot[arr]

MatrixPlotを使ってプロットを生成することができる：

Wolfram Language code: arr = {{0, 1, 1, 0}, {1, 0, 1, 0}, {1, 1, 0, 1}};
Wolfram Language code: ArrayMesh[arr]

プロットを示す：

Wolfram Language code: MatrixPlot[arr]

BoundaryMeshを使って境界メッシュ領域を求める：

Wolfram Language code: BoundaryMesh[ArrayMesh[{{0, 1, 1, 0}, {1, 0, 1, 0}, {1, 1, 0, 1}}]]

DataRange range はRescalingTransform[{...},range]を使うことに等しい：

Wolfram Language code: ArrayMesh[{{1, 0}, {1, 1}}, DataRange -> {{1, 2}, {1, 3}}, Frame -> True]

RescalingTransformを使う：

Wolfram Language code: box = TransformedRegion[ArrayMesh[{{1, 0}, {1, 1}}], RescalingTransform[{{0, 2}, {0, 2}}, {{1, 2}, {1, 3}}]];
Wolfram Language code: MeshRegion[box, Frame -> True]
Wolfram Research (2016), ArrayMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayMesh.html.

テキスト

Wolfram Research (2016), ArrayMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayMesh.html.

CMS

Wolfram Language. 2016. "ArrayMesh." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayMesh.html.

APA

Wolfram Language. (2016). ArrayMesh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayMesh.html

BibTeX

@misc{reference.wolfram_2026_arraymesh, author="Wolfram Research", title="{ArrayMesh}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayMesh.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arraymesh, organization={Wolfram Research}, title={ArrayMesh}, year={2016}, url={https://reference.wolfram.com/language/ref/ArrayMesh.html}, note=[Accessed: 16-September-2026]}